meta-ti: create a sub-layer meta-ti-bsp from existing content

Extra sub-layers will be created next and relevant content moved across them.

Signed-off-by: Denys Dmytriyenko <denys@konsulko.com>
Signed-off-by: Ryan Eatmon <reatmon@ti.com>

42 files changed, 924 insertions, 0 deletions

diff --git a/meta-ti-bsp/conf/machine/am335x-evm.conf b/meta-ti-bsp/conf/machine/am335x-evm.conf
new file mode 100644
index 00000000..469c4d37
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/am335x-evm.conf
@@ -0,0 +1,35 @@
+#@TYPE: Machine
+#@NAME: AM335x EVM
+#@DESCRIPTION: Machine configuration for the TI AM335x EVM
+
+require conf/machine/include/ti33x.inc
+
+MACHINE_GUI_CLASS = "smallscreen"
+MACHINE_FEATURES += "touchscreen"
+
+IMAGE_FSTYPES += "ubifs ubi"
+
+# Normally AM335 boards use ttyS0, but ICE uses ttyS3, so try both
+SERIAL_CONSOLES = "115200;ttyS0 115200;ttyS3"
+SERIAL_CONSOLES_CHECK = "${SERIAL_CONSOLES}"
+
+# UBI information.  Note that this is board and kernel specific.  Changes
+# in your kernel port may require changes in these variables.  For more
+# details about this board please see
+# http://processors.wiki.ti.com/index.php/UBIFS_Support
+
+# do ubiattach /dev/ubi_ctrl -m 7 -O 2048
+# From dmesg:
+# UBI: smallest flash I/O unit:    2048
+# UBI: logical eraseblock size:    126976 bytes
+# from ubiattach stdout:
+# UBI device number 0, total 1988 LEBs
+MKUBIFS_ARGS ?= "-F -m 2048 -e 126976 -c 9900"
+
+# do ubiattach /dev/ubi_ctrl -m 7 -O 2048
+# from dmesg:
+# UBI: smallest flash I/O unit:    2048
+# UBI: physical eraseblock size:   131072 bytes (128 KiB)
+# UBI: sub-page size:              512
+# UBI: VID header offset:          2048 (aligned 2048)
+UBINIZE_ARGS ?= "-m 2048 -p 128KiB -s 512 -O 2048"
diff --git a/meta-ti-bsp/conf/machine/am335x-hs-evm.conf b/meta-ti-bsp/conf/machine/am335x-hs-evm.conf
new file mode 100644
index 00000000..7caa5bfd
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/am335x-hs-evm.conf
@@ -0,0 +1,18 @@
+#@TYPE: Machine
+#@NAME: AM335x HS EVM
+#@DESCRIPTION: Machine configuration for the TI AM335x HS EVM
+
+require conf/machine/am335x-evm.conf
+
+UBOOT_MACHINE = ""
+# Last config in the list is default
+UBOOT_CONFIG ??= "uart mmc"
+UBOOT_CONFIG[uart] = "am335x_hs_evm_uart_config"
+UBOOT_CONFIG[mmc] = "am335x_hs_evm_config"
+
+UBOOT_ENTRYPOINT = "0x82000000"
+UBOOT_LOADADDRESS = "0x82000000"
+UBOOT_RD_LOADADDRESS = "0x84000000"
+UBOOT_RD_ENTRYPOINT = "0x84000000"
+
+TI_SECURE_DEV_PKG = "${TI_SECURE_DEV_PKG_CAT}/am3x"
diff --git a/meta-ti-bsp/conf/machine/am437x-evm.conf b/meta-ti-bsp/conf/machine/am437x-evm.conf
new file mode 100644
index 00000000..4e3681d5
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/am437x-evm.conf
@@ -0,0 +1,33 @@
+#@TYPE: Machine
+#@NAME: AM437x EVM
+#@DESCRIPTION: Machine configuration for the TI AM437x EVM
+
+require conf/machine/include/ti43x.inc
+
+MACHINE_GUI_CLASS = "smallscreen"
+MACHINE_FEATURES += "touchscreen"
+
+IMAGE_FSTYPES += "ubifs ubi"
+
+SERIAL_CONSOLES = "115200;ttyS0"
+
+# UBI information.  Note that this is board and kernel specific.  Changes
+# in your kernel port may require changes in these variables.  For more
+# details about this board please see
+# http://processors.wiki.ti.com/index.php/UBIFS_Support
+
+# do ubiattach /dev/ubi_ctrl -m 11 -O 4096
+# From dmesg:
+# UBI: smallest flash I/O unit:    4096
+# UBI: logical eraseblock size:    253952 bytes
+# from ubiattach stdout:
+# UBI device number 0, total 994 LEBs
+MKUBIFS_ARGS = "-F -m 4096 -e 253952 -c 4800"
+
+# do ubiattach /dev/ubi_ctrl -m 11 -O 4096
+# from dmesg:
+# UBI: smallest flash I/O unit:    4096
+# UBI: physical eraseblock size:   262144 bytes (256 KiB)
+# UBI: sub-page size:              4096
+# UBI: VID header offset:          4096 (aligned 4096)
+UBINIZE_ARGS = "-m 4096 -p 256KiB -s 4096 -O 4096"
diff --git a/meta-ti-bsp/conf/machine/am437x-hs-evm.conf b/meta-ti-bsp/conf/machine/am437x-hs-evm.conf
new file mode 100644
index 00000000..68b808d2
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/am437x-hs-evm.conf
@@ -0,0 +1,20 @@
+#@TYPE: Machine
+#@NAME: AM437x HS EVM
+#@DESCRIPTION: Machine configuration for the TI AM437x HS EVM
+
+require conf/machine/am437x-evm.conf
+
+UBOOT_MACHINE = "am43xx_hs_evm_config"
+
+UBOOT_ENTRYPOINT = "0x82000000"
+UBOOT_LOADADDRESS = "0x82000000"
+UBOOT_RD_LOADADDRESS = "0x84000000"
+UBOOT_RD_ENTRYPOINT = "0x84000000"
+
+TI_SECURE_DEV_PKG = "${TI_SECURE_DEV_PKG_CAT}/am4x"
+
+OPTEEMACHINE = "ti-am43xx"
+OPTEEFLAVOR = "am43xx"
+OPTEEOUTPUTMACHINE = "ti"
+
+EXTRA_IMAGEDEPENDS += "optee-os"
diff --git a/meta-ti-bsp/conf/machine/am57xx-evm.conf b/meta-ti-bsp/conf/machine/am57xx-evm.conf
new file mode 100644
index 00000000..eb0082ee
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/am57xx-evm.conf
@@ -0,0 +1,53 @@
+#@TYPE: Machine
+#@NAME: AM57xx EVM
+#@DESCRIPTION: Machine configuration for the TI AM57xx EVM
+
+require conf/machine/include/dra7xx.inc
+
+MACHINE_FEATURES += "touchscreen"
+
+SERIAL_CONSOLES = "115200;ttyS2"
+
+KERNEL_DEVICETREE = " \
+    am57xx-beagle-x15.dtb \
+    am57xx-beagle-x15-revb1.dtb \
+    am57xx-beagle-x15-revc.dtb \
+    am5729-beagleboneai.dtb \
+    am57xx-evm.dtb \
+    ti/am57xx-evm-common.dtbo \
+    am57xx-evm-reva3.dtb \
+    ti/am57xx-evm-reva3.dtbo \
+    am571x-idk.dtb \
+    ti/am571x-idk-touchscreen.dtbo \
+    am572x-idk.dtb \
+    am574x-idk.dtb \
+    ti/am57xx-idk-osd-lcd-common.dtbo \
+    ti/am572x-idk-touchscreen.dtbo \
+    ti/lcd-osd101t2587.dtbo \
+    ti/lcd-osd101t2045.dtbo \
+"
+
+KERNEL_DEVICETREE += "${@oe.utils.conditional('ENABLE_TI_UIO_DEVICES', '1', 'am574x-idk-pru-excl-uio.dtb am572x-idk-pru-excl-uio.dtb am571x-idk-pru-excl-uio.dtb', '', d)}"
+
+UBOOT_MACHINE = "am57xx_evm_config"
+
+# UBI information.  Note that this is board and kernel specific.  Changes
+# in your kernel port may require changes in these variables.  For more
+# details about this board please see
+# http://processors.wiki.ti.com/index.php/UBIFS_Support
+
+# do ubiattach /dev/ubi_ctrl -m 7 -O 2048
+# From dmesg:
+# UBI: smallest flash I/O unit:    2048
+# UBI: logical eraseblock size:    126976 bytes
+# from ubiattach stdout:
+# UBI device number 0, total 1988 LEBs
+MKUBIFS_ARGS = "-F -m 2048 -e 126976 -c 8192"
+
+# do ubiattach /dev/ubi_ctrl -m 7 -O 2048
+# from dmesg:
+# UBI: smallest flash I/O unit:    2048
+# UBI: physical eraseblock size:   131072 bytes (128 KiB)
+# UBI: sub-page size:              512
+# UBI: VID header offset:          2048 (aligned 2048)
+UBINIZE_ARGS = "-m 2048 -p 128KiB -s 512 -O 2048"
diff --git a/meta-ti-bsp/conf/machine/am57xx-hs-evm.conf b/meta-ti-bsp/conf/machine/am57xx-hs-evm.conf
new file mode 100644
index 00000000..5232cbd9
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/am57xx-hs-evm.conf
@@ -0,0 +1,21 @@
+#@TYPE: Machine
+#@NAME: AM57xx HS EVM
+#@DESCRIPTION: Machine configuration for the TI AM57xx HS EVM
+
+require conf/machine/am57xx-evm.conf
+
+UBOOT_MACHINE = "am57xx_hs_evm_config"
+
+UBOOT_ENTRYPOINT = "0x82000000"
+UBOOT_LOADADDRESS = "0x82000000"
+UBOOT_RD_LOADADDRESS = "0x84000000"
+UBOOT_RD_ENTRYPOINT = "0x84000000"
+
+TI_SECURE_DEV_PKG = "${TI_SECURE_DEV_PKG_AUTO}/am5x"
+
+OPTEEMACHINE = "ti-am57xx"
+OPTEEFLAVOR = "am57xx"
+OPTEEOUTPUTMACHINE = "ti"
+OPTEEPAGER = "y"
+
+EXTRA_IMAGEDEPENDS += "optee-os"
diff --git a/meta-ti-bsp/conf/machine/am64xx-evm-k3r5.conf b/meta-ti-bsp/conf/machine/am64xx-evm-k3r5.conf
new file mode 100644
index 00000000..afd36b72
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/am64xx-evm-k3r5.conf
@@ -0,0 +1,11 @@
+#@TYPE: Machine
+#@NAME: AM64xx EVM (R5F)
+#@DESCRIPTION: Machine configuration for the TI AM64xx EVM (R5F core)
+
+require conf/machine/include/k3r5.inc
+
+SYSFW_SOC = "am64x"
+SYSFW_CONFIG = "evm"
+SYSFW_SUFFIX = "gp"
+
+UBOOT_MACHINE = "am64x_evm_r5_defconfig"
diff --git a/meta-ti-bsp/conf/machine/am64xx-evm.conf b/meta-ti-bsp/conf/machine/am64xx-evm.conf
new file mode 100644
index 00000000..c6ba2a87
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/am64xx-evm.conf
@@ -0,0 +1,7 @@
+#@TYPE: Machine
+#@NAME: AM64xx EVM
+#@DESCRIPTION: Machine configuration for the TI AM64xx EVM
+
+require conf/machine/include/am64xx.inc
+
+UBOOT_MACHINE = "am64x_evm_a53_defconfig"
diff --git a/meta-ti-bsp/conf/machine/am64xx-hs-evm-k3r5.conf b/meta-ti-bsp/conf/machine/am64xx-hs-evm-k3r5.conf
new file mode 100644
index 00000000..d12c030f
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/am64xx-hs-evm-k3r5.conf
@@ -0,0 +1,14 @@
+#@TYPE: Machine
+#@NAME: AM64xx HS EVM (R5F)
+#@DESCRIPTION: Machine configuration for the TI AM64xx HS EVM (R5F core)
+
+require conf/machine/include/k3r5.inc
+
+SYSFW_SOC = "am64x"
+SYSFW_CONFIG = "evm"
+SYSFW_SUFFIX = "hs"
+SYSFW_SYMLINK = ""
+
+UBOOT_MACHINE = "am64x_hs_evm_r5_defconfig"
+
+TI_SECURE_DEV_PKG = "${TI_SECURE_DEV_PKG_K3}"
diff --git a/meta-ti-bsp/conf/machine/am64xx-hs-evm.conf b/meta-ti-bsp/conf/machine/am64xx-hs-evm.conf
new file mode 100644
index 00000000..44e81463
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/am64xx-hs-evm.conf
@@ -0,0 +1,22 @@
+#@TYPE: Machine
+#@NAME: AM64xx HS EVM
+#@DESCRIPTION: Machine configuration for the TI AM64xx HS EVM
+
+require conf/machine/include/am64xx.inc
+
+UBOOT_MACHINE = "am64x_hs_evm_a53_defconfig"
+
+UBOOT_ENTRYPOINT =       "0x80080000"
+UBOOT_LOADADDRESS =      "0x80080000"
+UBOOT_RD_LOADADDRESS =   "0x84000000"
+UBOOT_RD_ENTRYPOINT =    "0x84000000"
+UBOOT_DTB_LOADADDRESS =  "0x83000000"
+UBOOT_DTBO_LOADADDRESS = "0x83080000"
+UBOOT_DTBO_OFFSET =      "0x00010000"
+
+SPL_BINARY = "tispl.bin_HS"
+SPL_BINARYNAME = "tispl.bin"
+UBOOT_BINARY = "u-boot.img_HS"
+IMAGE_BOOT_FILES = "${UBOOT_BINARY}"
+
+TI_SECURE_DEV_PKG = "${TI_SECURE_DEV_PKG_K3}"
diff --git a/meta-ti-bsp/conf/machine/am65xx-evm-k3r5-sr2.conf b/meta-ti-bsp/conf/machine/am65xx-evm-k3r5-sr2.conf
new file mode 100644
index 00000000..e74dd3ab
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/am65xx-evm-k3r5-sr2.conf
@@ -0,0 +1,11 @@
+#@TYPE: Machine
+#@NAME: AM65xx SR2.0 EVM (R5F)
+#@DESCRIPTION: Machine configuration for the TI AM65xx SR2.0 EVM (R5F core)
+
+# Booting SR2 requires different SYSFW, the rest is handled at runtime
+
+require conf/machine/am65xx-evm-k3r5.conf
+SOC_FAMILY:append = ":k3r5-sr2"
+
+SYSFW_SOC = "am65x_sr2"
+SYSFW_SYMLINK = "sysfw.itb"
diff --git a/meta-ti-bsp/conf/machine/am65xx-evm-k3r5.conf b/meta-ti-bsp/conf/machine/am65xx-evm-k3r5.conf
new file mode 100644
index 00000000..bd17474e
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/am65xx-evm-k3r5.conf
@@ -0,0 +1,12 @@
+#@TYPE: Machine
+#@NAME: AM65xx EVM (R5F)
+#@DESCRIPTION: Machine configuration for the TI AM65xx EVM (R5F core)
+
+require conf/machine/include/k3r5.inc
+
+SYSFW_SOC = "am65x"
+SYSFW_CONFIG = "evm"
+SYSFW_SUFFIX = "gp"
+SYSFW_SYMLINK = ""
+
+UBOOT_MACHINE = "am65x_evm_r5_defconfig"
diff --git a/meta-ti-bsp/conf/machine/am65xx-evm.conf b/meta-ti-bsp/conf/machine/am65xx-evm.conf
new file mode 100644
index 00000000..8b6ef546
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/am65xx-evm.conf
@@ -0,0 +1,7 @@
+#@TYPE: Machine
+#@NAME: AM65xx EVM
+#@DESCRIPTION: Machine configuration for the TI AM65xx EVM
+
+require conf/machine/include/am65xx.inc
+
+UBOOT_MACHINE = "am65x_evm_a53_defconfig"
diff --git a/meta-ti-bsp/conf/machine/am65xx-hs-evm-k3r5-sr2.conf b/meta-ti-bsp/conf/machine/am65xx-hs-evm-k3r5-sr2.conf
new file mode 100644
index 00000000..ff1645e4
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/am65xx-hs-evm-k3r5-sr2.conf
@@ -0,0 +1,11 @@
+#@TYPE: Machine
+#@NAME: AM65xx SR2.0 HS EVM (R5F)
+#@DESCRIPTION: Machine configuration for the TI AM65xx SR2.0 HS EVM (R5F core)
+
+# Booting SR2 requires different SYSFW, the rest is handled at runtime
+
+require conf/machine/am65xx-hs-evm-k3r5.conf
+SOC_FAMILY:append = ":k3r5-sr2"
+
+SYSFW_SOC = "am65x_sr2"
+SYSFW_SYMLINK = "sysfw.itb"
diff --git a/meta-ti-bsp/conf/machine/am65xx-hs-evm-k3r5.conf b/meta-ti-bsp/conf/machine/am65xx-hs-evm-k3r5.conf
new file mode 100644
index 00000000..d6d4b1e3
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/am65xx-hs-evm-k3r5.conf
@@ -0,0 +1,14 @@
+#@TYPE: Machine
+#@NAME: AM65xx HS EVM (R5F)
+#@DESCRIPTION: Machine configuration for the TI AM65xx HS EVM (R5F core)
+
+require conf/machine/include/k3r5.inc
+
+SYSFW_SOC = "am65x"
+SYSFW_CONFIG = "evm"
+SYSFW_SUFFIX = "hs"
+SYSFW_SYMLINK = ""
+
+UBOOT_MACHINE = "am65x_hs_evm_r5_defconfig"
+
+TI_SECURE_DEV_PKG = "${TI_SECURE_DEV_PKG_K3}"
diff --git a/meta-ti-bsp/conf/machine/am65xx-hs-evm.conf b/meta-ti-bsp/conf/machine/am65xx-hs-evm.conf
new file mode 100644
index 00000000..e4eebb6a
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/am65xx-hs-evm.conf
@@ -0,0 +1,22 @@
+#@TYPE: Machine
+#@NAME: AM65xx HS EVM
+#@DESCRIPTION: Machine configuration for the TI AM65xx HS EVM
+
+require conf/machine/include/am65xx.inc
+
+UBOOT_MACHINE = "am65x_hs_evm_a53_defconfig"
+
+UBOOT_ENTRYPOINT =       "0x80080000"
+UBOOT_LOADADDRESS =      "0x80080000"
+UBOOT_RD_LOADADDRESS =   "0x84000000"
+UBOOT_RD_ENTRYPOINT =    "0x84000000"
+UBOOT_DTB_LOADADDRESS =  "0x83000000"
+UBOOT_DTBO_LOADADDRESS = "0x83080000"
+UBOOT_DTBO_OFFSET =      "0x00010000"
+
+SPL_BINARY = "tispl.bin_HS"
+SPL_BINARYNAME = "tispl.bin"
+UBOOT_BINARY = "u-boot.img_HS"
+IMAGE_BOOT_FILES = "${UBOOT_BINARY}"
+
+TI_SECURE_DEV_PKG = "${TI_SECURE_DEV_PKG_K3}"
diff --git a/meta-ti-bsp/conf/machine/beagle-x15.conf b/meta-ti-bsp/conf/machine/beagle-x15.conf
new file mode 100644
index 00000000..c7503266
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/beagle-x15.conf
@@ -0,0 +1,13 @@
+#@TYPE: Machine
+#@NAME: BeagleBoard X15
+#@DESCRIPTION: Machine configuration for the BeagleBoard X15
+
+require conf/machine/include/dra7xx.inc
+
+KERNEL_DEVICETREE = "am57xx-beagle-x15.dtb am57xx-beagle-x15-revb1.dtb am57xx-beagle-x15-revc.dtb"
+
+MACHINE_GUI_CLASS = "bigscreen"
+
+SERIAL_CONSOLES = "115200;ttyS2"
+
+UBOOT_MACHINE = "am57xx_evm_config"
diff --git a/meta-ti-bsp/conf/machine/beaglebone.conf b/meta-ti-bsp/conf/machine/beaglebone.conf
new file mode 100644
index 00000000..cce8fd09
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/beaglebone.conf
@@ -0,0 +1,16 @@
+#@TYPE: Machine
+#@NAME: BeagleBone machine
+#@DESCRIPTION: Machine configuration for the http://beagleboard.org/bone board
+
+require conf/machine/include/ti33x.inc
+
+KERNEL_DEVICETREE = "am335x-bone.dtb am335x-boneblue.dtb \
+                    am335x-boneblack.dtb am335x-boneblack-wireless.dtb \
+                    am335x-bonegreen.dtb am335x-bonegreen-wireless.dtb"
+
+# Only has DVI connector for external screen
+MACHINE_GUI_CLASS = "bigscreen"
+
+SERIAL_CONSOLES = "115200;ttyS0"
+
+IMAGE_INSTALL:append = " kernel-devicetree kernel-image-zimage"
diff --git a/meta-ti-bsp/conf/machine/dra7xx-evm.conf b/meta-ti-bsp/conf/machine/dra7xx-evm.conf
new file mode 100644
index 00000000..5fa1dfa5
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/dra7xx-evm.conf
@@ -0,0 +1,48 @@
+#@TYPE: Machine
+#@NAME: DRA7xx EVM
+#@DESCRIPTION: Machine configuration for the TI DRA7xx EVM
+
+require conf/machine/include/dra7xx.inc
+
+MACHINE_FEATURES += "touchscreen"
+
+SERIAL_CONSOLES = "115200;ttyS0"
+
+KERNEL_DEVICETREE = " \
+    dra7-evm.dtb \
+    ti/dra7x-evm-osd-lcd-common.dtbo \
+    dra71-evm.dtb \
+    dra71-evm-nand.dtb \
+    ti/dra71-evm-lcd-auo-g101evn01.0.dtbo \
+    dra72-evm.dtb \
+    dra72-evm-revc.dtb \
+    ti/dra72-evm-touchscreen.dtbo \
+    ti/dra74-evm-touchscreen.dtbo \
+    dra76-evm.dtb \
+    ti/dra76-evm-tfp410.dtbo \
+    ti/lcd-osd101t2045.dtbo \
+    ti/lcd-osd101t2587.dtbo \
+"
+
+UBOOT_MACHINE = "dra7xx_evm_config"
+
+# UBI information.  Note that this is board and kernel specific.  Changes
+# in your kernel port may require changes in these variables.  For more
+# details about this board please see
+# http://processors.wiki.ti.com/index.php/UBIFS_Support
+
+# do ubiattach /dev/ubi_ctrl -m 7 -O 2048
+# From dmesg:
+# UBI: smallest flash I/O unit:    2048
+# UBI: logical eraseblock size:    126976 bytes
+# from ubiattach stdout:
+# UBI device number 0, total 1988 LEBs
+MKUBIFS_ARGS = "-F -m 2048 -e 126976 -c 8192"
+
+# do ubiattach /dev/ubi_ctrl -m 7 -O 2048
+# from dmesg:
+# UBI: smallest flash I/O unit:    2048
+# UBI: physical eraseblock size:   131072 bytes (128 KiB)
+# UBI: sub-page size:              512
+# UBI: VID header offset:          2048 (aligned 2048)
+UBINIZE_ARGS = "-m 2048 -p 128KiB -s 512 -O 2048"
diff --git a/meta-ti-bsp/conf/machine/dra7xx-hs-evm.conf b/meta-ti-bsp/conf/machine/dra7xx-hs-evm.conf
new file mode 100644
index 00000000..49630081
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/dra7xx-hs-evm.conf
@@ -0,0 +1,21 @@
+#@TYPE: Machine
+#@NAME: DRA7xx HS EVM
+#@DESCRIPTION: Machine configuration for the TI DRA7xx HS EVM
+
+require conf/machine/dra7xx-evm.conf
+
+UBOOT_MACHINE = "dra7xx_hs_evm_config"
+
+UBOOT_ENTRYPOINT = "0x82000000"
+UBOOT_LOADADDRESS = "0x82000000"
+UBOOT_RD_LOADADDRESS = "0x84000000"
+UBOOT_RD_ENTRYPOINT = "0x84000000"
+
+TI_SECURE_DEV_PKG = "${TI_SECURE_DEV_PKG_AUTO}/dra7"
+
+OPTEEMACHINE = "ti-dra7xx"
+OPTEEFLAVOR = "dra7xx"
+OPTEEOUTPUTMACHINE = "ti"
+OPTEEPAGER = "y"
+
+EXTRA_IMAGEDEPENDS += "optee-os"
diff --git a/meta-ti-bsp/conf/machine/include/am64xx.inc b/meta-ti-bsp/conf/machine/include/am64xx.inc
new file mode 100644
index 00000000..afb96a22
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/include/am64xx.inc
@@ -0,0 +1,24 @@
+require conf/machine/include/k3.inc
+SOC_FAMILY:append = ":am64xx"
+
+MACHINE_FEATURES += "screen touchscreen"
+
+SERIAL_CONSOLES = "115200;ttyS2 115200;ttyS1"
+SERIAL_CONSOLES_CHECK = "${SERIAL_CONSOLES}"
+
+KERNEL_DEVICETREE = " \
+    ti/k3-am642-evm.dtb \
+    ti/k3-am642-sk.dtb \
+    ti/k3-am642-evm-icssg1-dualemac.dtbo \
+    ti/k3-am642-evm-nand.dtbo \
+"
+
+# AM64 supports multi-certificate images, use the same
+IMAGE_BOOT_FILES = "${IMAGE_BOOT_FILES_MULTI_CERT}"
+
+do_image_wic[mcdepends] = "mc::k3r5:ti-sci-fw:do_deploy"
+do_image_tar[mcdepends] = "mc::k3r5:ti-sci-fw:do_deploy"
+
+TFA_BOARD = "lite"
+OPTEEMACHINE = "k3-am65x"
+OPTEEOUTPUTMACHINE = "k3"
diff --git a/meta-ti-bsp/conf/machine/include/am65xx.inc b/meta-ti-bsp/conf/machine/include/am65xx.inc
new file mode 100644
index 00000000..111ef96f
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/include/am65xx.inc
@@ -0,0 +1,32 @@
+require conf/machine/include/k3.inc
+SOC_FAMILY:append = ":am65xx"
+
+MACHINE_FEATURES += "screen touchscreen gpu"
+
+SERIAL_CONSOLES = "115200;ttyS2 115200;ttyS1"
+SERIAL_CONSOLES_CHECK = "${SERIAL_CONSOLES}"
+
+KERNEL_DEVICETREE = " \
+    ti/k3-am654-base-board.dtb \
+    ti/k3-am654-base-board-sr1.dtbo \
+    ti/k3-am654-gp.dtbo \
+    ti/k3-am654-idk.dtbo \
+    ti/k3-am654-idk-sr1.dtbo \
+    ti/k3-am654-sr1.dtbo \
+    ti/k3-am654-pcie-usb2.dtbo \
+    ti/k3-am654-pcie-usb3.dtbo \
+    ti/k3-am654-evm-tc358876.dtbo \
+    ti/k3-am654-evm-oldi-lcd1evm.dtbo \
+    ti/k3-am654-evm-ov5640.dtbo \
+"
+
+BBMULTICONFIG += "k3r5-sr2"
+
+# Use default IMAGE_BOOT_FILES_LEGACY files
+# Since default sysfw.itb on AM65x is for SR2.0, add a version for SR1.0
+IMAGE_BOOT_FILES += "sysfw-am65x-evm.itb"
+do_image_wic[mcdepends] += "mc::k3r5-sr2:ti-sci-fw:do_deploy"
+do_image_tar[mcdepends] += "mc::k3r5-sr2:ti-sci-fw:do_deploy"
+
+OPTEEMACHINE = "k3-am65x"
+OPTEEOUTPUTMACHINE = "k3"
diff --git a/meta-ti-bsp/conf/machine/include/dra7xx.inc b/meta-ti-bsp/conf/machine/include/dra7xx.inc
new file mode 100644
index 00000000..a02421d9
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/include/dra7xx.inc
@@ -0,0 +1,4 @@
+require conf/machine/include/omap-a15.inc
+SOC_FAMILY:append = ":dra7xx"
+
+MACHINE_FEATURES += "pci"
diff --git a/meta-ti-bsp/conf/machine/include/j7.inc b/meta-ti-bsp/conf/machine/include/j7.inc
new file mode 100644
index 00000000..4ea3a5d8
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/include/j7.inc
@@ -0,0 +1,7 @@
+require conf/machine/include/k3.inc
+SOC_FAMILY:append = ":j7"
+
+OPTEEMACHINE = "k3-j721e"
+OPTEEOUTPUTMACHINE = "k3"
+
+# Use default IMAGE_BOOT_FILES_LEGACY files
diff --git a/meta-ti-bsp/conf/machine/include/k3.inc b/meta-ti-bsp/conf/machine/include/k3.inc
new file mode 100644
index 00000000..a39ddd2a
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/include/k3.inc
@@ -0,0 +1,55 @@
+# TI K3 Aarch64 profile for Cortex-A53/A72 cores
+
+require conf/machine/include/ti-soc.inc
+SOC_FAMILY:append = ":k3"
+
+require conf/machine/include/arm/arch-arm64.inc
+
+BBMULTICONFIG += "k3r5"
+
+# Increase this everytime you change something in the kernel
+MACHINE_KERNEL_PR = "r0"
+
+PREFERRED_PROVIDER_virtual/kernel ?= "linux-ti-staging"
+PREFERRED_PROVIDER_virtual/bootloader = "u-boot-ti-staging"
+PREFERRED_PROVIDER_u-boot = "u-boot-ti-staging"
+
+KERNEL_IMAGETYPE = "Image"
+KERNEL_IMAGETYPES = "Image vmlinux.gz"
+
+UBOOT_ARCH = "arm"
+UBOOT_ENTRYPOINT = "0x80008000"
+UBOOT_LOADADDRESS = "0x80008000"
+
+SPL_BINARY = "tispl.bin"
+UBOOT_SUFFIX = "img"
+
+EXTRA_IMAGEDEPENDS += "virtual/bootloader"
+
+TFA_PLATFORM = "k3"
+TFA_BOARD = "generic"
+
+MACHINE_GUI_CLASS = "smallscreen"
+
+# Use the expected value of the ubifs filesystem's volume name in the kernel
+# and u-boot.
+UBI_VOLNAME = "rootfs"
+
+# List common SoC features, may need to add touchscreen for specific machines
+MACHINE_FEATURES = "kernel26 apm usbgadget usbhost vfat ext2 alsa ethernet pci"
+
+IMAGE_FSTYPES += "tar.xz wic.xz wic.bmap"
+
+IMAGE_BOOT_FILES_LEGACY = "${SPL_BINARY} u-boot.${UBOOT_SUFFIX} tiboot3.bin sysfw.itb"
+IMAGE_BOOT_FILES_MULTI_CERT = "${SPL_BINARY} u-boot.${UBOOT_SUFFIX} tiboot3.bin"
+
+IMAGE_BOOT_FILES ?= "${IMAGE_BOOT_FILES_LEGACY}"
+IMAGE_EFI_BOOT_FILES ?= "${IMAGE_BOOT_FILES}"
+
+EFI_PROVIDER ?= "grub-efi"
+MACHINE_FEATURES += "efi"
+
+WKS_FILE ?= "sdimage-2part-efi.wks"
+do_image_wic[depends] += "virtual/bootloader:do_deploy"
+do_image_wic[mcdepends] += "mc::k3r5:virtual/bootloader:do_deploy mc::k3r5:ti-sci-fw:do_deploy"
+do_image_tar[mcdepends] += "mc::k3r5:virtual/bootloader:do_deploy mc::k3r5:ti-sci-fw:do_deploy"
diff --git a/meta-ti-bsp/conf/machine/include/k3r5.inc b/meta-ti-bsp/conf/machine/include/k3r5.inc
new file mode 100644
index 00000000..3cc79061
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/include/k3r5.inc
@@ -0,0 +1,24 @@
+# TI K3 Armv7 profile for Cortex-R5F cores
+
+require conf/machine/include/ti-soc.inc
+SOC_FAMILY:append = ":k3r5"
+
+# The closest of existing tunes for Cortex-R5F
+DEFAULTTUNE = "armv7athf"
+require conf/machine/include/arm/armv7a/tune-cortexa8.inc
+
+# R5 runs early bootloader and loads SYSFW
+# https://git.ti.com/cgit/ti-u-boot/ti-u-boot/tree/board/ti/am65x/README
+# https://git.ti.com/cgit/ti-u-boot/ti-u-boot/tree/board/ti/j721e/README
+PREFERRED_PROVIDER_virtual/kernel = "linux-dummy"
+PREFERRED_PROVIDER_virtual/bootloader = "u-boot-ti-staging"
+PREFERRED_PROVIDER_u-boot = "u-boot-ti-staging"
+
+SPL_BINARY = ""
+UBOOT_SUFFIX = "bin"
+UBOOT_BINARY = "tiboot3.${UBOOT_SUFFIX}"
+UBOOT_IMAGE = "tiboot3-${MAINMACHINE}-${PV}-${PR}.${UBOOT_SUFFIX}"
+UBOOT_SYMLINK = "tiboot3-${MAINMACHINE}.${UBOOT_SUFFIX}"
+
+PACKAGECONFIG:pn-u-boot-ti-staging = ""
+PACKAGECONFIG:pn-u-boot-ti-mainline = ""
diff --git a/meta-ti-bsp/conf/machine/include/omap-a15.inc b/meta-ti-bsp/conf/machine/include/omap-a15.inc
new file mode 100644
index 00000000..9a2e0044
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/include/omap-a15.inc
@@ -0,0 +1,55 @@
+require conf/machine/include/ti-soc.inc
+SOC_FAMILY:append = ":omap-a15"
+
+DEFAULTTUNE ?= "armv7athf-neon"
+require conf/machine/include/arm/armv7a/tune-cortexa15.inc
+
+# Increase this everytime you change something in the kernel
+MACHINE_KERNEL_PR = "r7"
+
+PREFERRED_PROVIDER_virtual/kernel ?= "linux-ti-staging"
+PREFERRED_PROVIDER_virtual/bootloader = "u-boot-ti-staging"
+PREFERRED_PROVIDER_u-boot = "u-boot-ti-staging"
+
+KERNEL_IMAGETYPE = "zImage"
+KERNEL_IMAGETYPES = "zImage uImage"
+KERNEL_CLASSES += "kernel-uimage"
+
+UBOOT_ARCH = "arm"
+UBOOT_ENTRYPOINT = "0x80008000"
+UBOOT_LOADADDRESS = "0x80008000"
+
+DEVICETREE_FILE = "${@d.getVar('KERNEL_DEVICETREE').replace("ti/","")}"
+
+# Generate an extlinux.conf file
+UBOOT_EXTLINUX = "1"
+UBOOT_EXTLINUX_ROOT = "root=PARTUUID=${uuid}"
+UBOOT_EXTLINUX_BOOT_FILES = " \
+    extlinux.conf;extlinux/extlinux.conf \
+    ${KERNEL_IMAGETYPE} \
+    ${DEVICETREE_FILE} \
+"
+
+SPL_BINARY = "MLO"
+UBOOT_SUFFIX = "img"
+
+EXTRA_IMAGEDEPENDS += "virtual/bootloader"
+
+PREFERRED_PROVIDER_virtual/xserver = "xserver-xorg"
+XSERVER = "xserver-xorg \
+           xf86-input-evdev \
+           xf86-video-fbdev"
+
+MACHINE_GUI_CLASS = "smallscreen"
+
+# Use the expected value of the ubifs filesystem's volume name in the kernel
+# and u-boot.
+UBI_VOLNAME = "rootfs"
+
+# List common SoC features, may need to add touchscreen for specific machines
+MACHINE_FEATURES = "kernel26 apm usbgadget usbhost vfat ext2 screen alsa ethernet gpu mmip dsp gc320"
+
+IMAGE_FSTYPES += "tar.xz wic.xz"
+WKS_FILE ?= "sdimage-2part.wks"
+IMAGE_BOOT_FILES ?= "${SPL_BINARY} u-boot.${UBOOT_SUFFIX} ${UBOOT_EXTLINUX_BOOT_FILES}"
+do_image_wic[depends] += "u-boot:do_deploy"
diff --git a/meta-ti-bsp/conf/machine/include/omapl1.inc b/meta-ti-bsp/conf/machine/include/omapl1.inc
new file mode 100644
index 00000000..d0262c3f
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/include/omapl1.inc
@@ -0,0 +1,2 @@
+require conf/machine/include/ti-soc.inc
+SOC_FAMILY:append = ":omapl1"
diff --git a/meta-ti-bsp/conf/machine/include/omapl138.inc b/meta-ti-bsp/conf/machine/include/omapl138.inc
new file mode 100644
index 00000000..c6eb0cd9
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/include/omapl138.inc
@@ -0,0 +1,2 @@
+require conf/machine/include/omapl1.inc
+SOC_FAMILY:append = ":omapl138"
diff --git a/meta-ti-bsp/conf/machine/include/ti-soc.inc b/meta-ti-bsp/conf/machine/include/ti-soc.inc
new file mode 100644
index 00000000..2792d2a0
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/include/ti-soc.inc
@@ -0,0 +1,5 @@
+# This is a generic TI SOC family. It is a superset of all other SOCs
+# and platforms defined in meta-ti to allow BSP-level overrides.
+SOC_FAMILY = "ti-soc"
+KERNEL_DTB_OVERLAY_SUPPORT ?= "1"
+require conf/machine/include/soc-family.inc
diff --git a/meta-ti-bsp/conf/machine/include/ti33x.inc b/meta-ti-bsp/conf/machine/include/ti33x.inc
new file mode 100644
index 00000000..afb80fd6
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/include/ti33x.inc
@@ -0,0 +1,70 @@
+require conf/machine/include/ti-soc.inc
+SOC_FAMILY:append = ":ti33x"
+
+DEFAULTTUNE ?= "armv7athf-neon"
+require conf/machine/include/arm/armv7a/tune-cortexa8.inc
+
+PREFERRED_PROVIDER_virtual/xserver = "xserver-xorg"
+
+# For built-in LCD, add xf86-input-tslib
+XSERVER = "xserver-xorg \
+           xf86-input-evdev \
+           xf86-input-mouse \
+           xf86-video-fbdev \
+           xf86-input-keyboard"
+
+# Default to external video, change to smallscreen for built-in LCD
+MACHINE_GUI_CLASS = "bigscreen"
+
+# Increase this everytime you change something in the kernel
+MACHINE_KERNEL_PR = "r22"
+
+# Default providers, may need to override for specific machines
+PREFERRED_PROVIDER_virtual/kernel ?= "linux-ti-staging"
+PREFERRED_PROVIDER_virtual/bootloader = "u-boot-ti-staging"
+PREFERRED_PROVIDER_u-boot = "u-boot-ti-staging"
+
+KERNEL_IMAGETYPE = "zImage"
+
+KERNEL_DEVICETREE = " \
+    am335x-evm.dtb am335x-evmsk.dtb \
+    am335x-icev2.dtb \
+    am335x-pocketbeagle.dtb am335x-bone.dtb am335x-boneblue.dtb \
+    am335x-bonegreen.dtb am335x-bonegreen-wireless.dtb \
+    am335x-boneblack.dtb am335x-boneblack-wireless.dtb \
+    am335x-sancloud-bbe.dtb \
+"
+
+KERNEL_DEVICETREE += "${@oe.utils.conditional('ENABLE_TI_UIO_DEVICES', '1', 'am335x-icev2-pru-excl-uio.dtb', '', d)}"
+
+UBOOT_ARCH = "arm"
+UBOOT_MACHINE = "am335x_evm_config"
+
+UBOOT_ENTRYPOINT = "0x80008000"
+UBOOT_LOADADDRESS = "0x80008000"
+
+# Generate an extlinux.conf file
+UBOOT_EXTLINUX = "1"
+UBOOT_EXTLINUX_ROOT = "root=PARTUUID=${uuid}"
+UBOOT_EXTLINUX_BOOT_FILES = " \
+    extlinux.conf;extlinux/extlinux.conf \
+    ${KERNEL_IMAGETYPE} \
+    ${KERNEL_DEVICETREE} \
+"
+
+SPL_BINARY = "MLO"
+UBOOT_SUFFIX = "img"
+
+# Use the expected value of the ubifs filesystem's volume name in the kernel
+# and u-boot.
+UBI_VOLNAME = "rootfs"
+
+EXTRA_IMAGEDEPENDS += "virtual/bootloader"
+
+# List common SoC features, may need to add touchscreen for specific machines
+MACHINE_FEATURES = "kernel26 apm usbgadget usbhost vfat ext2 screen alsa ethernet gpu"
+
+IMAGE_FSTYPES += "tar.xz wic.xz"
+WKS_FILE ?= "sdimage-2part.wks"
+IMAGE_BOOT_FILES ?= "${SPL_BINARY} u-boot.${UBOOT_SUFFIX} ${UBOOT_EXTLINUX_BOOT_FILES}"
+do_image_wic[depends] += "virtual/bootloader:do_deploy"
diff --git a/meta-ti-bsp/conf/machine/include/ti43x.inc b/meta-ti-bsp/conf/machine/include/ti43x.inc
new file mode 100644
index 00000000..2c3a3770
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/include/ti43x.inc
@@ -0,0 +1,67 @@
+require conf/machine/include/ti-soc.inc
+SOC_FAMILY:append = ":ti43x"
+
+DEFAULTTUNE ?= "armv7athf-neon"
+require conf/machine/include/arm/armv7a/tune-cortexa9.inc
+
+PREFERRED_PROVIDER_virtual/xserver = "xserver-xorg"
+
+# For built-in LCD, add xf86-input-tslib
+XSERVER = "xserver-xorg \
+           xf86-input-evdev \
+           xf86-input-mouse \
+           xf86-video-fbdev \
+           xf86-input-keyboard"
+
+# Default to external video, change to smallscreen for built-in LCD
+MACHINE_GUI_CLASS = "bigscreen"
+
+# Increase this everytime you change something in the kernel
+MACHINE_KERNEL_PR = "r3"
+
+# Default providers, may need to override for specific machines
+PREFERRED_PROVIDER_virtual/kernel ?= "linux-ti-staging"
+PREFERRED_PROVIDER_virtual/bootloader = "u-boot-ti-staging"
+PREFERRED_PROVIDER_u-boot = "u-boot-ti-staging"
+
+KERNEL_IMAGETYPE = "zImage"
+
+KERNEL_DEVICETREE = " \
+    am437x-gp-evm.dtb am437x-gp-evm-hdmi.dtb \
+    am437x-sk-evm.dtb am437x-idk-evm.dtb \
+    am43x-epos-evm.dtb am43x-epos-evm-hdmi.dtb \
+"
+
+KERNEL_DEVICETREE += "${@oe.utils.conditional('ENABLE_TI_UIO_DEVICES', '1', 'am437x-idk-pru-excl-uio.dtb', '', d)}"
+
+UBOOT_ARCH = "arm"
+UBOOT_MACHINE = "am43xx_evm_config"
+
+UBOOT_ENTRYPOINT = "0x80008000"
+UBOOT_LOADADDRESS = "0x80008000"
+
+# Generate an extlinux.conf file
+UBOOT_EXTLINUX = "1"
+UBOOT_EXTLINUX_ROOT = "root=PARTUUID=${uuid}"
+UBOOT_EXTLINUX_BOOT_FILES = " \
+    extlinux.conf;extlinux/extlinux.conf \
+    ${KERNEL_IMAGETYPE} \
+    ${KERNEL_DEVICETREE} \
+"
+
+SPL_BINARY = "MLO"
+UBOOT_SUFFIX = "img"
+
+# Use the expected value of the ubifs filesystem's volume name in the kernel
+# and u-boot.
+UBI_VOLNAME = "rootfs"
+
+EXTRA_IMAGEDEPENDS += "u-boot"
+
+# List common SoC features, may need to add touchscreen for specific machines
+MACHINE_FEATURES = "kernel26 apm usbgadget usbhost vfat ext2 screen alsa ethernet gpu"
+
+IMAGE_FSTYPES += "tar.xz wic.xz"
+WKS_FILE ?= "sdimage-2part.wks"
+IMAGE_BOOT_FILES ?= "${SPL_BINARY} u-boot.${UBOOT_SUFFIX} ${UBOOT_EXTLINUX_BOOT_FILES}"
+do_image_wic[depends] += "u-boot:do_deploy"
diff --git a/meta-ti-bsp/conf/machine/j7-evm-k3r5.conf b/meta-ti-bsp/conf/machine/j7-evm-k3r5.conf
new file mode 100644
index 00000000..b9e8cc01
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/j7-evm-k3r5.conf
@@ -0,0 +1,11 @@
+#@TYPE: Machine
+#@NAME: J7 EVM (R5F)
+#@DESCRIPTION: Machine configuration for the TI J7 EVM (R5F core)
+
+require conf/machine/include/k3r5.inc
+
+SYSFW_SOC = "j721e"
+SYSFW_CONFIG = "evm"
+SYSFW_SUFFIX = "gp"
+
+UBOOT_MACHINE = "j721e_evm_r5_defconfig"
diff --git a/meta-ti-bsp/conf/machine/j7-evm.conf b/meta-ti-bsp/conf/machine/j7-evm.conf
new file mode 100644
index 00000000..267a5e14
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/j7-evm.conf
@@ -0,0 +1,18 @@
+#@TYPE: Machine
+#@NAME: J7 EVM
+#@DESCRIPTION: Machine configuration for the TI J7 EVM
+
+require conf/machine/include/j7.inc
+
+MACHINE_FEATURES += "gpu"
+
+SERIAL_CONSOLES = "115200;ttyS2 115200;ttyS3"
+SERIAL_CONSOLES_CHECK = "${SERIAL_CONSOLES}"
+
+KERNEL_DEVICETREE = " \
+    ti/k3-j721e-common-proc-board.dtb \
+    ti/k3-j721e-common-proc-board-infotainment.dtbo \
+    ti/k3-j721e-sk.dtb \
+"
+
+UBOOT_MACHINE = "j721e_evm_a72_config"
diff --git a/meta-ti-bsp/conf/machine/j7-hs-evm-k3r5-sr1-1.conf b/meta-ti-bsp/conf/machine/j7-hs-evm-k3r5-sr1-1.conf
new file mode 100644
index 00000000..73f5afd6
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/j7-hs-evm-k3r5-sr1-1.conf
@@ -0,0 +1,11 @@
+#@TYPE: Machine
+#@NAME: J7 SR1.1 HS EVM (R5F)
+#@DESCRIPTION: Machine configuration for the TI J7 SR1.1 HS EVM (R5F core)
+
+# Booting SR1.1 requires different SYSFW, the rest is handled at runtime
+
+require conf/machine/j7-hs-evm-k3r5.conf
+SOC_FAMILY:append = ":k3r5-sr1-1"
+
+SYSFW_SOC = "j721e_sr1_1"
+SYSFW_SYMLINK = "sysfw.itb"
diff --git a/meta-ti-bsp/conf/machine/j7-hs-evm-k3r5.conf b/meta-ti-bsp/conf/machine/j7-hs-evm-k3r5.conf
new file mode 100644
index 00000000..53a7016f
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/j7-hs-evm-k3r5.conf
@@ -0,0 +1,13 @@
+#@TYPE: Machine
+#@NAME: J7 HS EVM (R5F)
+#@DESCRIPTION: Machine configuration for the TI J7 HS EVM (R5F core)
+
+require conf/machine/include/k3r5.inc
+
+SYSFW_SOC = "j721e"
+SYSFW_CONFIG = "evm"
+SYSFW_SUFFIX = "hs"
+
+UBOOT_MACHINE = "j721e_hs_evm_r5_defconfig"
+
+TI_SECURE_DEV_PKG = "${TI_SECURE_DEV_PKG_K3}"
diff --git a/meta-ti-bsp/conf/machine/j7-hs-evm.conf b/meta-ti-bsp/conf/machine/j7-hs-evm.conf
new file mode 100644
index 00000000..f2e3ccf5
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/j7-hs-evm.conf
@@ -0,0 +1,30 @@
+#@TYPE: Machine
+#@NAME: J7 HS EVM
+#@DESCRIPTION: Machine configuration for the TI J7 HS EVM
+
+require conf/machine/j7-evm.conf
+
+UBOOT_MACHINE = "j721e_hs_evm_a72_defconfig"
+
+UBOOT_ENTRYPOINT =       "0x80080000"
+UBOOT_LOADADDRESS =      "0x80080000"
+UBOOT_RD_LOADADDRESS =   "0x84000000"
+UBOOT_RD_ENTRYPOINT =    "0x84000000"
+UBOOT_DTB_LOADADDRESS =  "0x83000000"
+UBOOT_DTBO_LOADADDRESS = "0x83080000"
+UBOOT_DTBO_OFFSET =      "0x00010000"
+
+SPL_BINARY = "tispl.bin_HS"
+SPL_BINARYNAME = "tispl.bin"
+UBOOT_BINARY = "u-boot.img_HS"
+IMAGE_BOOT_FILES = "${UBOOT_BINARY}"
+
+BBMULTICONFIG += "k3r5-sr1-1"
+
+# Use default IMAGE_BOOT_FILES_LEGACY files
+# Since default sysfw.itb on J7 is for SR1.1, add a version for SR1.0
+IMAGE_BOOT_FILES += "sysfw-j721e-evm.itb"
+do_image_wic[mcdepends] += "mc::k3r5-sr1-1:ti-sci-fw:do_deploy"
+do_image_tar[mcdepends] += "mc::k3r5-sr1-1:ti-sci-fw:do_deploy"
+
+TI_SECURE_DEV_PKG = "${TI_SECURE_DEV_PKG_K3}"
diff --git a/meta-ti-bsp/conf/machine/j7200-evm-k3r5.conf b/meta-ti-bsp/conf/machine/j7200-evm-k3r5.conf
new file mode 100644
index 00000000..68061883
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/j7200-evm-k3r5.conf
@@ -0,0 +1,11 @@
+#@TYPE: Machine
+#@NAME: J7200 EVM (R5F)
+#@DESCRIPTION: Machine configuration for the TI J7200 EVM (R5F core)
+
+require conf/machine/include/k3r5.inc
+
+SYSFW_SOC = "j7200"
+SYSFW_CONFIG = "evm"
+SYSFW_SUFFIX = "gp"
+
+UBOOT_MACHINE = "j7200_evm_r5_defconfig"
diff --git a/meta-ti-bsp/conf/machine/j7200-evm.conf b/meta-ti-bsp/conf/machine/j7200-evm.conf
new file mode 100644
index 00000000..2565c90c
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/j7200-evm.conf
@@ -0,0 +1,20 @@
+#@TYPE: Machine
+#@NAME: J7200 EVM
+#@DESCRIPTION: Machine configuration for the TI J7200 EVM
+
+require conf/machine/include/j7.inc
+
+SERIAL_CONSOLES = "115200;ttyS2 115200;ttyS3"
+SERIAL_CONSOLES_CHECK = "${SERIAL_CONSOLES}"
+
+KERNEL_DEVICETREE = " \
+    ti/k3-j7200-common-proc-board.dtb \
+"
+
+UBOOT_MACHINE = "j7200_evm_a72_config"
+
+# J7200 supports multi-certificate images, use the same
+IMAGE_BOOT_FILES = "${IMAGE_BOOT_FILES_MULTI_CERT}"
+
+do_image_wic[mcdepends] = "mc::k3r5:ti-sci-fw:do_deploy"
+do_image_tar[mcdepends] = "mc::k3r5:ti-sci-fw:do_deploy"
diff --git a/meta-ti-bsp/conf/machine/j7200-hs-evm-k3r5.conf b/meta-ti-bsp/conf/machine/j7200-hs-evm-k3r5.conf
new file mode 100644
index 00000000..488f19ec
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/j7200-hs-evm-k3r5.conf
@@ -0,0 +1,13 @@
+#@TYPE: Machine
+#@NAME: J7200 HS EVM (R5F)
+#@DESCRIPTION: Machine configuration for the TI J7200 HS EVM (R5F core)
+
+require conf/machine/include/k3r5.inc
+
+SYSFW_SOC = "j7200"
+SYSFW_CONFIG = "evm"
+SYSFW_SUFFIX = "hs"
+
+UBOOT_MACHINE = "j7200_hs_evm_r5_defconfig"
+
+TI_SECURE_DEV_PKG = "${TI_SECURE_DEV_PKG_K3}"
diff --git a/meta-ti-bsp/conf/machine/j7200-hs-evm.conf b/meta-ti-bsp/conf/machine/j7200-hs-evm.conf
new file mode 100644
index 00000000..a5bd637e
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/j7200-hs-evm.conf
@@ -0,0 +1,22 @@
+#@TYPE: Machine
+#@NAME: J7200 HS EVM
+#@DESCRIPTION: Machine configuration for the TI J7200 HS EVM
+
+require conf/machine/j7200-evm.conf
+
+UBOOT_MACHINE = "j7200_hs_evm_a72_defconfig"
+
+UBOOT_ENTRYPOINT =       "0x80080000"
+UBOOT_LOADADDRESS =      "0x80080000"
+UBOOT_RD_LOADADDRESS =   "0x84000000"
+UBOOT_RD_ENTRYPOINT =    "0x84000000"
+UBOOT_DTB_LOADADDRESS =  "0x83000000"
+UBOOT_DTBO_LOADADDRESS = "0x83080000"
+UBOOT_DTBO_OFFSET =      "0x00010000"
+
+SPL_BINARY = "tispl.bin_HS"
+SPL_BINARYNAME = "tispl.bin"
+UBOOT_BINARY = "u-boot.img_HS"
+IMAGE_BOOT_FILES = "${UBOOT_BINARY}"
+
+TI_SECURE_DEV_PKG = "${TI_SECURE_DEV_PKG_K3}"
diff --git a/meta-ti-bsp/conf/machine/omapl138-lcdk.conf b/meta-ti-bsp/conf/machine/omapl138-lcdk.conf
new file mode 100644
index 00000000..ba4d5645
--- /dev/null
+++ b/meta-ti-bsp/conf/machine/omapl138-lcdk.conf
@@ -0,0 +1,19 @@
+#@TYPE: Machine
+#@NAME: OMAP-L138 LCDK
+#@DESCRIPTION: Machine configuration for the TI OMAP-L138 LCDK board
+
+require conf/machine/include/davinci.inc
+require conf/machine/include/omapl138.inc
+
+UBOOT_MACHINE = "omapl138_lcdk_config"
+UBOOT_SUFFIX = "ais"
+SPL_BINARY = ""
+
+UBOOT_ENTRYPOINT = "0xc0008000"
+UBOOT_LOADADDRESS = "0xc0008000"
+
+IMAGE_FSTYPES += "tar.xz"
+
+SERIAL_CONSOLES = "115200;ttyS2"
+
+KERNEL_DEVICETREE = "da850-evm.dtb da850-lcdk.dtb"