meta-ti: move WiLink components to meta-ti-extras

Move WiLink WiFi and BT components from meta-ti-bsp to meta-ti-extras layer.

Signed-off-by: Denys Dmytriyenko <denys@konsulko.com>
Signed-off-by: Ryan Eatmon <reatmon@ti.com>

9 files changed, 247 insertions, 0 deletions

diff --git a/meta-ti-extras/recipes-bsp/bt-fw/bt-fw_git.bb b/meta-ti-extras/recipes-bsp/bt-fw/bt-fw_git.bb
new file mode 100644
index 00000000..ea42c168
--- /dev/null
+++ b/meta-ti-extras/recipes-bsp/bt-fw/bt-fw_git.bb
@@ -0,0 +1,24 @@
+DESCRIPTION = "Firmware files for Bluetooth"
+LICENSE = "TI-TSPA"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=f39eac9f4573be5b012e8313831e72a9"
+
+PV = "8.7.1+git${SRCPV}"
+
+CLEANBROKEN = "1"
+
+SRCREV = "0ee619b598d023fffc77679f099bc2a4815510e4"
+BRANCH = "master"
+SRC_URI = "git://git.ti.com/ti-bt/service-packs.git;branch=${BRANCH}"
+
+S = "${WORKDIR}/git"
+
+do_compile() {
+    :
+}
+
+do_install() {
+    install -d ${D}${base_libdir}/firmware/ti-connectivity
+    oe_runmake "DEST_DIR=${D}" "BASE_LIB_DIR=${base_libdir}" install
+}
+
+FILES:${PN} += "${base_libdir}/firmware/ti-connectivity/*"
diff --git a/meta-ti-extras/recipes-bsp/wl18xx-fw/wl18xx-fw/0001-Add-Makefile-to-install-firmware-files.patch b/meta-ti-extras/recipes-bsp/wl18xx-fw/wl18xx-fw/0001-Add-Makefile-to-install-firmware-files.patch
new file mode 100644
index 00000000..a8db0770
--- /dev/null
+++ b/meta-ti-extras/recipes-bsp/wl18xx-fw/wl18xx-fw/0001-Add-Makefile-to-install-firmware-files.patch
@@ -0,0 +1,29 @@
+From 3a8fc3ccf00796254d6cef4b6d4cd70dc37012e1 Mon Sep 17 00:00:00 2001
+From: Denys Dmytriyenko <denys@ti.com>
+Date: Fri, 10 Mar 2017 13:28:29 -0500
+Subject: [PATCH] Add Makefile to install firmware files
+
+Signed-off-by: Denys Dmytriyenko <denys@ti.com>
+---
+ Makefile | 9 +++++++++
+ 1 file changed, 9 insertions(+)
+ create mode 100644 Makefile
+
+diff --git a/Makefile b/Makefile
+new file mode 100644
+index 0000000..1cf38e3
+--- /dev/null
++++ b/Makefile
+@@ -0,0 +1,9 @@
++# Installs the the ti-connectivity wlan firmware files into the root file system
++
++install:
++       @if [ ! -d $(DESTDIR) ] ; then \
++               echo "Target filesystem directory doesn't exist."; \
++               exit 1; \
++       fi
++       install -d  $(DEST_DIR)/lib/firmware/ti-connectivity
++       cp *.bin $(DEST_DIR)/lib/firmware/ti-connectivity/
+-- 
+2.7.4
+
diff --git a/meta-ti-extras/recipes-bsp/wl18xx-fw/wl18xx-fw_8.9.0.0.86.bb b/meta-ti-extras/recipes-bsp/wl18xx-fw/wl18xx-fw_8.9.0.0.86.bb
new file mode 100644
index 00000000..48b500a8
--- /dev/null
+++ b/meta-ti-extras/recipes-bsp/wl18xx-fw/wl18xx-fw_8.9.0.0.86.bb
@@ -0,0 +1,25 @@
+DESCRIPTION = "Firmware files for use with TI wl18xx"
+LICENSE = "TI-TSPA"
+LIC_FILES_CHKSUM = "file://LICENCE;md5=4977a0fe767ee17765ae63c435a32a9e"
+
+SRC_URI = " \
+        git://git.ti.com/wilink8-wlan/wl18xx_fw.git;protocol=git;branch=${BRANCH} \
+        file://0001-Add-Makefile-to-install-firmware-files.patch \
+"
+
+SRCREV = "5ec05007f2662f460f881c5868311fd3ab7e6e71"
+BRANCH = "master"
+
+S = "${WORKDIR}/git"
+
+CLEANBROKEN = "1"
+
+do_compile() {
+    :
+}
+
+do_install() {
+    oe_runmake 'DEST_DIR=${D}' install
+}
+
+FILES:${PN} = "/lib/firmware/ti-connectivity/*"
diff --git a/meta-ti-extras/recipes-connectivity/uim/uim-sysfs_8.5.bb b/meta-ti-extras/recipes-connectivity/uim/uim-sysfs_8.5.bb
new file mode 100644
index 00000000..72e2166f
--- /dev/null
+++ b/meta-ti-extras/recipes-connectivity/uim/uim-sysfs_8.5.bb
@@ -0,0 +1,20 @@
+DESCRIPTION = "Shared Transport Line Discipline User Mode initialisation Manager Daemon"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://uim.c;beginline=1;endline=18;md5=9f0bbfbc10c67689e81a523e2976c31e"
+
+INITSCRIPT_NAME = "uim-sysfs"
+INITSCRIPT_PARAMS = "defaults 03"
+
+inherit update-rc.d
+
+SRCREV = "a75f45be2d5c74fc1dd913d08afc30f09a230aa9"
+SRC_URI = "git://git.ti.com/ti-bt/uim.git"
+
+S = "${WORKDIR}/git"
+
+do_install() {
+        install -d ${D}${bindir}
+        install -m 0755 uim ${D}${bindir}
+        install -d ${D}${sysconfdir}/init.d
+        install -m 0755 scripts/uim-sysfs ${D}${sysconfdir}/init.d
+}
diff --git a/meta-ti-extras/recipes-connectivity/wl18xx-calibrator/wl18xx-calibrator/0001-plt.h-Do-not-define-EFUSE_PARAMETER_TYPE_ENMT-type-e.patch b/meta-ti-extras/recipes-connectivity/wl18xx-calibrator/wl18xx-calibrator/0001-plt.h-Do-not-define-EFUSE_PARAMETER_TYPE_ENMT-type-e.patch
new file mode 100644
index 00000000..fc5542e0
--- /dev/null
+++ b/meta-ti-extras/recipes-connectivity/wl18xx-calibrator/wl18xx-calibrator/0001-plt.h-Do-not-define-EFUSE_PARAMETER_TYPE_ENMT-type-e.patch
@@ -0,0 +1,35 @@
+From e3f694496322d3679dd9b007dc3caa4343f0f376 Mon Sep 17 00:00:00 2001
+From: Khem Raj <raj.khem@gmail.com>
+Date: Tue, 11 Aug 2020 18:12:58 -0700
+Subject: [PATCH] plt.h: Do not define EFUSE_PARAMETER_TYPE_ENMT type enum in
+ header file
+
+gcc10 uses -fno-common by default and this causes multiple definitions
+of this enum in all files including plt.h file, therefore just define
+the type in header file
+
+Fixes
+arm-yoe-linux-musleabi-ld: misc_cmds.o:/usr/src/debug/wl18xx-calibrator/8.7.3-r0/git/./plt.h:402: multiple definition of `EFUSE_PARAMETER_TYPE_ENM'; nvs.o:/usr/src/debug/wl18xx-calibrator/8.7.3-r0/git/./plt.h:402: first defined here
+
+Upstream-Status: Pending
+Signed-off-by: Khem Raj <raj.khem@gmail.com>
+---
+ plt.h | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/plt.h b/plt.h
+index 8b534a9..43d5dbc 100644
+--- a/plt.h
++++ b/plt.h
+@@ -399,7 +399,7 @@ enum EFUSE_PARAMETER_TYPE_ENMT {
+        TX_BIP_PD_BUFFER_VBIAS_ERROR_E,
+        EFUSE_NUMBER_OF_PARAMETERS_E,
+        EFUSE_LAST_PARAMETER_E = (EFUSE_NUMBER_OF_PARAMETERS_E - 1)
+-} EFUSE_PARAMETER_TYPE_ENM;
++};
+ 
+ int get_mac_addr(int ifc_num, unsigned char *mac_addr);
+ 
+-- 
+2.28.0
+
diff --git a/meta-ti-extras/recipes-connectivity/wl18xx-calibrator/wl18xx-calibrator_8.7.3.bb b/meta-ti-extras/recipes-connectivity/wl18xx-calibrator/wl18xx-calibrator_8.7.3.bb
new file mode 100644
index 00000000..2888b95a
--- /dev/null
+++ b/meta-ti-extras/recipes-connectivity/wl18xx-calibrator/wl18xx-calibrator_8.7.3.bb
@@ -0,0 +1,26 @@
+DESCRIPTION = "The calibrator utility for TI wireless solution based on wl18xx driver"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://COPYING;md5=4725015cb0be7be389cf06deeae3683d"
+
+DEPENDS = "libnl"
+RDEPENDS:${PN} = "wl18xx-fw"
+
+#Tag: R8.7_SP3 (8.7.3)
+SRCREV = "5048b59a444ac59ba7171d6e122d5a84581aebf2"
+SRC_URI = "git://git.ti.com/wilink8-wlan/18xx-ti-utils.git \
+           file://0001-plt.h-Do-not-define-EFUSE_PARAMETER_TYPE_ENMT-type-e.patch \  
+          "
+
+S = "${WORKDIR}/git"
+
+export CROSS_COMPILE = "${TARGET_PREFIX}"
+
+EXTRA_OEMAKE = "CFLAGS="${CFLAGS} -I${STAGING_INCDIR}/libnl3/ -DCONFIG_LIBNL32 " \
+                LDFLAGS="${LDFLAGS} -L${STAGING_LIBDIR}" \
+                CC="${CC}" \
+                NLVER=3"
+
+do_install() {
+    install -d ${D}${bindir}
+    install -m 0755 calibrator ${D}${bindir}/
+}
diff --git a/meta-ti-extras/recipes-connectivity/wl18xx-target-scripts/wl18xx-target-scripts/0001-print_stat.sh-replace-system-bin-sh-with-bin-sh.patch b/meta-ti-extras/recipes-connectivity/wl18xx-target-scripts/wl18xx-target-scripts/0001-print_stat.sh-replace-system-bin-sh-with-bin-sh.patch
new file mode 100644
index 00000000..c0719e34
--- /dev/null
+++ b/meta-ti-extras/recipes-connectivity/wl18xx-target-scripts/wl18xx-target-scripts/0001-print_stat.sh-replace-system-bin-sh-with-bin-sh.patch
@@ -0,0 +1,23 @@
+From ba1ac3862c8c3b2dbb615dc342b7fb1eaa96900f Mon Sep 17 00:00:00 2001
+From: Denys Dmytriyenko <denys@ti.com>
+Date: Fri, 10 Nov 2017 17:02:39 -0500
+Subject: [PATCH] print_stat.sh: replace /system/bin/sh with /bin/sh
+
+Signed-off-by: Denys Dmytriyenko <denys@ti.com>
+---
+ testing/print_stat.sh | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/testing/print_stat.sh b/testing/print_stat.sh
+index 681a063..0a519f6 100755
+--- a/testing/print_stat.sh
++++ b/testing/print_stat.sh
+@@ -1,4 +1,4 @@
+-#!/system/bin/sh
++#!/bin/sh
+ 
+ PHY=`ls /sys/class/ieee80211/`
+ mkdir -p /debug
+-- 
+2.7.4
+
diff --git a/meta-ti-extras/recipes-connectivity/wl18xx-target-scripts/wl18xx-target-scripts_8.7.3.bb b/meta-ti-extras/recipes-connectivity/wl18xx-target-scripts/wl18xx-target-scripts_8.7.3.bb
new file mode 100644
index 00000000..2a44fa84
--- /dev/null
+++ b/meta-ti-extras/recipes-connectivity/wl18xx-target-scripts/wl18xx-target-scripts_8.7.3.bb
@@ -0,0 +1,26 @@
+DESCRIPTION = "Scripts and configuration files for TI wireless drivers"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://README;beginline=1;endline=21;md5=b8d6a0865f50159bf5c0d175d1f4a705"
+
+# Tag: R8.7_SP3 (8.7.3)
+SRCREV = "a07b6e711d2a70608101d3d6cdc5749c4d8a96d5"
+BRANCH = "sitara-scripts"
+SRC_URI = "git://git.ti.com/wilink8-wlan/wl18xx-target-scripts.git;protocol=git;branch=${BRANCH} \
+file://0001-print_stat.sh-replace-system-bin-sh-with-bin-sh.patch \
+"
+
+PR = "r1"
+
+S = "${WORKDIR}/git"
+
+FILES:${PN} += "${datadir}/wl18xx/"
+
+do_install() {
+        install -d ${D}${datadir}/wl18xx/
+
+        scripts=`find ./* -type f -name "*.*"`
+        for s in $scripts
+        do
+                install -m 0755 $s ${D}${datadir}/wl18xx/
+        done
+}
diff --git a/meta-ti-extras/recipes-connectivity/wlconf/wlconf_8.7.3.bb b/meta-ti-extras/recipes-connectivity/wlconf/wlconf_8.7.3.bb
new file mode 100644
index 00000000..475bac28
--- /dev/null
+++ b/meta-ti-extras/recipes-connectivity/wlconf/wlconf_8.7.3.bb
@@ -0,0 +1,39 @@
+DESCRIPTION = "Configuration utility for TI wireless drivers"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://README;beginline=1;endline=21;md5=adc05a1903d3f107f85c90328e3a9438"
+
+# Tag: R8.7_SP3 (8.7.3)
+SRCREV = "5048b59a444ac59ba7171d6e122d5a84581aebf2"
+SRC_URI = "git://git.ti.com/wilink8-wlan/18xx-ti-utils.git"
+
+S = "${WORKDIR}/git/wlconf"
+
+EXTRA_OEMAKE = "CC="${CC}""
+
+do_install() {
+        install -d ${D}${sbindir}
+        install -d ${D}${sbindir}/wlconf/
+        install -d ${D}${sbindir}/wlconf/official_inis
+        install -d ${D}/lib/firmware/ti-connectivity
+
+        install -m 0755 wlconf ${D}${sbindir}/wlconf/
+        install -m 0755 dictionary.txt ${D}${sbindir}/wlconf/
+        install -m 0755 struct.bin ${D}${sbindir}/wlconf/
+        install -m 0755 default.conf ${D}${sbindir}/wlconf/
+        install -m 0755 wl18xx-conf-default.bin ${D}${sbindir}/wlconf/
+        install -m 0755 wl18xx-conf-default.bin ${D}/lib/firmware/ti-connectivity/wl18xx-conf.bin
+        install -m 0755 README ${D}${sbindir}/wlconf/
+        install -m 0755 example.conf ${D}${sbindir}/wlconf/
+        install -m 0755 example.ini ${D}${sbindir}/wlconf/
+        install -m 0755 configure-device.sh ${D}${sbindir}/wlconf/
+        install -m 0755 ${S}/official_inis/* \
+                        ${D}${sbindir}/wlconf/official_inis/
+}
+
+FILES:${PN} += " \
+        ${sbindir}/wlconf \
+        ${sbindir}/wlconf/official_inis \
+        /lib/firmware/ti-connectivity/wl18xx-conf.bin \
+"
+
+FILES:${PN}-dbg += "${sbindir}/wlconf/.debug"