From 38b3de4ad59ffe59ba74b7357f9899271edf1d5f Mon Sep 17 00:00:00 2001
From: Andreas Oberritter <obi@opendreambox.org>
Date: Mon, 20 Jan 2014 16:08:39 +0100
Subject: libconnman-qt: update to 1.0.46, add recipe for qte

* Use _git version suffix, because it really is a Git recipe.
* Create an inc file to be shared between qt4x11 and qt4e.
* Use CONFIG+=notests, because CONFIG+=notest has no effect now.
* Reorder some variables according to style guide.
* Remove unneeded PROVIDES for ${PN}-plugin, which is already listed
  in PACKAGES.
* Hardcode branch to master, because no other branch exists upstream.
* Simplify do_install.
* Don't overwrite EXTRA_QMAKEVARS_PRE, because qt4e.bbclass uses
  it to pass on QT_LIBINFX.
* Generalize QT_IMPORTS_DIR to make it valid for qte.

Signed-off-by: Andreas Oberritter <obi@opendreambox.org>
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
---
 meta-oe/recipes-qt/libconnman-qt/libconnman-qt.inc | 53 +++++++++++++++++
 .../libconnman-qt/libconnman-qt_1.0.7.bb           | 66 ----------------------
 .../recipes-qt/libconnman-qt/libconnman-qt_git.bb  |  3 +
 .../recipes-qt/libconnman-qt/libconnman-qte_git.bb |  3 +
 4 files changed, 59 insertions(+), 66 deletions(-)
 create mode 100644 meta-oe/recipes-qt/libconnman-qt/libconnman-qt.inc
 delete mode 100644 meta-oe/recipes-qt/libconnman-qt/libconnman-qt_1.0.7.bb
 create mode 100644 meta-oe/recipes-qt/libconnman-qt/libconnman-qt_git.bb
 create mode 100644 meta-oe/recipes-qt/libconnman-qt/libconnman-qte_git.bb

(limited to 'meta-oe')

diff --git a/meta-oe/recipes-qt/libconnman-qt/libconnman-qt.inc b/meta-oe/recipes-qt/libconnman-qt/libconnman-qt.inc
new file mode 100644
index 000000000..77e70e899
--- /dev/null
+++ b/meta-oe/recipes-qt/libconnman-qt/libconnman-qt.inc
@@ -0,0 +1,53 @@
+DESCRIPTION = "Qt Library for ConnMan"
+HOMEPAGE = "https://github.com/nemomobile/libconnman-qt"
+SECTION = "qt/lib"
+LICENSE = "Apache-2.0"
+LIC_FILES_CHKSUM = "file://libconnman-qt/clockmodel.h;endline=8;md5=ea9f724050803f15d2d900ce3c5dac88"
+SRCREV = "ddbeaf72b4d3c49285b0513b28948edacfc40b51"
+PV = "1.0.46+git${SRCPV}"
+
+SRC_URI = "git://github.com/nemomobile/libconnman-qt.git;branch=master"
+
+S = "${WORKDIR}/git"
+
+inherit pkgconfig
+
+EXTRA_QMAKEVARS_PRE += "CONFIG+=notests"
+
+do_configure_prepend() {
+    # Hack *.pro variables
+    find ${S}/plugin/*.pro -exec sed -i -e 's,$$\[QT_INSTALL_IMPORTS\],${QT_IMPORTS_DIR},g' '{}' ';'
+}
+do_install() {
+    oe_runmake install INSTALL_ROOT=${D}
+}
+
+PACKAGES =+ "${PN}-plugin ${PN}-plugin-dbg"
+
+RDEPENDS_${PN} = "connman"
+RDEPENDS_${PN}-plugin = "${PN}"
+
+RRECOMMENDS_${PN} = "${PN}-plugin"
+
+FILES_${PN} = " \
+    ${libdir}/libconnman-qt*${SOLIBS} \
+"
+FILES_${PN}-dev = " \
+    ${includedir}/connman-qt*/* \
+    ${libdir}/libconnman-qt*${SOLIBSDEV} \
+    ${libdir}/libconnman-qt*.prl \
+    ${libdir}/pkgconfig/connman-qt*.pc \
+    ${libdir}/connman-qt*.pc \
+"
+FILES_${PN}-plugin = " \
+    ${PLUGINS_TARGET}/qmldir \
+    ${PLUGINS_TARGET}/lib*.so \
+"
+FILES_${PN}-plugin-dbg = " \
+    ${PLUGINS_TARGET}/.debug \
+    ${PLUGINS_TARGET}/.debug/* \
+"
+
+QT_IMPORTS_DIR = "${libdir}/${QT_DIR_NAME}/imports"
+# the plugin target needs to be the same as 'target.path' and 'qmldir.path' in ${S}/plugin/plugin.pro
+PLUGINS_TARGET = "${QT_IMPORTS_DIR}/MeeGo/Connman"
diff --git a/meta-oe/recipes-qt/libconnman-qt/libconnman-qt_1.0.7.bb b/meta-oe/recipes-qt/libconnman-qt/libconnman-qt_1.0.7.bb
deleted file mode 100644
index 2288c4f97..000000000
--- a/meta-oe/recipes-qt/libconnman-qt/libconnman-qt_1.0.7.bb
+++ /dev/null
@@ -1,66 +0,0 @@
-DESCRIPTION = "Qt Library for ConnMan"
-HOMEPAGE = "https://github.com/nemomobile/libconnman-qt"
-LICENSE = "Apache-2.0"
-LIC_FILES_CHKSUM = "file://libconnman-qt/clockmodel.h;endline=8;md5=ea9f724050803f15d2d900ce3c5dac88"
-
-SECTION = "qt/lib"
-
-
-inherit qt4x11 pkgconfig
-
-RDEPENDS_${PN} = "connman"
-RDEPENDS_${PN}-plugin = "${PN}"
-
-PROVIDES += "${PN}-plugin"
-
-PACKAGES =+ "${PN}-plugin ${PN}-plugin-dbg"
-RRECOMMENDS_${PN} = "${PN}-plugin"
-
-BRANCH = "master"
-SRCREV = "6a5e4f981112a90a8c19d82bd671da389d2af993"
-
-SRC_URI = " \
-    git://github.com/nemomobile/${PN}.git;branch=${BRANCH} \
-"
-
-S = "${WORKDIR}/git"
-
-QT_IMPORTS_DIR = "${libdir}/qt4/imports"
-# the plugin target needs to be the same as 'target.path' and 'qmldir.path' in ${S}/plugin/plugin.pro
-PLUGINS_TARGET = "${QT_IMPORTS_DIR}/MeeGo/Connman"
-
-EXTRA_QMAKEVARS_PRE = " \
-    CONFIG+=notest \
-"
-
-do_configure_prepend() {
-    # Hack *.pro variables
-    find ${S}/plugin/*.pro -exec sed -i -e 's,$$\[QT_INSTALL_IMPORTS\],${QT_IMPORTS_DIR},g' '{}' ';'
-}
-
-do_install() {
-    export INSTALL_ROOT=${D}
-    oe_runmake install
-}
-
-FILES_${PN} = " \
-    ${libdir}/libconnman-qt4${SOLIBS} \
-"
-
-FILES_${PN}-dev = " \
-    ${includedir}/connman-qt/* \
-    ${libdir}/libconnman-qt4${SOLIBSDEV} \
-    ${libdir}/libconnman-qt4.prl \
-    ${libdir}/pkgconfig/connman-qt4.pc \
-    ${libdir}/connman-qt4.pc \
-"
-
-FILES_${PN}-plugin = " \
-    ${PLUGINS_TARGET}/qmldir \
-    ${PLUGINS_TARGET}/lib*.so \
-"
-
-FILES_${PN}-plugin-dbg = " \
-    ${PLUGINS_TARGET}/.debug \
-    ${PLUGINS_TARGET}/.debug/* \
-"
diff --git a/meta-oe/recipes-qt/libconnman-qt/libconnman-qt_git.bb b/meta-oe/recipes-qt/libconnman-qt/libconnman-qt_git.bb
new file mode 100644
index 000000000..8d8822c5e
--- /dev/null
+++ b/meta-oe/recipes-qt/libconnman-qt/libconnman-qt_git.bb
@@ -0,0 +1,3 @@
+inherit qt4x11
+
+require libconnman-qt.inc
diff --git a/meta-oe/recipes-qt/libconnman-qt/libconnman-qte_git.bb b/meta-oe/recipes-qt/libconnman-qt/libconnman-qte_git.bb
new file mode 100644
index 000000000..7ee4bdb08
--- /dev/null
+++ b/meta-oe/recipes-qt/libconnman-qt/libconnman-qte_git.bb
@@ -0,0 +1,3 @@
+inherit qt4e
+
+require libconnman-qt.inc
-- 
cgit v1.2.3-54-g00ecf