blob: b10a317fad9b2f66a7969bdd49a86677629c2324 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
SUMMARY = "Portable C library for multiline text editing"
HOMEPAGE = "http://projects.gnome.org/gtksourceview/"
LICENSE = "LGPL-2.1-only"
LIC_FILES_CHKSUM = "file://COPYING;md5=fbc093901857fcd118f065f900982c24"
DEPENDS = "gtk+3 libxml2 intltool-native gnome-common-native glib-2.0-native"
PNAME = "gtksourceview"
S = "${WORKDIR}/${PNAME}-${PV}"
inherit gnomebase lib_package gettext features_check gtk-doc gobject-introspection vala
ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
SRC_URI = "https://download.gnome.org/sources/gtksourceview/4.8/${PNAME}-${PV}.tar.xz"
SRC_URI[sha256sum] = "842de7e5cb52000fd810e4be39cd9fe29ffa87477f15da85c18f7b82d45637cc"
GIR_MESON_OPTION = 'gir'
GTKDOC_MESON_OPTION = "gtk_doc"
# Override the definition in meson.bbclass. The dependencies in mason.build are incomplete
# and the recipe will not build with "-j 1". This fix is benign but should be reviewed when
# updating versions.
#
meson_do_compile() {
bbnote "========== generating gtksourceview-gresources.h ========"
bbnote "PARALLEL_MAKE is ${PARALLEL_MAKE}"
ninja ${PARALLEL_MAKE} gtksourceview/gtksourceview-gresources.h
bbnote "========== compiling target all ========"
ninja ${PARALLEL_MAKE}
}
FILES:${PN} += "${datadir}/gtksourceview-4"
|
