blob: 3a40680a45658ede6bf90815db56db90ed8053ab (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
SUMMARY = "Crypto and TLS for C++11"
HOMEPAGE = "https://botan.randombit.net"
LICENSE = "BSD-2-Clause"
LIC_FILES_CHKSUM = "file://license.txt;md5=573e74513ae3057b04757df65b537de0"
SECTION = "libs"
SRC_URI = "https://botan.randombit.net/releases/Botan-${PV}.tar.xz"
SRC_URI[sha256sum] = "67e8dae1ca2468d90de4e601c87d5f31ff492b38e8ab8bcbd02ddf7104ed8a9f"
S = "${WORKDIR}/Botan-${PV}"
inherit python3native siteinfo lib_package
CPU ?= "${TARGET_ARCH}"
CPU:x86 = "x86_32"
CPU:armv7a = "armv7"
CPU:armv7ve = "armv7"
do_configure() {
python3 ${S}/configure.py \
--prefix="${exec_prefix}" \
--libdir="${libdir}" \
--cpu="${CPU}" \
--cc-bin="${CXX}" \
--cxxflags="${CXXFLAGS}" \
--ldflags="${LDFLAGS}" \
--with-endian=${@oe.utils.conditional('SITEINFO_ENDIANNESS', 'le', 'little', 'big', d)} \
${@bb.utils.contains("TUNE_FEATURES","neon","","--disable-neon",d)} \
--with-sysroot-dir=${STAGING_DIR_HOST} \
--with-build-dir="${B}" \
--optimize-for-size \
--with-stack-protector \
--enable-shared-library \
--with-python-versions=3 \
${EXTRA_OECONF}
}
do_compile() {
oe_runmake
}
do_install() {
oe_runmake DESTDIR=${D} install
sed -i -e 's|${WORKDIR}|<scrubbed>|g' ${D}${includedir}/botan-3/botan/build.h
}
PACKAGES += "${PN}-python3"
FILES:${PN}-python3 = "${libdir}/python3"
RDEPENDS:${PN}-python3 += "python3"
COMPATIBLE_HOST:riscv32 = "null"
|