ca-certificates: upgrade to 20130119

* old archive is no longer on upstream URL

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
Signed-off-by: Eric Bénard <eric@eukrea.com>

1 files changed, 42 insertions, 0 deletions

diff --git a/meta-oe/recipes-support/ca-certificates/ca-certificates_20130119.bb b/meta-oe/recipes-support/ca-certificates/ca-certificates_20130119.bb
new file mode 100644
index 000000000..5ad4485a0
--- /dev/null
+++ b/meta-oe/recipes-support/ca-certificates/ca-certificates_20130119.bb
@@ -0,0 +1,42 @@
+DESCRIPTION = "Common CA certificates"
+HOMEPAGE = "http://packages.debian.org/sid/ca-certificates"
+SECTION = "misc"
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://debian/copyright;md5=6135800ff6d893c7904d7aad90972eb5"
+
+SRC_URI = "${DEBIAN_MIRROR}/main/c/ca-certificates/ca-certificates_${PV}.tar.gz \
+           file://0001-update-ca-certificates-remove-c-rehash.patch"
+
+SRC_URI[md5sum] = "1fbbec2028a33cf865b79c204aa2e626"
+SRC_URI[sha256sum] = "fb51ec9a2c551838cc1646a0b3c9e6bea5c1bb20ff5d71c542451fac4b191c22"
+
+inherit autotools allarch
+
+do_install_prepend() {
+        mkdir -p ${D}/usr/share/ca-certificates
+        mkdir -p ${D}/usr/sbin
+        mkdir -p ${D}/etc/ssl/certs
+        mkdir -p ${D}/etc/ca-certificates/update.d
+}
+
+do_install_append() {
+        cd ${D}/usr/share/ca-certificates
+        echo "# Lines starting with # will be ignored" > ${D}/etc/ca-certificates.conf
+        echo "# Lines starting with ! will remove certificate on next update" >> ${D}/etc/ca-certificates.conf
+        echo "#" >> ${D}/etc/ca-certificates.conf
+        for crt in $(find . -type f -name '*.crt' -print)
+        do
+                crt=$(echo $crt | sed -e 's/\.\///')
+                echo $crt >> ${D}/etc/ca-certificates.conf
+        done
+}
+
+pkg_postinst_${PN} () {
+if [ -n "$D" ] ; then
+        exit 1
+fi
+
+${sbindir}/update-ca-certificates
+}
+
+CONFFILES_${PN} = "/etc/ca-certificates.conf"