1 files changed, 77 insertions, 0 deletions

diff --git a/recipes-security/audit/audit_2.3.2.bb b/recipes-security/audit/audit_2.3.2.bb
new file mode 100644
index 0000000..bd7b4eb
--- /dev/null
+++ b/recipes-security/audit/audit_2.3.2.bb
@@ -0,0 +1,77 @@
+SUMMARY = "User space tools for kernel auditing"
+DESCRIPTION = "The audit package contains the user space utilities for \
+storing and searching the audit records generated by the audit subsystem \
+in the Linux kernel."
+HOMEPAGE = "http://people.redhat.com/sgrubb/audit/"
+SECTION = "base"
+PR = "r8"
+LICENSE = "GPLv2+ & LGPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
+
+SRC_URI = "http://people.redhat.com/sgrubb/audit/audit-${PV}.tar.gz \
+           file://disable-ldap.patch \
+           file://audit-python.patch \
+           file://audit-python-configure.patch \
+           file://audit-for-cross-compiling.patch \
+           file://auditd \
+           file://fix-swig-host-contamination.patch"
+
+inherit autotools pythonnative update-rc.d
+
+UPDATERCPN = "auditd"
+INITSCRIPT_NAME = "auditd"
+INITSCRIPT_PARAMS = "defaults"
+
+SRC_URI[md5sum] = "4e8d065b5cc16b77b9b61e93a9ed160e"
+SRC_URI[sha256sum] = "8872e0b5392888789061db8034164305ef0e1b34543e1e7004d275f039081d29"
+
+DEPENDS += "python tcp-wrappers libcap-ng linux-libc-headers (>= 2.6.30)"
+
+EXTRA_OECONF += "--without-prelude \
+        --with-libwrap \
+        --enable-gssapi-krb5=no \
+        --disable-ldap \
+        --with-libcap-ng=yes \
+        --with-python=yes \
+        --libdir=${base_libdir} \
+        --sbindir=${base_sbindir} \
+        "
+
+EXTRA_OEMAKE += "PYLIBVER='python${PYTHON_BASEVERSION}' \
+        PYINC='${STAGING_INCDIR}/$(PYLIBVER)' \
+        pyexecdir=${libdir}/python${PYTHON_BASEVERSION}/site-packages \
+        STDINC='${STAGING_INCDIR}' \
+        "
+
+SUMMARY_audispd-plugins = "Plugins for the audit event dispatcher"
+DESCRIPTION_audispd-plugins = "The audispd-plugins package provides plugins for the real-time \
+interface to the audit system, audispd. These plugins can do things \
+like relay events to remote machines or analyze events for suspicious \
+behavior."
+
+PACKAGES =+ "audispd-plugins"
+PACKAGES += "auditd ${PN}-python"
+
+FILES_${PN} = "${sysconfdir}/libaudit.conf ${base_libdir}/libaudit.so.1* ${base_libdir}/libauparse.so.*"
+FILES_auditd += "${bindir}/* ${base_sbindir}/* ${sysconfdir}/*"
+FILES_audispd-plugins += "${sysconfdir}/audisp/audisp-remote.conf \
+        ${sysconfdir}/audisp/plugins.d/au-remote.conf \
+        ${sbindir}/audisp-remote ${localstatedir}/spool/audit \
+        "
+FILES_${PN}-dbg += "${libdir}/python${PYTHON_BASEVERSION}/*/.debug"
+FILES_${PN}-python = "${libdir}/python${PYTHON_BASEVERSION}"
+FILES_${PN}-dev += "${base_libdir}/*.so ${base_libdir}/*.la"
+
+do_install_append() {
+        rm -f ${D}/${libdir}/python${PYTHON_BASEVERSION}/site-packages/*.a
+        rm -f ${D}/${libdir}/python${PYTHON_BASEVERSION}/site-packages/*.la
+
+        # reuse auditd config
+        [ ! -e ${D}/etc/default ] && mkdir ${D}/etc/default
+        mv ${D}/etc/sysconfig/auditd ${D}/etc/default
+        rmdir ${D}/etc/sysconfig/
+
+        # replace init.d
+        install -D -m 0755 ${S}/../auditd ${D}/etc/init.d/auditd
+        rm -rf ${D}/etc/rc.d
+}