diff options
Diffstat (limited to 'meta-oe/recipes-support/webkitgtk/webkitgtk3_2.44.3.bb')
-rw-r--r-- | meta-oe/recipes-support/webkitgtk/webkitgtk3_2.44.3.bb | 189 |
1 files changed, 189 insertions, 0 deletions
diff --git a/meta-oe/recipes-support/webkitgtk/webkitgtk3_2.44.3.bb b/meta-oe/recipes-support/webkitgtk/webkitgtk3_2.44.3.bb new file mode 100644 index 000000000..9493d8642 --- /dev/null +++ b/meta-oe/recipes-support/webkitgtk/webkitgtk3_2.44.3.bb | |||
@@ -0,0 +1,189 @@ | |||
1 | SUMMARY = "WebKit web rendering engine for the GTK+ platform" | ||
2 | HOMEPAGE = "https://www.webkitgtk.org/" | ||
3 | BUGTRACKER = "https://bugs.webkit.org/" | ||
4 | |||
5 | LICENSE = "BSD-2-Clause & LGPL-2.0-or-later" | ||
6 | LIC_FILES_CHKSUM = "file://Source/JavaScriptCore/COPYING.LIB;md5=d0c6d6397a5d84286dda758da57bd691 \ | ||
7 | file://Source/WebCore/LICENSE-APPLE;md5=4646f90082c40bcf298c285f8bab0b12 \ | ||
8 | file://Source/WebCore/LICENSE-LGPL-2;md5=36357ffde2b64ae177b2494445b79d21 \ | ||
9 | file://Source/WebCore/LICENSE-LGPL-2.1;md5=a778a33ef338abbaf8b8a7c36b6eec80 \ | ||
10 | " | ||
11 | |||
12 | SRC_URI = "https://www.webkitgtk.org/releases/webkitgtk-${PV}.tar.xz \ | ||
13 | file://0001-FindGObjectIntrospection.cmake-prefix-variables-obta.patch \ | ||
14 | file://reproducibility.patch \ | ||
15 | file://no-musttail-arm.patch \ | ||
16 | file://0001-LowLevelInterpreter.cpp-339-21-error-t6-was-not-decl.patch \ | ||
17 | file://30e1d5e22213fdaca2a29ec3400c927d710a37a8.patch \ | ||
18 | file://0001-Fix-build-issues-with-latest-Clang.patch \ | ||
19 | " | ||
20 | SRC_URI[sha256sum] = "dc82d042ecaca981a4852357c06e5235743319cf10a94cd36ad41b97883a0b54" | ||
21 | |||
22 | inherit cmake pkgconfig gobject-introspection perlnative features_check upstream-version-is-even gi-docgen | ||
23 | |||
24 | S = "${WORKDIR}/webkitgtk-${PV}" | ||
25 | |||
26 | ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}" | ||
27 | REQUIRED_DISTRO_FEATURES = "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'opengl', '', d)}" | ||
28 | |||
29 | CVE_PRODUCT = "webkitgtk webkitgtk\+" | ||
30 | |||
31 | DEPENDS += " \ | ||
32 | ruby-native \ | ||
33 | gperf-native \ | ||
34 | unifdef-native \ | ||
35 | cairo \ | ||
36 | harfbuzz \ | ||
37 | jpeg \ | ||
38 | atk \ | ||
39 | libwebp \ | ||
40 | gtk+3 \ | ||
41 | libxslt \ | ||
42 | libtasn1 \ | ||
43 | libnotify \ | ||
44 | gstreamer1.0 \ | ||
45 | gstreamer1.0-plugins-base \ | ||
46 | glib-2.0-native \ | ||
47 | gettext-native \ | ||
48 | " | ||
49 | |||
50 | PACKAGECONFIG_SOUP ?= "soup3" | ||
51 | PACKAGECONFIG ??= " \ | ||
52 | ${@bb.utils.filter('DISTRO_FEATURES', 'systemd wayland x11', d)} \ | ||
53 | ${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'webgl opengl', '', d)} \ | ||
54 | ${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', 'webgl gles2', d)} \ | ||
55 | ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'opengl-or-es', '', d)} \ | ||
56 | enchant \ | ||
57 | libsecret \ | ||
58 | ${PACKAGECONFIG_SOUP} \ | ||
59 | " | ||
60 | |||
61 | PACKAGECONFIG[wayland] = "-DENABLE_WAYLAND_TARGET=ON,-DENABLE_WAYLAND_TARGET=OFF,wayland libwpe wpebackend-fdo wayland-native" | ||
62 | PACKAGECONFIG[angle] = "-DUSE_ANGLE_WEBGL=ON,-DUSE_ANGLE_WEBGL=OFF" | ||
63 | PACKAGECONFIG[x11] = "-DENABLE_X11_TARGET=ON,-DENABLE_X11_TARGET=OFF,virtual/libx11 libxcomposite libxdamage libxrender libxt" | ||
64 | PACKAGECONFIG[geoclue] = "-DENABLE_GEOLOCATION=ON,-DENABLE_GEOLOCATION=OFF,geoclue" | ||
65 | PACKAGECONFIG[enchant] = "-DENABLE_SPELLCHECK=ON,-DENABLE_SPELLCHECK=OFF,enchant2" | ||
66 | PACKAGECONFIG[gles2] = "-DENABLE_GLES2=ON,-DENABLE_GLES2=OFF,virtual/libgles2" | ||
67 | PACKAGECONFIG[jpegxl] = " -DUSE_JPEGXL=ON,-DUSE_JPEGXL=OFF,libjxl" | ||
68 | PACKAGECONFIG[webgl] = "-DENABLE_WEBGL=ON,-DENABLE_WEBGL=OFF,virtual/egl" | ||
69 | PACKAGECONFIG[opengl] = "-DENABLE_GRAPHICS_CONTEXT_GL=ON,-DENABLE_GRAPHICS_CONTEXT_GL=OFF,virtual/egl" | ||
70 | PACKAGECONFIG[opengl-or-es] = "-DUSE_OPENGL_OR_ES=ON,-DUSE_OPENGL_OR_ES=OFF" | ||
71 | PACKAGECONFIG[libsecret] = "-DUSE_LIBSECRET=ON,-DUSE_LIBSECRET=OFF,libsecret" | ||
72 | PACKAGECONFIG[libhyphen] = "-DUSE_LIBHYPHEN=ON,-DUSE_LIBHYPHEN=OFF,libhyphen" | ||
73 | PACKAGECONFIG[woff2] = "-DUSE_WOFF2=ON,-DUSE_WOFF2=OFF,woff2" | ||
74 | PACKAGECONFIG[openjpeg] = "-DUSE_OPENJPEG=ON,-DUSE_OPENJPEG=OFF,openjpeg" | ||
75 | PACKAGECONFIG[systemd] = "-DUSE_SYSTEMD=ON,-DUSE_SYSTEMD=off,systemd" | ||
76 | PACKAGECONFIG[reduce-size] = "-DCMAKE_BUILD_TYPE=MinSizeRel,-DCMAKE_BUILD_TYPE=Release,," | ||
77 | PACKAGECONFIG[lcms] = "-DUSE_LCMS=ON,-DUSE_LCMS=OFF,lcms" | ||
78 | PACKAGECONFIG[soup2] = "-DUSE_SOUP2=ON,-DUSE_SOUP2=OFF,libsoup-2.4,,,soup3" | ||
79 | PACKAGECONFIG[soup3] = ",,libsoup,,,soup2" | ||
80 | PACKAGECONFIG[journald] = "-DENABLE_JOURNALD_LOG=ON,-DENABLE_JOURNALD_LOG=OFF,systemd" | ||
81 | PACKAGECONFIG[avif] = "-DUSE_AVIF_LOG=ON,-DUSE_AVIF=OFF,libavif" | ||
82 | PACKAGECONFIG[media-recorder] = "-DENABLE_MEDIA_RECORDER=ON,-DENABLE_MEDIA_RECORDER=OFF,gstreamer1.0-plugins-bad" | ||
83 | PACKAGECONFIG[gamepad] = "-DENABLE_GAMEPAD=ON,-DENABLE_GAMEPAD=OFF,libmanette" | ||
84 | PACKAGECONFIG[webrtc] = "-DENABLE_WEB_RTC=ON,-DENABLE_WEB_RTC=OFF" | ||
85 | PACKAGECONFIG[bubblewrap] = "-DENABLE_BUBBLEWRAP_SANDBOX=ON -DBWRAP_EXECUTABLE=${bindir}/bwrap -DDBUS_PROXY_EXECUTABLE=${bindir}/xdg-dbus-proxy,-DENABLE_BUBBLEWRAP_SANDBOX=OFF,,bubblewrap xdg-dbus-proxy" | ||
86 | PACKAGECONFIG[backtrace] = "-DUSE_LIBBACKTRACE=ON,-DUSE_LIBBACKTRACE=OFF,libbacktrace" | ||
87 | |||
88 | EXTRA_OECMAKE = " \ | ||
89 | -DPORT=GTK \ | ||
90 | -DUSE_GTK4=OFF \ | ||
91 | ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-DENABLE_INTROSPECTION=ON', '-DENABLE_INTROSPECTION=OFF', d)} \ | ||
92 | ${@bb.utils.contains('GIDOCGEN_ENABLED', 'True', '-DENABLE_DOCUMENTATION=ON', '-DENABLE_DOCUMENTATION=OFF', d)} \ | ||
93 | -DENABLE_MINIBROWSER=ON \ | ||
94 | -DCMAKE_EXPORT_COMPILE_COMMANDS=OFF \ | ||
95 | " | ||
96 | # Unless DEBUG_BUILD is enabled, pass -g1 to massively reduce the size of the | ||
97 | # debug symbols (4.3GB to 700M at time of writing) | ||
98 | DEBUG_FLAGS:append = "${@oe.utils.vartrue('DEBUG_BUILD', '', ' -g1', d)}" | ||
99 | |||
100 | # Javascript JIT is not supported on ARC | ||
101 | EXTRA_OECMAKE:append:arc = " -DENABLE_JIT=OFF " | ||
102 | # By default 25-bit "medium" calls are used on ARC | ||
103 | # which is not enough for binaries larger than 32 MiB | ||
104 | CFLAGS:append:arc = " -mlong-calls" | ||
105 | CXXFLAGS:append:arc = " -mlong-calls" | ||
106 | |||
107 | # Needed for non-mesa graphics stacks when x11 is disabled | ||
108 | CXXFLAGS += "${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', '-DEGL_NO_X11=1', d)}" | ||
109 | |||
110 | # Javascript JIT is not supported on powerpc | ||
111 | EXTRA_OECMAKE:append:powerpc = " -DENABLE_JIT=OFF " | ||
112 | EXTRA_OECMAKE:append:powerpc64 = " -DENABLE_JIT=OFF " | ||
113 | |||
114 | # ARM JIT code does not build on ARMv4/5/6 anymore | ||
115 | EXTRA_OECMAKE:append:armv4 = " -DENABLE_JIT=OFF " | ||
116 | EXTRA_OECMAKE:append:armv5 = " -DENABLE_JIT=OFF " | ||
117 | EXTRA_OECMAKE:append:armv6 = " -DENABLE_JIT=OFF " | ||
118 | |||
119 | # And for armv7* don't enable it for softfp, because after: | ||
120 | # https://github.com/WebKit/WebKit/commit/a2ec4ef1997d6fafa6ffc607bffb54e76168a918 | ||
121 | # https://bugs.webkit.org/show_bug.cgi?id=242172 | ||
122 | # softfp armv7* fails because WEBASSEMBLY is left enabled by default and JIT gets | ||
123 | # explicitly disabled causing: | ||
124 | # http://errors.yoctoproject.org/Errors/Details/734587/ | ||
125 | # PR was sent upstream, but the end result is the same both JIT and WEBASSEMBLY disabled | ||
126 | # https://github.com/WebKit/WebKit/pull/17447 | ||
127 | EXTRA_OECMAKE:append:armv7a = " -DENABLE_JIT=${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', 'ON', 'OFF', d)}" | ||
128 | EXTRA_OECMAKE:append:armv7r = " -DENABLE_JIT=${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', 'ON', 'OFF', d)}" | ||
129 | EXTRA_OECMAKE:append:armv7ve = " -DENABLE_JIT=${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', 'ON', 'OFF', d)}" | ||
130 | |||
131 | EXTRA_OECMAKE:append:mipsarch = " -DUSE_LD_GOLD=OFF " | ||
132 | EXTRA_OECMAKE:append:powerpc = " -DUSE_LD_GOLD=OFF " | ||
133 | |||
134 | # JIT and gold linker does not work on RISCV | ||
135 | EXTRA_OECMAKE:append:riscv32 = " -DUSE_LD_GOLD=OFF -DENABLE_JIT=OFF" | ||
136 | EXTRA_OECMAKE:append:riscv64 = " -DUSE_LD_GOLD=OFF" | ||
137 | |||
138 | # JIT not supported on MIPS either | ||
139 | EXTRA_OECMAKE:append:mipsarch = " -DENABLE_JIT=OFF -DENABLE_C_LOOP=ON " | ||
140 | |||
141 | # JIT not supported on X32 | ||
142 | # An attempt was made to upstream JIT support for x32 in | ||
143 | # https://bugs.webkit.org/show_bug.cgi?id=100450, but this was closed as | ||
144 | # unresolved due to limited X32 adoption. | ||
145 | EXTRA_OECMAKE:append:x86-x32 = " -DENABLE_JIT=OFF " | ||
146 | |||
147 | SECURITY_CFLAGS:remove:aarch64 = "-fpie" | ||
148 | SECURITY_CFLAGS:append:aarch64 = " -fPIE" | ||
149 | |||
150 | FILES:${PN} += "${libdir}/webkit2gtk-4.*/injected-bundle/libwebkit2gtkinjectedbundle.so" | ||
151 | |||
152 | RRECOMMENDS:${PN} += "ca-certificates shared-mime-info" | ||
153 | |||
154 | # http://errors.yoctoproject.org/Errors/Details/20370/ | ||
155 | ARM_INSTRUCTION_SET:armv4 = "arm" | ||
156 | ARM_INSTRUCTION_SET:armv5 = "arm" | ||
157 | ARM_INSTRUCTION_SET:armv6 = "arm" | ||
158 | |||
159 | # https://bugzilla.yoctoproject.org/show_bug.cgi?id=9474 | ||
160 | # https://bugs.webkit.org/show_bug.cgi?id=159880 | ||
161 | # JSC JIT can build on ARMv7 with -marm, but doesn't work on runtime. | ||
162 | # Upstream only tests regularly the JSC JIT on ARMv7 with Thumb2 (-mthumb). | ||
163 | ARM_INSTRUCTION_SET:armv7a = "thumb" | ||
164 | ARM_INSTRUCTION_SET:armv7r = "thumb" | ||
165 | ARM_INSTRUCTION_SET:armv7ve = "thumb" | ||
166 | |||
167 | # ANGLE requires SSE support as of webkit 2.40.x on 32 bit x86 | ||
168 | COMPATIBLE_HOST:x86 = "${@bb.utils.contains_any('TUNE_FEATURES', 'core2 corei7', '.*', 'null', d)}" | ||
169 | |||
170 | # introspection inside qemu-arm hangs forever on musl/arm builds | ||
171 | # therefore disable GI_DATA | ||
172 | GI_DATA_ENABLED:libc-musl:armv7a = "False" | ||
173 | GI_DATA_ENABLED:libc-musl:armv7ve = "False" | ||
174 | |||
175 | do_install:append() { | ||
176 | mv ${D}${bindir}/WebKitWebDriver ${D}${bindir}/WebKitWebDriver3 | ||
177 | } | ||
178 | |||
179 | PACKAGE_PREPROCESS_FUNCS += "src_package_preprocess" | ||
180 | src_package_preprocess () { | ||
181 | # Trim build paths from comments in generated sources to ensure reproducibility | ||
182 | sed -i -e "s,${WORKDIR},,g" \ | ||
183 | ${B}/JavaScriptCore/DerivedSources/*.h \ | ||
184 | ${B}/JavaScriptCore/DerivedSources/yarr/*.h \ | ||
185 | ${B}/JavaScriptCore/PrivateHeaders/JavaScriptCore/*.h \ | ||
186 | ${B}/WebCore/DerivedSources/*.cpp \ | ||
187 | ${B}/WebKitGTK/DerivedSources/webkit/*.cpp | ||
188 | } | ||
189 | |||