From 20f3191aeb592dd889eeaf96a31526297de95306 Mon Sep 17 00:00:00 2001
From: Denys Dmytriyenko <denys@konsulko.com>
Date: Tue, 22 Feb 2022 04:13:45 +0000
Subject: meta-ti: create a sub-layer meta-ti-bsp from existing content

Extra sub-layers will be created next and relevant content moved across them.

Signed-off-by: Denys Dmytriyenko <denys@konsulko.com>
Signed-off-by: Ryan Eatmon <reatmon@ti.com>
---
 .../recipes-bsp/ti-sci-fw/ti-sci-fw-source_git.bb  | 45 ++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 meta-ti-bsp/recipes-bsp/ti-sci-fw/ti-sci-fw-source_git.bb

(limited to 'meta-ti-bsp/recipes-bsp/ti-sci-fw/ti-sci-fw-source_git.bb')

diff --git a/meta-ti-bsp/recipes-bsp/ti-sci-fw/ti-sci-fw-source_git.bb b/meta-ti-bsp/recipes-bsp/ti-sci-fw/ti-sci-fw-source_git.bb
new file mode 100644
index 00000000..bab4acf0
--- /dev/null
+++ b/meta-ti-bsp/recipes-bsp/ti-sci-fw/ti-sci-fw-source_git.bb
@@ -0,0 +1,45 @@
+# ti-sci-fw builds and packages multiple config variants via multiconfig
+# Let's take a page from gcc-source as a common recipe for all gcc stages,
+# but also to provide a single package for MAINMACHINE of all multiconfigs
+
+require recipes-bsp/ti-linux-fw/ti-linux-fw.inc
+
+SUMMARY += "- sources"
+
+COMPATIBLE_MACHINE = "k3"
+
+EXCLUDE_FROM_WORLD = "1"
+INHIBIT_DEFAULT_DEPS = "1"
+DEPENDS = ""
+
+PACKAGES = "${PN}"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+do_configure[noexec] = "1"
+do_compile[noexec] = "1"
+
+SRCIPK_SRC_DIR = "${WORKDIR}/imggen"
+SRCIPK_INSTALL_DIR = "board-support/k3-image-gen-${PV}"
+FILES:${PN} = "${SRCIPK_INSTALL_DIR}"
+
+do_install() {
+    # Copy sources for packaging
+    mkdir -p ${D}/${SRCIPK_INSTALL_DIR}
+    if [ -e ${SRCIPK_SRC_DIR} ]; then
+        if [ "${SRCIPK_SRC_DIR}" = "${WORKDIR}" ]; then
+            excludes='--exclude ./temp --exclude ${D}'
+        fi
+        tar -C ${SRCIPK_SRC_DIR} -cO $excludes . | tar -C ${D}/${SRCIPK_INSTALL_DIR} -xpf -
+    fi
+
+    # Fix up patches/ directory to contain actual patches instead of symlinks
+    if [ -e ${D}/${SRCIPK_INSTALL_DIR}/patches ]
+    then
+        mv ${D}/${SRCIPK_INSTALL_DIR}/patches ${D}/${SRCIPK_INSTALL_DIR}/patches-links
+        cp -rL ${D}/${SRCIPK_INSTALL_DIR}/patches-links ${D}/${SRCIPK_INSTALL_DIR}/patches
+        rm -rf ${D}/${SRCIPK_INSTALL_DIR}/patches-links
+    fi
+}
+
+# Do not perform any QA checks on source package
+INSANE_SKIP:${PN} += "${ALL_QA}"
-- 
cgit v1.2.3-54-g00ecf