dhcp-relay: upgrade 4.4.2p1 -> 4.4.3

License-Update: The ISC DHCP is licensed under the Mozilla Public
License, MPL 2.0 rather than ISC License now[1][2].

[1] https://www.isc.org/licenses/
[2] https://downloads.isc.org/isc/dhcp/4.4.3/dhcp-4.4.3-RELNOTES

The bundled BIND has been updated to 9.11.36. We don't need to download
it from external anymore.

Signed-off-by: Yi Zhao <yi.zhao@windriver.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

6 files changed, 97 insertions, 118 deletions

diff --git a/meta-networking/recipes-connectivity/dhcp/dhcp-relay_4.4.2p1.bb b/meta-networking/recipes-connectivity/dhcp/dhcp-relay_4.4.2p1.bb
deleted file mode 100644
index 8d4be95cf..000000000
--- a/meta-networking/recipes-connectivity/dhcp/dhcp-relay_4.4.2p1.bb
+++ /dev/null
@@ -1,83 +0,0 @@
-SECTION = "console/network"
-SUMMARY = "Internet Software Consortium DHCP Relay Agent"
-DESCRIPTION = "A DHCP relay agent passes DHCP requests from one \
-LAN to another, so that a DHCP server is not needed on every LAN."
-
-HOMEPAGE = "http://www.isc.org/"
-
-LICENSE = "ISC"
-LIC_FILES_CHKSUM = "file://LICENSE;beginline=4;md5=004a4db50a1e20972e924a8618747c01"
-
-DEPENDS = "openssl libcap zlib chrpath-replacement-native"
-EXTRANATIVEPATH += "chrpath-native"
-
-SRC_URI = "https://ftp.isc.org/isc/dhcp/4.4.2-P1/dhcp-4.4.2-P1.tar.gz \
-           https://ftp.isc.org/isc/bind9/9.11.32/bind-9.11.32.tar.gz;name=bind;unpack=0 \
-           file://default-relay \
-           file://init-relay \
-           file://dhcrelay.service \
-           file://0001-Makefile.am-only-build-dhcrelay.patch \
-           file://0002-bind-version-update-to-latest-version.patch \
-           file://0003-bind-Makefile.in-disable-backtrace.patch \
-           "
-
-SRC_URI[md5sum] = "3089a1ebd20a802ec0870ae337d43907"
-SRC_URI[sha256sum] = "b05e04337539545a8faa0d6ac518defc61a07e5aec66a857f455e7f218c85a1a"
-SRC_URI[bind.md5sum] = "0d029dd06ca60c6739c3189c999ef757"
-SRC_URI[bind.sha256sum] = "cbf8cb4b74dd1452d97c3a2a8c625ea346df8516b4b3508ef07443121a591342"
-
-UPSTREAM_CHECK_URI = "http://ftp.isc.org/isc/dhcp/"
-UPSTREAM_CHECK_REGEX = "(?P<pver>\d+\.\d+\.(\d+?))/"
-
-S = "${WORKDIR}/dhcp-4.4.2-P1"
-
-inherit autotools-brokensep systemd
-
-SYSTEMD_SERVICE:${PN} = "dhcrelay.service"
-SYSTEMD_AUTO_ENABLE:${PN} = "disable"
-
-CFLAGS += "-D_GNU_SOURCE -fcommon"
-LDFLAGS:append = " -pthread"
-
-EXTRA_OECONF = "--enable-paranoia \
-                --disable-static \
-                --enable-libtool \
-                --with-randomdev=/dev/random \
-               "
-
-# Enable shared libs per dhcp README
-do_configure:prepend () {
-    cp configure.ac+lt configure.ac
-    cp ${WORKDIR}/bind-9.11.32.tar.gz ${S}/bind/bind.tar.gz
-}
-
-do_compile:prepend() {
-    # Need to unpack this now instead of earlier as do_configure will delete the configure script
-    rm -rf ${S}/bind/bind-9.11.32/
-    tar xf ${S}/bind/bind.tar.gz -C ${S}/bind
-    install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.guess ${S}/bind/bind-9.11.32/
-    install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.sub ${S}/bind/bind-9.11.32/
-    cp -fpR ${S}/m4/*.m4 ${S}/bind/bind-9.11.32/libtool.m4/
-    rm -rf ${S}/bind/bind-9.11.32/libtool
-    install -m 0755 ${S}/libtool ${S}/bind/bind-9.11.32/
-}
-
-do_install:append () {
-    install -Dm 0644 ${WORKDIR}/default-relay ${D}${sysconfdir}/default/dhcp-relay
-    install -Dm 0755 ${B}/bind/bind-9.11.32/lib/isccfg/.libs/libisccfg.so.163 ${D}${libdir}/libisccfg.so.163
-    install -Dm 0755 ${B}/bind/bind-9.11.32/lib/dns/.libs/libdns.so.1115 ${D}${libdir}/libdns.so.1115
-    chrpath --delete ${D}${libdir}/libisccfg.so.163
-    chrpath --delete ${D}${libdir}/libdns.so.1115
-
-    if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
-        install -d ${D}${systemd_unitdir}/system
-        install -m 0644 ${WORKDIR}/dhcrelay.service ${D}${systemd_unitdir}/system
-        sed -i -e 's,@SBINDIR@,${sbindir},g' ${D}${systemd_unitdir}/system/dhcrelay.service
-        sed -i -e 's,@SYSCONFDIR@,${sysconfdir},g' ${D}${systemd_unitdir}/system/dhcrelay.service
-    else
-        install -d ${D}${sysconfdir}/init.d
-        install -m 0755 ${WORKDIR}/init-relay ${D}${sysconfdir}/init.d/dhcp-relay
-    fi
-}
-
-PARALLEL_MAKE = ""
diff --git a/meta-networking/recipes-connectivity/dhcp/dhcp-relay_4.4.3.bb b/meta-networking/recipes-connectivity/dhcp/dhcp-relay_4.4.3.bb
new file mode 100644
index 000000000..92c648708
--- /dev/null
+++ b/meta-networking/recipes-connectivity/dhcp/dhcp-relay_4.4.3.bb
@@ -0,0 +1,62 @@
+SECTION = "console/network"
+SUMMARY = "Internet Software Consortium DHCP Relay Agent"
+DESCRIPTION = "A DHCP relay agent passes DHCP requests from one \
+LAN to another, so that a DHCP server is not needed on every LAN."
+
+HOMEPAGE = "http://www.isc.org/"
+
+LICENSE = "MPL-2.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=c463f4afde26d9eb60f14f50aeb85f8f"
+
+DEPENDS = "openssl libcap zlib"
+
+SRC_URI = "https://downloads.isc.org/isc/dhcp/${PV}/dhcp-${PV}.tar.gz \
+           file://default-relay \
+           file://init-relay \
+           file://dhcrelay.service \
+           file://0001-Makefile.am-only-build-dhcrelay.patch \
+           file://0002-bind-Makefile.in-disable-backtrace.patch \
+           file://0003-bind-Makefile.in-regenerate-configure.patch \
+           "
+
+SRC_URI[sha256sum] = "0e3ec6b4c2a05ec0148874bcd999a66d05518378d77421f607fb0bc9d0135818"
+
+UPSTREAM_CHECK_URI = "http://ftp.isc.org/isc/dhcp/"
+UPSTREAM_CHECK_REGEX = "(?P<pver>\d+\.\d+\.(\d+?))/"
+
+S = "${WORKDIR}/dhcp-${PV}"
+
+inherit autotools-brokensep systemd pkgconfig
+
+SYSTEMD_SERVICE:${PN} = "dhcrelay.service"
+SYSTEMD_AUTO_ENABLE:${PN} = "disable"
+
+CFLAGS += "-D_GNU_SOURCE -fcommon"
+LDFLAGS:append = " -pthread"
+
+EXTRA_OECONF = "--enable-paranoia \
+                --disable-static \
+                --enable-libtool \
+                --with-randomdev=/dev/random \
+               "
+
+# Enable shared libs per dhcp README
+do_configure:prepend () {
+    cp configure.ac+lt configure.ac
+}
+
+do_install:append () {
+    install -Dm 0644 ${WORKDIR}/default-relay ${D}${sysconfdir}/default/dhcp-relay
+
+    if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
+        install -d ${D}${systemd_unitdir}/system
+        install -m 0644 ${WORKDIR}/dhcrelay.service ${D}${systemd_unitdir}/system
+        sed -i -e 's,@SBINDIR@,${sbindir},g' ${D}${systemd_unitdir}/system/dhcrelay.service
+        sed -i -e 's,@SYSCONFDIR@,${sysconfdir},g' ${D}${systemd_unitdir}/system/dhcrelay.service
+    else
+        install -d ${D}${sysconfdir}/init.d
+        install -m 0755 ${WORKDIR}/init-relay ${D}${sysconfdir}/init.d/dhcp-relay
+    fi
+}
+
+PARALLEL_MAKE = ""
diff --git a/meta-networking/recipes-connectivity/dhcp/files/0001-Makefile.am-only-build-dhcrelay.patch b/meta-networking/recipes-connectivity/dhcp/files/0001-Makefile.am-only-build-dhcrelay.patch
index fed85d2a8..5320d7c9e 100644
--- a/meta-networking/recipes-connectivity/dhcp/files/0001-Makefile.am-only-build-dhcrelay.patch
+++ b/meta-networking/recipes-connectivity/dhcp/files/0001-Makefile.am-only-build-dhcrelay.patch
@@ -1,4 +1,4 @@
-From 17cc080e58894644dd18664ac6f3451096d5f065 Mon Sep 17 00:00:00 2001
+From 4fd67b6adb7c1d8524ba17d1a0b3894f901555a9 Mon Sep 17 00:00:00 2001
 From: Yi Zhao <yi.zhao@windriver.com>
 Date: Thu, 13 May 2021 15:23:16 +0800
 Subject: [PATCH] Makefile.am: only build dhcrelay
@@ -26,5 +26,5 @@ index ed692a5..34f9772 100644
  DIST_SUBDIRS = $(SUBDIRS) keama
  
 -- 
-2.17.1
+2.25.1
 
diff --git a/meta-networking/recipes-connectivity/dhcp/files/0003-bind-Makefile.in-disable-backtrace.patch b/meta-networking/recipes-connectivity/dhcp/files/0002-bind-Makefile.in-disable-backtrace.patch
index 51520bc62..631a640ec 100644
--- a/meta-networking/recipes-connectivity/dhcp/files/0003-bind-Makefile.in-disable-backtrace.patch
+++ b/meta-networking/recipes-connectivity/dhcp/files/0002-bind-Makefile.in-disable-backtrace.patch
@@ -1,4 +1,4 @@
-From bc9c5d64ad4829c7830ef70fcaff94470974247c Mon Sep 17 00:00:00 2001
+From 6c6bbfe6b33e5c7e46a4260d656593dbe610fd8a Mon Sep 17 00:00:00 2001
 From: Yi Zhao <yi.zhao@windriver.com>
 Date: Tue, 8 Jun 2021 10:13:57 +0800
 Subject: [PATCH] bind/Makefile.in: disable backtrace
@@ -14,7 +14,7 @@ Signed-off-by: Yi Zhao <yi.zhao@windriver.com>
  1 file changed, 1 insertion(+), 1 deletion(-)
 
 diff --git a/bind/Makefile.in b/bind/Makefile.in
-index 8fe8883..1058160 100644
+index 2e60091..533d55c 100644
 --- a/bind/Makefile.in
 +++ b/bind/Makefile.in
 @@ -22,7 +22,7 @@ prefix = @prefix@
@@ -27,5 +27,5 @@ index 8fe8883..1058160 100644
         @BINDLT@ @BINDIOMUX@ @BINDCONFIG@ --enable-full-report
  
 -- 
-2.17.1
+2.25.1
 
diff --git a/meta-networking/recipes-connectivity/dhcp/files/0002-bind-version-update-to-latest-version.patch b/meta-networking/recipes-connectivity/dhcp/files/0002-bind-version-update-to-latest-version.patch
deleted file mode 100644
index 5c7a5f058..000000000
--- a/meta-networking/recipes-connectivity/dhcp/files/0002-bind-version-update-to-latest-version.patch
+++ /dev/null
@@ -1,30 +0,0 @@
-From edb68972f8dc636e6208e78f02dec6f9805e4c0b Mon Sep 17 00:00:00 2001
-From: Yi Zhao <yi.zhao@windriver.com>
-Date: Wed, 26 May 2021 11:39:00 +0800
-Subject: [PATCH] bind/version: update to latest version
-
-Update the bundled bind from 9.11.14 to 9.11.32.
-
-Upstream-Status: Inappropriate [embedded specific]
-
-Signed-off-by: Yi Zhao <yi.zhao@windriver.com>
----
- bind/version.tmp | 2 +-
- 1 file changed, 1 insertion(+), 1 deletion(-)
-
-diff --git a/bind/version.tmp b/bind/version.tmp
-index cf52f1b..4cc538e 100644
---- a/bind/version.tmp
-+++ b/bind/version.tmp
-@@ -5,7 +5,7 @@ PRODUCT=BIND
- DESCRIPTION="(Extended Support Version)"
- MAJORVER=9
- MINORVER=11
--PATCHVER=14
-+PATCHVER=32
- RELEASETYPE=
- RELEASEVER=
- EXTENSIONS=
--- 
-2.17.1
-
diff --git a/meta-networking/recipes-connectivity/dhcp/files/0003-bind-Makefile.in-regenerate-configure.patch b/meta-networking/recipes-connectivity/dhcp/files/0003-bind-Makefile.in-regenerate-configure.patch
new file mode 100644
index 000000000..71be0276a
--- /dev/null
+++ b/meta-networking/recipes-connectivity/dhcp/files/0003-bind-Makefile.in-regenerate-configure.patch
@@ -0,0 +1,30 @@
+From 6ca1b224032355521b35471d222d0b09c08369a0 Mon Sep 17 00:00:00 2001
+From: Yi Zhao <yi.zhao@windriver.com>
+Date: Thu, 27 May 2021 11:38:36 +0800
+Subject: [PATCH] bind/Makefile.in: regenerate configure
+
+Run autogen.sh to regenerate configure.
+
+Upstream-Status: Inappropriate [embedded specific]
+
+Signed-off-by: Yi Zhao <yi.zhao@windriver.com>
+---
+ bind/Makefile.in | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+
+diff --git a/bind/Makefile.in b/bind/Makefile.in
+index 533d55c..fdffe15 100644
+--- a/bind/Makefile.in
++++ b/bind/Makefile.in
+@@ -55,7 +55,7 @@ bind1:
+        else                                                            \
+                echo Configuring BIND libraries for DHCP. ;             \
+                rm -rf ${cleandirs} ${cleanfiles} ;                     \
+-               (cd ${bindsrcdir} &&                                    \
++               (cd ${bindsrcdir} && ./autogen.sh &&                    \
+                  ./configure ${bindconfig} > ${binddir}/configure.log); \
+        fi
+ 
+-- 
+2.25.1
+