diff options
Diffstat (limited to 'meta-networking/recipes-connectivity/mbedtls/mbedtls_2.28.5.bb')
-rw-r--r-- | meta-networking/recipes-connectivity/mbedtls/mbedtls_2.28.5.bb | 82 |
1 files changed, 82 insertions, 0 deletions
diff --git a/meta-networking/recipes-connectivity/mbedtls/mbedtls_2.28.5.bb b/meta-networking/recipes-connectivity/mbedtls/mbedtls_2.28.5.bb new file mode 100644 index 000000000..a1c283d9e --- /dev/null +++ b/meta-networking/recipes-connectivity/mbedtls/mbedtls_2.28.5.bb | |||
@@ -0,0 +1,82 @@ | |||
1 | SUMMARY = "Lightweight crypto and SSL/TLS library" | ||
2 | DESCRIPTION = "mbedtls is a lean open source crypto library \ | ||
3 | for providing SSL and TLS support in your programs. It offers \ | ||
4 | an intuitive API and documented header files, so you can actually \ | ||
5 | understand what the code does. It features: \ | ||
6 | \ | ||
7 | - Symmetric algorithms, like AES, Blowfish, Triple-DES, DES, ARC4, \ | ||
8 | Camellia and XTEA \ | ||
9 | - Hash algorithms, like SHA-1, SHA-2, RIPEMD-160 and MD5 \ | ||
10 | - Entropy pool and random generators, like CTR-DRBG and HMAC-DRBG \ | ||
11 | - Public key algorithms, like RSA, Elliptic Curves, Diffie-Hellman, \ | ||
12 | ECDSA and ECDH \ | ||
13 | - SSL v3 and TLS 1.0, 1.1 and 1.2 \ | ||
14 | - Abstraction layers for ciphers, hashes, public key operations, \ | ||
15 | platform abstraction and threading \ | ||
16 | " | ||
17 | |||
18 | HOMEPAGE = "https://tls.mbed.org/" | ||
19 | |||
20 | LICENSE = "Apache-2.0" | ||
21 | LIC_FILES_CHKSUM = "file://LICENSE;md5=3b83ef96387f14655fc854ddc3c6bd57" | ||
22 | |||
23 | SECTION = "libs" | ||
24 | |||
25 | S = "${WORKDIR}/git" | ||
26 | SRCREV = "47e8cc9db2e469d902b0e3093ae9e482c3d87188" | ||
27 | SRC_URI = "git://github.com/ARMmbed/mbedtls.git;protocol=https;branch=mbedtls-2.28 \ | ||
28 | file://run-ptest \ | ||
29 | " | ||
30 | |||
31 | inherit cmake update-alternatives ptest | ||
32 | |||
33 | PACKAGECONFIG ??= "shared-libs programs ${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)}" | ||
34 | PACKAGECONFIG[shared-libs] = "-DUSE_SHARED_MBEDTLS_LIBRARY=ON,-DUSE_SHARED_MBEDTLS_LIBRARY=OFF" | ||
35 | PACKAGECONFIG[programs] = "-DENABLE_PROGRAMS=ON,-DENABLE_PROGRAMS=OFF" | ||
36 | PACKAGECONFIG[werror] = "-DMBEDTLS_FATAL_WARNINGS=ON,-DMBEDTLS_FATAL_WARNINGS=OFF" | ||
37 | # Make X.509 and TLS calls use PSA | ||
38 | # https://github.com/Mbed-TLS/mbedtls/blob/development/docs/use-psa-crypto.md | ||
39 | PACKAGECONFIG[psa] = "" | ||
40 | PACKAGECONFIG[tests] = "-DENABLE_TESTING=ON,-DENABLE_TESTING=OFF" | ||
41 | |||
42 | EXTRA_OECMAKE = "-DLIB_INSTALL_DIR:STRING=${libdir}" | ||
43 | |||
44 | # For now the only way to enable PSA is to explicitly pass a -D via CFLAGS | ||
45 | CFLAGS:append = "${@bb.utils.contains('PACKAGECONFIG', 'psa', ' -DMBEDTLS_USE_PSA_CRYPTO', '', d)}" | ||
46 | |||
47 | PROVIDES += "polarssl" | ||
48 | RPROVIDES:${PN} = "polarssl" | ||
49 | |||
50 | PACKAGES =+ "${PN}-programs" | ||
51 | FILES:${PN}-programs = "${bindir}/" | ||
52 | |||
53 | ALTERNATIVE:${PN}-programs = "hello" | ||
54 | ALTERNATIVE_LINK_NAME[hello] = "${bindir}/hello" | ||
55 | |||
56 | BBCLASSEXTEND = "native nativesdk" | ||
57 | |||
58 | CVE_PRODUCT = "mbed_tls" | ||
59 | |||
60 | # Fix merged upstream https://github.com/Mbed-TLS/mbedtls/pull/5310 | ||
61 | CVE_CHECK_IGNORE += "CVE-2021-43666" | ||
62 | # Fix merged upstream https://github.com/Mbed-TLS/mbedtls/commit/9a4a9c66a48edfe9ece03c7e4a53310adf73a86c | ||
63 | CVE_CHECK_IGNORE += "CVE-2021-45451" | ||
64 | |||
65 | # Strip host paths from autogenerated test files | ||
66 | do_compile:append() { | ||
67 | sed -i 's+${S}/++g' ${B}/tests/*.c 2>/dev/null || : | ||
68 | sed -i 's+${B}/++g' ${B}/tests/*.c 2>/dev/null || : | ||
69 | } | ||
70 | |||
71 | # Export source files/headers needed by Arm Trusted Firmware | ||
72 | sysroot_stage_all:append() { | ||
73 | sysroot_stage_dir "${S}/library" "${SYSROOT_DESTDIR}/usr/share/mbedtls-source/library" | ||
74 | sysroot_stage_dir "${S}/include" "${SYSROOT_DESTDIR}/usr/share/mbedtls-source/include" | ||
75 | } | ||
76 | |||
77 | do_install_ptest () { | ||
78 | install -d ${D}${PTEST_PATH}/tests | ||
79 | cp -f ${B}/tests/test_suite_* ${D}${PTEST_PATH}/tests/ | ||
80 | find ${D}${PTEST_PATH}/tests/ -type f -name "*.c" -delete | ||
81 | cp -fR ${S}/tests/data_files ${D}${PTEST_PATH}/tests/ | ||
82 | } | ||