Uprev memcached from upstream

memcached 1.4.15 has some configuration errors:
configure:5798: error: cannot run test program while cross compiling

Uprev has the needed fix for the configuration error and some other fixes.

Signed-off-by: Amy Fong <amy.fong@windriver.com>
Signed-off-by: Joe MacDonald <joe_macdonald@mentor.com>

2 files changed, 43 insertions, 15 deletions

diff --git a/meta-networking/recipes-support/memcached/memcached_1.4.15.bb b/meta-networking/recipes-support/memcached/memcached_1.4.15.bb
deleted file mode 100644
index 016eaeb6e..000000000
--- a/meta-networking/recipes-support/memcached/memcached_1.4.15.bb
+++ /dev/null
@@ -1,15 +0,0 @@
-DESCRIPTION = "Free & open source, high-performance, distributed memory object \
-caching system, generic in nature, but intended for use in speeding up dynamic \
-web applications by alleviating database load."
-HOMEPAGE = "http://memcached.org/"
-LICENSE = "BSD"
-LIC_FILES_CHKSUM = "file://COPYING;md5=7e5ded7363d335e1bb18013ca08046ff"
-
-SRC_URI = "http://memcached.googlecode.com/files/memcached-${PV}.tar.gz"
-
-SRC_URI[md5sum] = "36ea966f5a29655be1746bf4949f7f69"
-SRC_URI[sha256sum] = "169721ab7a7531add6ae9f6b14b6b5641725fe0b1f0bdf5c3a4327725901e2b4"
-
-DEPENDS = "libevent"
-
-inherit autotools
diff --git a/meta-networking/recipes-support/memcached/memcached_1.4.17.bb b/meta-networking/recipes-support/memcached/memcached_1.4.17.bb
new file mode 100644
index 000000000..6a01ec28c
--- /dev/null
+++ b/meta-networking/recipes-support/memcached/memcached_1.4.17.bb
@@ -0,0 +1,43 @@
+SUMMARY = "A high-performance memory object caching system"
+DESCRIPTION = "\
+ memcached optimizes specific high-load serving applications that are designed \
+ to take advantage of its versatile no-locking memory access system. Clients \
+ are available in several different programming languages, to suit the needs \
+ of the specific application. Traditionally this has been used in mod_perl \
+ apps to avoid storing large chunks of data in Apache memory, and to share \
+ this burden across several machines."
+
+HOMEPAGE = "http://memcached.org/"
+LICENSE = "BSD-3-Clause"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=7e5ded7363d335e1bb18013ca08046ff"
+
+inherit autotools
+
+DEPENDS += "libevent"
+RDEPENDS_${PN} += "perl perl-module-posix perl-module-autoloader perl-module-tie-hash"
+
+SRC_URI = "http://www.memcached.org/files/${PN}-${PV}.tar.gz"
+
+SRC_URI[md5sum] = "46402dfbd7faadf6182283dbbd18b1a6"
+SRC_URI[sha256sum] = "d9173ef6d99ba798c982ea4566cb4f0e64eb23859fdbf9926a89999d8cdc0458"
+
+python __anonymous () {
+    endianness = d.getVar('SITEINFO_ENDIANNESS', True)
+    if endianness == 'le':
+        d.setVar('EXTRA_OECONF', "ac_cv_c_endian=little")
+    else:
+        d.setVar('EXTRA_OECONF', "ac_cv_c_endian=big")
+}
+
+inherit update-rc.d
+
+INITSCRIPT_NAME = "memcached"
+INITSCRIPT_PARAMS = "defaults"
+
+do_install_append() {
+    install -D -m 755 ${S}/scripts/memcached-init ${D}${sysconfdir}/init.d/memcached
+    mkdir -p ${D}/usr/share/memcached/scripts
+    install -m 755 ${S}/scripts/memcached-tool ${D}/usr/share/memcached/scripts
+    install -m 755 ${S}/scripts/start-memcached ${D}/usr/share/memcached/scripts
+}