meta-ti: create a sub-layer meta-ti-bsp from existing content

Extra sub-layers will be created next and relevant content moved across them.

Signed-off-by: Denys Dmytriyenko <denys@konsulko.com>
Signed-off-by: Ryan Eatmon <reatmon@ti.com>

3 files changed, 185 insertions, 0 deletions

diff --git a/meta-ti-bsp/recipes-graphics/libgal/ti-gc320-libs_5.0.11.p7.bb b/meta-ti-bsp/recipes-graphics/libgal/ti-gc320-libs_5.0.11.p7.bb
new file mode 100644
index 00000000..ab72c109
--- /dev/null
+++ b/meta-ti-bsp/recipes-graphics/libgal/ti-gc320-libs_5.0.11.p7.bb
@@ -0,0 +1,46 @@
+DESCRIPTION = "Userspace libraries for GC320 chipset on TI SoCs"
+HOMEPAGE = "https://git.ti.com/graphics/ti-gc320-libs"
+LICENSE = "TI-TSPA"
+LIC_FILES_CHKSUM = "file://Manifest.html;md5=a9121e8936ace09820d23f7626daaca5"
+
+inherit features_check
+
+REQUIRED_MACHINE_FEATURES = "gc320"
+
+COMPATIBLE_MACHINE = "omap-a15"
+
+CLEANBROKEN = "1"
+
+BRANCH = "ti-${PV}"
+
+SRC_URI = "git://git.ti.com/graphics/ti-gc320-libs.git;protocol=git;branch=${BRANCH}"
+SRCREV = "c0afab259de59909cfe74c01f3f7fbaa147f94b5"
+
+RRECOMMENDS:${PN} = "ti-gc320-driver"
+
+# There's only hardfp version available
+python __anonymous() {
+    tunes = d.getVar("TUNE_FEATURES")
+    if not tunes:
+        return
+    pkgn = d.getVar("PN")
+    pkgv = d.getVar("PV")
+    if "callconvention-hard" not in tunes:
+        bb.warn("%s-%s ONLY supports hardfp mode for now" % (pkgn, pkgv))
+        raise bb.parse.SkipPackage("%s-%s ONLY supports hardfp mode for now" % (pkgn, pkgv))
+}
+
+TARGET_PRODUCT = "jacinto6evm"
+
+PR = "r3"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE += "DESTDIR=${D} TARGET_PRODUCT=${TARGET_PRODUCT} LIBDIR=${libdir}"
+
+do_install() {
+    oe_runmake install
+    chown -R root:root ${D}
+}
+
+INSANE_SKIP:${PN} += "ldflags"
diff --git a/meta-ti-bsp/recipes-graphics/libgles/ti-img-rogue-umlibs_1.13.5776728.bb b/meta-ti-bsp/recipes-graphics/libgles/ti-img-rogue-umlibs_1.13.5776728.bb
new file mode 100644
index 00000000..1ff4b65a
--- /dev/null
+++ b/meta-ti-bsp/recipes-graphics/libgles/ti-img-rogue-umlibs_1.13.5776728.bb
@@ -0,0 +1,69 @@
+DESCRIPTION = "Userspace libraries for PowerVR Rogue GPU on TI SoCs"
+HOMEPAGE = "http://git.ti.com/graphics/ti-img-rogue-umlibs"
+LICENSE = "TI-TFL"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=7232b98c1c58f99e3baa03de5207e76f"
+
+inherit features_check
+
+REQUIRED_MACHINE_FEATURES = "gpu"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "j7"
+
+PR = "r3"
+
+BRANCH = "linuxws/dunfell/k5.10/${PV}"
+
+SRC_URI = "git://git.ti.com/graphics/ti-img-rogue-umlibs.git;branch=${BRANCH}"
+
+SRCREV = "5ef38353c38d921a65ea6df75c7b6ce710b66034"
+
+PVR_SOC ?= "j721e_linux"
+PVR_BUILD ?= "release"
+PVR_WS = "wayland"
+
+INITSCRIPT_NAME = "rc.pvr"
+INITSCRIPT_PARAMS = "defaults 8"
+
+inherit update-rc.d
+
+PROVIDES += "virtual/egl virtual/libgles1 virtual/libgles2 virtual/libgbm"
+
+DEPENDS += "libdrm wayland expat"
+RDEPENDS:${PN} += "bash"
+RDEPENDS:${PN} += "wayland expat"
+
+RPROVIDES:${PN} = "libegl libgles1 libgles2 libgbm"
+RPROVIDES:${PN}-dev = "libegl-dev libgles1-dev libgles2-dev libgbm-dev"
+RPROVIDES:${PN}-dbg = "libegl-dbg libgles1-dbg libgles2-dbg"
+
+RREPLACES:${PN} = "libegl libgles1 liblges2 libgbm"
+RREPLACES:${PN}-dev = "libegl-dev libgles1-dev libgles2-dev libgbm-dev"
+RREPLACES:${PN}-dbg = "libegl-dbg libgles1-dbg libgles2-dbg"
+
+RCONFLICTS:${PN} = "libegl libgles1 libgles2 libgbm"
+RCONFLICTS:${PN}-dev = "libegl-dev libgles1-dev libgles2-dev libgbm-dev"
+RCONFLICTS:${PN}-dbg = "libegl-dbg libgles1-dbg libgles2-dbg"
+
+RRECOMMENDS:${PN} += "ti-img-rogue-driver"
+
+S = "${WORKDIR}/git"
+
+do_install () {
+    oe_runmake install DESTDIR=${D} TARGET_PRODUCT=${PVR_SOC} BUILD=${PVR_BUILD} WINDOW_SYSTEM=${PVR_WS}
+    chown -R root:root ${D}
+}
+
+FILES:${PN} += " ${base_libdir}/firmware/"
+FILES:${PN} += " ${datadir}/"
+
+PACKAGES =+ "${PN}-plugins"
+FILES:${PN}-plugins = "${libdir}/libGLESv2.so ${libdir}/libGLESv1_CM.so ${libdir}/libEGL.so ${libdir}/dri/pvr_dri.so"
+RDEPENDS:${PN} += "${PN}-plugins"
+
+ALLOW_EMPTY:${PN}-plugins = "1"
+
+INSANE_SKIP:${PN} += "ldflags arch already-stripped"
+INSANE_SKIP:${PN}-plugins = "dev-so"
+
+CLEANBROKEN = "1"
diff --git a/meta-ti-bsp/recipes-graphics/libgles/ti-sgx-ddk-um_1.17.4948957.bb b/meta-ti-bsp/recipes-graphics/libgles/ti-sgx-ddk-um_1.17.4948957.bb
new file mode 100644
index 00000000..d4b7a1a6
--- /dev/null
+++ b/meta-ti-bsp/recipes-graphics/libgles/ti-sgx-ddk-um_1.17.4948957.bb
@@ -0,0 +1,70 @@
+DESCRIPTION = "Userspace libraries for PowerVR SGX chipset on TI SoCs"
+HOMEPAGE = "https://git.ti.com/graphics/omap5-sgx-ddk-um-linux"
+LICENSE = "TI-TSPA"
+LIC_FILES_CHKSUM = "file://TI-Linux-Graphics-DDK-UM-Manifest.doc;md5=b17390502bc89535c86cfbbae961a2a8"
+
+inherit features_check
+
+REQUIRED_MACHINE_FEATURES = "gpu"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+COMPATIBLE_MACHINE = "ti33x|ti43x|omap-a15|k3"
+
+PR = "r37"
+
+BRANCH = "ti-img-sgx/dunfell/${PV}"
+
+SRC_URI = "git://git.ti.com/graphics/omap5-sgx-ddk-um-linux.git;protocol=git;branch=${BRANCH}"
+SRCREV = "742cf38aba13e1ba1a910cf1f036a1a212c263b6"
+
+TARGET_PRODUCT:omap-a15 = "jacinto6evm"
+TARGET_PRODUCT:ti33x = "ti335x"
+TARGET_PRODUCT:ti43x = "ti437x"
+TARGET_PRODUCT:k3 = "ti654x"
+
+INITSCRIPT_NAME = "rc.pvr"
+INITSCRIPT_PARAMS = "defaults 8"
+
+inherit update-rc.d
+
+PROVIDES += "virtual/egl virtual/libgles1 virtual/libgles2 virtual/libgbm"
+
+DEPENDS += "libdrm udev wayland wayland-protocols libffi expat"
+DEPENDS:append:libc-musl = " gcompat"
+RDEPENDS:${PN} += "libdrm libdrm-omap udev wayland wayland-protocols libffi expat"
+
+RPROVIDES:${PN} = "libegl libgles1 libgles2 libgbm"
+RPROVIDES:${PN}-dev = "libegl-dev libgles1-dev libgles2-dev libgbm-dev"
+RPROVIDES:${PN}-dbg = "libegl-dbg libgles1-dbg libgles2-dbg libgbm-dbg"
+
+RREPLACES:${PN} = "libegl libgles1 libgles2 libgbm"
+RREPLACES:${PN}-dev = "libegl-dev libgles1-dev libgles2-dev libgbm-dev"
+RREPLACES:${PN}-dbg = "libegl-dbg libgles1-dbg libgles2-dbg libgbm-dbg"
+
+RCONFLICTS:${PN} = "libegl libgles1 libgles2 libgbm"
+RCONFLICTS:${PN}-dev = "libegl-dev libgles1-dev libgles2-dev libgbm-dev"
+RCONFLICTS:${PN}-dbg = "libegl-dbg libgles1-dbg libgles2-dbg libgbm-dbg"
+
+# The actual SONAME is libGLESv2.so.2, so need to explicitly specify RPROVIDES for .so.1 here
+RPROVIDES:${PN} += "libGLESv2.so.1"
+
+RRECOMMENDS:${PN} += "ti-sgx-ddk-km"
+
+S = "${WORKDIR}/git"
+
+do_install () {
+    oe_runmake install DESTDIR=${D} TARGET_PRODUCT=${TARGET_PRODUCT}
+    ln -sf libGLESv2.so ${D}${libdir}/libGLESv2.so.1
+
+    chown -R root:root ${D}
+}
+
+FILES:${PN} =  "${bindir}/*"
+FILES:${PN} += " ${libdir}/*"
+FILES:${PN} +=  "${includedir}/*"
+FILES:${PN} +=  "${sysconfdir}/*"
+
+INSANE_SKIP:${PN} += "dev-so ldflags useless-rpaths"
+INSANE_SKIP:${PN} += "already-stripped dev-deps"
+
+CLEANBROKEN = "1"