From 0f2fed9a0c6534b31320bad0d423e8022bc2bdc2 Mon Sep 17 00:00:00 2001
From: Jacob Stiffler <j-stiffler@ti.com>
Date: Wed, 8 Oct 2014 18:06:20 +0000
Subject: ti-ipc: Upgrade to IPC 3.30.00.09

* Added new recipe for latest IPC
* Removed older recipe versions
* Latest recipe points to IPC 3.30.00.09

Signed-off-by: Jacob Stiffler <j-stiffler@ti.com>
Signed-off-by: Denys Dmytriyenko <denys@ti.com>
---
 recipes-ti/ipc/ti-ipc_git.bb | 62 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 recipes-ti/ipc/ti-ipc_git.bb

(limited to 'recipes-ti/ipc/ti-ipc_git.bb')

diff --git a/recipes-ti/ipc/ti-ipc_git.bb b/recipes-ti/ipc/ti-ipc_git.bb
new file mode 100644
index 00000000..185e58b8
--- /dev/null
+++ b/recipes-ti/ipc/ti-ipc_git.bb
@@ -0,0 +1,62 @@
+DESCRIPTION = "TI Inter Process Communication (IPC) Mechanisms (for Uni- and Multi- Processor Configurations)"
+HOMEPAGE="http://processors.wiki.ti.com/index.php/Category:IPC"
+
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://${S}/ipc-linux.mak;beginline=1;endline=30;md5=abd112f156e5eb9b0f3e202e48747f9a"
+
+DEPENDS += "virtual/kernel"
+
+PV = "3.30.00.09"
+
+# This is the first version of the 3.30.00.09 
+# PR = "r0"
+
+BRANCH = "master"
+SRC_URI = "git://git.ti.com/ipc/ipcdev.git;protocol=git;branch=${BRANCH} \
+           file://tiipclad-daemon.sh \
+           "
+SRCREV = "595bc3e3bbb2e7ec12a8287145d8e3929291e59d"
+
+S = "${WORKDIR}/git"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+PLATFORM = "UNKNOWN"
+PLATFORM_omap5-evm = "OMAP54XX"
+PLATFORM_dra7xx = "DRA7XX"
+PLATFORM_keystone = "TCI6638"
+
+DAEMON = "UNKNOWN"
+DAEMON_omap5-evm = "lad_omap54xx_smp"
+DAEMON_dra7xx = "lad_dra7xx"
+DAEMON_keystone = "lad_tci6638"
+
+inherit autotools pkgconfig update-rc.d
+
+INITSCRIPT_NAME = "tiipclad-daemon.sh"
+INITSCRIPT_PARAMS = "defaults 10"
+
+EXTRA_OECONF += "PLATFORM=${PLATFORM} KERNEL_INSTALL_DIR=${STAGING_KERNEL_DIR}"
+
+do_configure() {
+    oe_runconf
+}
+
+do_install_append() {
+    install -d ${D}${sysconfdir}/init.d/
+
+    # Modify the tiipclad-daemon.sh script to point to the right
+    # lad daemon executable.
+    sed -i -e "s/__LAD_DAEMON__/${DAEMON}/" ${WORKDIR}/tiipclad-daemon.sh
+    install -c -m 755 ${WORKDIR}/tiipclad-daemon.sh ${D}${sysconfdir}/init.d/${INITSCRIPT_NAME}
+}
+
+PACKAGES =+ "${PN}-test"
+RDEPENDS_${PN}-test += "${PN}"
+
+FILES_${PN}-test = " \
+    ${bindir}/NameServerApp \
+    ${bindir}/MessageQApp \
+    ${bindir}/MessageQMulti \
+    ${bindir}/ping_rpmsg"
+
-- 
cgit v1.2.3-54-g00ecf