4 files changed, 102 insertions, 0 deletions

diff --git a/meta-ti-bsp/recipes-bsp/dsptop/debugss-module-drv_git.bb b/meta-ti-bsp/recipes-bsp/dsptop/debugss-module-drv_git.bb
new file mode 100644
index 00000000..a250b825
--- /dev/null
+++ b/meta-ti-bsp/recipes-bsp/dsptop/debugss-module-drv_git.bb
@@ -0,0 +1,22 @@
+DESCRIPTION = "Debug Sub-System (DebugSS) driver for Keystone and DRA7xx devices"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING.txt;md5=9d4316fe434ba450dca4da25348ca5a3"
+
+# This package builds a kernel module, use kernel PR as base and append a local
+MACHINE_KERNEL_PR:append = "d"
+PR = "${MACHINE_KERNEL_PR}"
+PV:append = "+git${SRCPV}"
+
+S = "${WORKDIR}/git/debugss_module/debugss-mod"
+
+inherit module
+
+PLATFORM = ""
+PLATFORM:dra7xx = "DRA7xx_PLATFORM"
+
+EXTRA_OEMAKE = "'PLATFORM=${PLATFORM}' KVERSION=${KERNEL_VERSION} KERNEL_SRC=${STAGING_KERNEL_DIR}"
+
+COMPATIBLE_MACHINE = "dra7xx"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+include dsptop.inc
diff --git a/meta-ti-bsp/recipes-bsp/dsptop/dsptop.inc b/meta-ti-bsp/recipes-bsp/dsptop/dsptop.inc
new file mode 100644
index 00000000..31f775e2
--- /dev/null
+++ b/meta-ti-bsp/recipes-bsp/dsptop/dsptop.inc
@@ -0,0 +1,8 @@
+# This corresponds to version 1.4.0
+SRCREV = "816485e68430bbec643eac9498bfa5303eb2c2e1"
+PV = "1.4.0"
+INC_PR = "r2"
+
+SRC_URI = "git://git.ti.com/sdo-emu/dsptop.git;protocol=git;branch=${BRANCH}"
+
+BRANCH = "master"
diff --git a/meta-ti-bsp/recipes-bsp/dsptop/dsptop_git.bb b/meta-ti-bsp/recipes-bsp/dsptop/dsptop_git.bb
new file mode 100644
index 00000000..20818443
--- /dev/null
+++ b/meta-ti-bsp/recipes-bsp/dsptop/dsptop_git.bb
@@ -0,0 +1,27 @@
+DESCRIPTION = "TI dsptop utility."
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://debian/copyright;md5=309825aa8f5edfcf2c44912ac094b979"
+
+DEPENDS = "libulm ncurses"
+
+PR = "${INC_PR}.2"
+
+S = "${WORKDIR}/git/dsptop"
+
+DEVICE = ""
+DEVICE:dra7xx = "DRA7xx"
+
+EXTRA_OEMAKE = "release DEVICE=${DEVICE} CROSS_COMPILE=${TARGET_PREFIX} CC="${CC}""
+
+do_install() {
+    oe_runmake install DESTDIR=${D}
+}
+
+COMPATIBLE_MACHINE = "dra7xx"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+RDEPENDS:${PN} = "debugss-module-drv bash"
+
+include dsptop.inc
+
+PARALLEL_MAKE = ""
diff --git a/meta-ti-bsp/recipes-bsp/dsptop/libulm_git.bb b/meta-ti-bsp/recipes-bsp/dsptop/libulm_git.bb
new file mode 100644
index 00000000..f3e7ec3c
--- /dev/null
+++ b/meta-ti-bsp/recipes-bsp/dsptop/libulm_git.bb
@@ -0,0 +1,45 @@
+SUMMARY = "TI Usage & Load Monitor Implementation"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://../debian/copyright;md5=309825aa8f5edfcf2c44912ac094b979"
+
+inherit features_check
+
+REQUIRED_MACHINE_FEATURES = "dsp"
+
+DEPENDS = "ti-cgt6x-native"
+PR = "${INC_PR}.0"
+
+S = "${WORKDIR}/git/dsptop/ulm"
+
+DEVICE=""
+DEVICE:dra7xx = "DRA7xx"
+
+EXTRA_OEMAKE = "release DEVICE=${DEVICE} CROSS_COMPILE=${TARGET_PREFIX}"
+
+do_compile() {
+    oe_runmake arm XPORT_ONLY CC="${CC}"
+    oe_runmake dsp C6X_C_DIR=${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x/include
+}
+
+do_install() {
+    install -d ${D}${includedir}
+    install -d ${D}${libdir}
+    install -d ${D}${datadir}/ti/ulm
+    cp -f tiulm.h ${D}${includedir}
+    cp -f release/libtiulm.a ${D}${libdir}
+    cp -f tiulm.h ${D}${datadir}/ti/ulm
+    cp -f release/libtiulm.ae66 ${D}${datadir}/ti/ulm
+}
+
+COMPATIBLE_MACHINE = "dra7xx"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+FILES:${PN}-dev += "\
+    ${datadir}/ti/ulm \
+"
+
+include dsptop.inc
+
+ALLOW_EMPTY:${PN} = "1"
+
+PARALLEL_MAKE= ""