cpsw9g-eth-fw: Add CPSW 9G support for J7

Signed-off-by: Santhana Bharathi <santa@ti.com>
Signed-off-by: Denys Dmytriyenko <denys@ti.com>

1 files changed, 43 insertions, 0 deletions

diff --git a/recipes-bsp/cpsw9g-eth-fw/cpsw9g-eth-fw_git.bb b/recipes-bsp/cpsw9g-eth-fw/cpsw9g-eth-fw_git.bb
new file mode 100644
index 00000000..0c86488d
--- /dev/null
+++ b/recipes-bsp/cpsw9g-eth-fw/cpsw9g-eth-fw_git.bb
@@ -0,0 +1,43 @@
+SUMMARY = "R5 PSDK CPSW9G Ethernet Switch Firmware"
+
+LICENSE = "TI-TFL"
+LIC_FILES_CHKSUM = "file://LICENSE.ti;md5=04ad0a015d4bb63c2b9e7b112debf3db"
+
+PV = "1.0+git${SRCPV}"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit deploy
+inherit update-alternatives
+
+PROTOCOL = "git"
+BRANCH = "master"
+SRCREV = "df7f399319ee401dfbda9317878128a0f718507f"
+
+SRC_URI = "git://git.ti.com/glsdk/ti-eth-fw.git;protocol=${PROTOCOL};branch=${BRANCH}"
+
+S = "${WORKDIR}/git"
+
+CPSW9G_FW_DIR = "${S}/ethfw"
+CPSW9G_FW_FILENAME = "app_remoteswitchcfg_server.xer5f"
+
+# make sure that lib/firmware, and all its contents are part of the package
+FILES_${PN} += "${base_libdir}/firmware"
+
+do_install() {
+  install -d ${D}${base_libdir}/firmware
+# Ethernet firmware to be loaded on Main R5 core(needs read permission)
+  install -m 0644 ${CPSW9G_FW_DIR}/${CPSW9G_FW_FILENAME} ${D}${base_libdir}/firmware
+}
+
+TARGET_MAIN_R5FSS0_0 = "j7-main-r5f0_0-fw"
+ALTERNATIVE_${PN} = "j7-main-r5f0_0-fw"
+ALTERNATIVE_LINK_NAME[j7-main-r5f0_0-fw] = "${base_libdir}/firmware/${TARGET_MAIN_R5FSS0_0}"
+ALTERNATIVE_TARGET[j7-main-r5f0_0-fw] = "${base_libdir}/firmware/${CPSW9G_FW_FILENAME}"
+ALTERNATIVE_PRIORITY = "17"
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+INSANE_SKIP_${PN} += "arch"
+
+do_compile[noexec] = "1"
+do_configure[noexec] = "1"