blob: 30f0579e2d324f4eab117dc09de7a5127bca82ae (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
SUMMARY = "The GIMP is the GNU Image Manipulation Program"
HOMEPAGE = "http://www.gimp.org"
SECTION = "x11/graphics"
LICENSE = "GPLv3"
LIC_FILES_CHKSUM = "file://COPYING;md5=c678957b0c8e964aa6c70fd77641a71e"
DEPENDS = " \
gdk-pixbuf-native \
intltool-native \
libxslt-native \
gegl-native \
dbus-glib \
gtk+ \
babl \
gegl \
libmypaint \
mypaint-brushes-1.0 \
gexiv2 \
jpeg \
libpng \
libexif \
tiff \
lcms \
poppler \
poppler-data \
jasper \
bzip2 \
libgudev \
libmng \
${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'libxmu libxpm', '', d)} \
"
DEPENDS_append_libc-musl = " libexecinfo"
inherit features_check gnomebase gtk-icon-cache gtk-doc mime-xdg
REQUIRED_DISTRO_FEATURES = "x11"
SHPV = "${@gnome_verdir("${PV}")}"
SRC_URI = "https://download.gimp.org/pub/${BPN}/v${SHPV}/${BP}.tar.bz2"
SRC_URI[md5sum] = "a64f2be299755a2da130306cad9b1d26"
SRC_URI[sha256sum] = "df9b0f11c2078eea1de3ebc66529a5d3854c5e28636cd25a8dd077bd9d6ddc54"
EXTRA_OECONF = "--disable-python \
--without-webkit \
--without-wmf"
do_configure_append() {
find ${B} -name Makefile | xargs sed -i s:'-I$(includedir)':'-I.':g
find ${B} -name Makefile | xargs sed -i s:'-I/usr/include':'-I${STAGING_INCDIR}':g
}
do_compile_prepend() {
# Let native babl/gegl find their plugins
export BABL_PATH=`find ${STAGING_LIBDIR_NATIVE} -maxdepth 1 -name 'babl-*'`
export GEGL_PATH=`find ${STAGING_LIBDIR_NATIVE} -maxdepth 1 -name 'gegl-*'`
}
FILES_${PN} += "${datadir}/metainfo"
RDEPENDS_${PN} += "mypaint-brushes-1.0"
|
