setools: upgrade 4.4.0 -> 4.4.1

Changelog:
https://github.com/SELinuxProject/setools/releases/tag/4.4.1

License-Update: Refine COPYING text. No license changes.[1]

[1] https://github.com/SELinuxProject/setools/commit/fff1906ff436835108b62bf46616e19705183dfb

Signed-off-by: Yi Zhao <yi.zhao@windriver.com>
Signed-off-by: Joe MacDonald <joe@deserted.net>

1 files changed, 38 insertions, 0 deletions

diff --git a/recipes-security/setools/setools_4.4.1.bb b/recipes-security/setools/setools_4.4.1.bb
new file mode 100644
index 0000000..8ed8f19
--- /dev/null
+++ b/recipes-security/setools/setools_4.4.1.bb
@@ -0,0 +1,38 @@
+SUMMARY = "Policy analysis tools for SELinux"
+DESCRIPTION = "\
+SETools is a collection of graphical tools, command-line tools, and \
+libraries designed to facilitate SELinux policy analysis."
+SECTION = "base"
+LICENSE = "GPL-2.0-only & LGPL-2.1-only"
+
+SRC_URI = "git://github.com/SELinuxProject/${BPN}.git;branch=4.4;protocol=https \
+           file://setools4-fixes-for-cross-compiling.patch \
+          "
+SRCREV = "bec5c81d4fc41c45c63f0ba19f132fab94f8d2e5"
+
+LIC_FILES_CHKSUM = "file://${S}/COPYING;md5=69a7b68f0a4a570d7c0c43465333ecbc \
+                    file://${S}/COPYING.GPL;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+                    file://${S}/COPYING.LGPL;md5=4fbd65380cdd255951079008b364516c"
+
+S = "${WORKDIR}/git"
+
+DEPENDS = "python3-cython-native libsepol libselinux"
+
+RDEPENDS:${PN} = "python3-networkx python3-setuptools \
+                  python3-logging libselinux-python"
+
+RPROVIDES:${PN} = "${PN}-console"
+
+inherit setuptools3
+
+do_install:prepend() {
+    sed -i -e 's:${RECIPE_SYSROOT}::g' ${S}/setools/policyrep.c
+}
+
+do_install:append() {
+    # Need PyQt5 support, disable gui tools
+    rm -f ${D}${bindir}/apol
+    rm -rf ${D}${libdir}/${PYTHON_DIR}/site-packages/setoolsgui
+    rm -rf ${D}${libdir}/${PYTHON_DIR}/site-packages/setools/__pycache__
+    rm -rf ${D}${libdir}/${PYTHON_DIR}/site-packages/setools/*/__pycache__
+}