diff options
author | Paul Eggleton <paul.eggleton@linux.intel.com> | 2013-02-11 10:16:25 +0000 |
---|---|---|
committer | Paul Eggleton <paul.eggleton@linux.intel.com> | 2013-02-18 09:28:26 +0000 |
commit | dbb905c9786eb4686ebc85d8e5aad1f481591448 (patch) | |
tree | 0e307d630757b37955d278bf9c60db865c994b31 /meta-webserver/recipes-webadmin/ajenti/ajenti_git.bb | |
parent | cc00595f68cb8f9530b9f2a723e757e18192ab9f (diff) | |
download | meta-openembedded-dbb905c9786eb4686ebc85d8e5aad1f481591448.tar.gz |
ajenti: add new recipe
Add new recipe for the Ajenti web administration interface.
This was developed and tested with assistance from
Kevin Strasser <kevin.strasser@linux.intel.com>
Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com>
Diffstat (limited to 'meta-webserver/recipes-webadmin/ajenti/ajenti_git.bb')
-rw-r--r-- | meta-webserver/recipes-webadmin/ajenti/ajenti_git.bb | 80 |
1 files changed, 80 insertions, 0 deletions
diff --git a/meta-webserver/recipes-webadmin/ajenti/ajenti_git.bb b/meta-webserver/recipes-webadmin/ajenti/ajenti_git.bb new file mode 100644 index 000000000..dc1508eba --- /dev/null +++ b/meta-webserver/recipes-webadmin/ajenti/ajenti_git.bb | |||
@@ -0,0 +1,80 @@ | |||
1 | SUMMARY = "Web-based system administration interface" | ||
2 | HOMEPAGE = "http://ajenti.org" | ||
3 | SECTION = "devel/python" | ||
4 | LICENSE = "LGPLv3" | ||
5 | LIC_FILES_CHKSUM = "file://LICENSE;md5=e6a600fd5e1d9cbde2d983680233ad02" | ||
6 | |||
7 | DEPENDS += "python-pyopenssl python-lxml python-gevent python-greenlet \ | ||
8 | python-psutil python-imaging" | ||
9 | |||
10 | PV = "0.6.2+git${SRCPV}" | ||
11 | |||
12 | SRC_URI = "git://github.com/Eugeny/ajenti.git \ | ||
13 | file://0001-setup.py-remove-extra-data-files.patch \ | ||
14 | file://0002-plugins-hddstat-fix-disk-usage-check-to-work-with-bu.patch \ | ||
15 | file://0003-plugins-sysload-fix-to-work-with-busybox.patch \ | ||
16 | file://0005-plugins-power-fix-shutdown.patch \ | ||
17 | file://0006-plugins-services-add-basic-sysvinit-implementation.patch \ | ||
18 | file://0007-plugins-services-replace-s_upstart-with-s_init-in-MO.patch \ | ||
19 | ${DISTRO_FILES}" | ||
20 | |||
21 | # Allow this to be customised easily | ||
22 | DISTRO_FILES = "file://distro-detection-openembedded.patch \ | ||
23 | file://distributor-logo-openembedded.png" | ||
24 | |||
25 | # Corresponds to the 0.6.2 tag | ||
26 | SRCREV = "c08fb4da65923aebd09116750a1f43f13b98a51a" | ||
27 | |||
28 | S = "${WORKDIR}/git" | ||
29 | |||
30 | inherit setuptools update-rc.d | ||
31 | |||
32 | do_configure_prepend() { | ||
33 | rm ajenti/plugins/dashboard/files/distributor-logo-*.png | ||
34 | cp ${WORKDIR}/distributor-logo-*.png ajenti/plugins/dashboard/files/ | ||
35 | rm plugins/services/s_upstart.py | ||
36 | } | ||
37 | |||
38 | do_install_append() { | ||
39 | install -d ${D}${sysconfdir} | ||
40 | install -d ${D}${sysconfdir}/ajenti | ||
41 | install -m 0644 packaging/files/ajenti.conf ${D}${sysconfdir}/ajenti/ | ||
42 | install -d ${D}${sysconfdir}/ajenti/users | ||
43 | install -m 0644 packaging/files/admin.conf ${D}${sysconfdir}/ajenti/users/ | ||
44 | install -d ${D}${sysconfdir}/init.d | ||
45 | install -m 0755 packaging/files/ajenti ${D}${sysconfdir}/init.d/ | ||
46 | install -d ${D}${localstatedir} | ||
47 | install -d ${D}${localstatedir}/lib | ||
48 | install -d ${D}${localstatedir}/lib/ajenti | ||
49 | install -d ${D}${localstatedir}/lib/ajenti/plugins | ||
50 | install -m 0644 packaging/files/.placeholder ${D}${localstatedir}/lib/ajenti/plugins | ||
51 | |||
52 | for plugin in plugins/* ; do | ||
53 | cp -r $plugin ${D}${localstatedir}/lib/ajenti/plugins/ | ||
54 | done | ||
55 | } | ||
56 | |||
57 | INITSCRIPT_NAME = "ajenti" | ||
58 | INITSCRIPT_PARAMS = "start 99 2 3 4 5 . stop 20 0 1 6 ." | ||
59 | |||
60 | python populate_packages_prepend() { | ||
61 | plugindir = d.expand('${localstatedir}/lib/ajenti/plugins') | ||
62 | do_split_packages(d, plugindir, '(^[^.]*$)', 'ajenti-plugin-%s', 'Ajenti plugin for %s', allow_dirs=True, prepend=False) | ||
63 | } | ||
64 | |||
65 | PACKAGES_DYNAMIC = "ajenti-plugin-*" | ||
66 | FILES_${PN} += "${sysconfdir}/ajenti.conf \ | ||
67 | ${sysconfdir}/ajenti \ | ||
68 | ${sysconfdir}/init.d \ | ||
69 | ${localstatedir}/lib/ajenti/plugins/.placeholder" | ||
70 | RDEPENDS_${PN} += "python-re python-json python-logging python-subprocess \ | ||
71 | python-threading python-setuptools python-netclient \ | ||
72 | python-netserver python-shell python-syslog \ | ||
73 | python-pyopenssl python-lxml python-gevent python-greenlet" | ||
74 | RDEPENDS_${PN}-plugin-taskmgr += "python-psutil" | ||
75 | RDEPENDS_${PN}-plugin-services += "python-psutil" | ||
76 | RDEPENDS_${PN}-plugin-logs += "python-compression" | ||
77 | RDEPENDS_${PN}-plugin-terminal += "python-compression python-codecs python-math \ | ||
78 | python-terminal python-imaging" | ||
79 | RDEPENDS_${PN}-plugin-fm += "python-unixadmin" | ||
80 | |||