pidgin: add PACKAGECONFIGs

* disable gstreamer and vv, because gstreamer 0.10 is in meta-multimedia now
* disable farsight2/farstream, because farsight2 is blacklisted
* don't enable X11 support without x11 in DISTRO_FEATURES
* allow to disable all UI, useful for DISTROs who want just the purple libraries
  like LuneOS

Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
Signed-off-by: Armin Kuster <akuster808@gmail.com>

1 files changed, 23 insertions, 8 deletions

diff --git a/meta-oe/recipes-support/pidgin/pidgin_2.10.12.bb b/meta-oe/recipes-support/pidgin/pidgin_2.10.12.bb
index 9133c1ce2..ac0871fb4 100644
--- a/meta-oe/recipes-support/pidgin/pidgin_2.10.12.bb
+++ b/meta-oe/recipes-support/pidgin/pidgin_2.10.12.bb
@@ -2,7 +2,7 @@ DESCRIPTION = "multi-protocol instant messaging client"
 SECTION = "x11/network"
 LICENSE = "GPLv2"
 LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
-DEPENDS = "python startup-notification avahi gtk+ ncurses gnutls virtual/libintl gstreamer dbus intltool-native farsight2 libidn libxml2 gconf dbus-glib"
+DEPENDS = "python virtual/libintl intltool-native libxml2 gconf"
 
 inherit autotools gettext pkgconfig gconf perlnative
 
@@ -16,18 +16,33 @@ SRC_URI = "\
 SRC_URI[md5sum] = "14e0f5cfb2ed065e4dc80391a806ac76"
 SRC_URI[sha256sum] = "2c7523f0fefe89749c03b2b738ab9f7bd186da435be4762f1487eee31e77ffdd"
 
+PACKAGECONFIG ??= "gnutls consoleui avahi dbus idn \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11 gtk startup-notification', '', d)} \
+"
+PACKAGECONFIG[farsight2] = "--enable-farstream,--disable-farstream,farsight2"
+#  --disable-gstreamer     compile without GStreamer audio support
+#  --disable-gstreamer-video
+#                          compile without GStreamer 1.0 Video Overlay support
+#  --disable-gstreamer-interfaces
+#                          compile without GStreamer 0.10 interface support
+#  --with-gstreamer=<version>
+#                          compile with GStreamer 0.10 or 1.0 interface
+PACKAGECONFIG[gstreamer] = "--enable-gstreamer,--disable-gstreamer,gstreamer"
+PACKAGECONFIG[vv] = "--enable-vv,--disable-vv,gstreamer"
+PACKAGECONFIG[idn] = "--enable-idn,--disable-idn,libidn"
+PACKAGECONFIG[gtk] = "--enable-gtkui,--disable-gtkui,gtk+"
+PACKAGECONFIG[x11] = "--with-x=yes --x-includes=${STAGING_INCDIR} --x-libraries=${STAGING_LIBDIR},--with-x=no,virtual/libx11"
+PACKAGECONFIG[startup-notification] = "--enable-startup-notification,--disable-startup-notification,startup-notification"
+PACKAGECONFIG[consoleui] = "--enable-consoleui --with-ncurses-headers=${STAGING_INCDIR},--disable-consoleui,ncurses"
+PACKAGECONFIG[gnutls] = "--enable-gnutls --with-gnutls-includes=${STAGING_INCDIR} --with-gnutls-libs=${STAGING_LIBDIR},--disable-gnutls,gnutls"
+PACKAGECONFIG[dbus] = "--enable-dbus,--disable-dbus,dbus dbus-glib"
+PACKAGECONFIG[avahi] = "--enable-avahi,--disable-avahi,avahi"
+
 EXTRA_OECONF = " \
-    --enable-vv \
     --disable-perl \
     --disable-tcl \
     --disable-gevolution \
     --disable-schemas-install \
-    --x-includes=${STAGING_INCDIR} \
-    --x-libraries=${STAGING_LIBDIR} \
-    --enable-gnutls=yes \
-    --with-ncurses-headers=${STAGING_INCDIR} \
-    --with-gnutls-includes=${STAGING_INCDIR} \
-    --with-gnutls-libs=${STAGING_LIBDIR} \
     --disable-gtkspell \
     --disable-meanwhile \
     --disable-nm \