FILESEXTRAPATHS_prepend := "${THISDIR}/linux-intel:"

require recipes-kernel/linux/linux-intel_5.10.bb
require recipes-kernel/linux/linux-deploy-kconfig.inc
require recipes-kernel/linux/linux-common-config.inc

SRCREV_metaenea = "52d45bac8f69340d4677a9271a0f967fc087c44a"
KENEABRANCH = "intel-5.10"
SRC_URI_append = " git://git@git.enea.com/linux/enea-kernel-cache.git;protocol=ssh;type=kmeta;name=metaenea;branch=${KENEABRANCH};destsuffix=enea-kernel-meta"

# Upstream BSPs include aufs support (by patching the kernel source + enabling it in kernel config).
# However, our current kernel version contains a backported commit that conflicts with aufs patches.
# Until aufs patches are rebased in yocto-kernel-cache, disable aufs kernel source patching, since
# we don't enable it via kernel config anyway.
do_kernel_metadata_prepend() {
    ## ENEA_start ##
    # kernel-meta patching via patch files added to SRC_URI is currently broken, handle it here
    sed -i -E 's/^(include features.aufs.*)$/# \1/g' ${WORKDIR}/kernel-meta/ktypes/standard/standard.scc
    ## ENEA_end ##
}

# Allow BSPs to supply patches without explicitly adding the scc files to SRC_URI/KERNEL_FEATURES
KMETA_EXTERNAL_BSPS = "t"

# KERNEL CONFIG DEFAULT CHECK LEVELS:
#   0: no reporting
#   1: report options that are specified, but not in the final config
#   2: report options that are not hardware related, but set by a BSP
# KCONF_AUDIT_LEVEL="1"
# KCONF_BSP_AUDIT_LEVEL="2"
# KMETA_AUDIT="yes"
# KMETA_AUDIT_WERROR=""

KERNEL_FEATURES_append_atom-c3000 = " bsp/atom-c3000/atom-c3000.scc"

KERNEL_FEATURES_append = " features/apic/x2apic_y.scc"

KERNEL_FEATURES_append = " features/udev/udev.scc"

# NFS boot support
KERNEL_FEATURES_append = " features/blkdev/net_blk_dev.scc"

# Ramdisk boot support
KERNEL_FEATURES_append = " features/blkdev/ramdisk_blk_dev.scc"

# Intel 10G ports(SoC)
KERNEL_FEATURES_append_x86-64 = " features/dca/dca_y.scc"

# NMVe SSD
KERNEL_FEATURES_append = " features/nvme/nvme.scc"

# IPMI support
KERNEL_FEATURES_append = " features/ipmi/ipmi.scc"
KERNEL_FEATURES_append = " features/ipmi/ipmi_ssif.scc"

# IPv4 waiting for carrier on
KERNEL_FEATURES_append = " patches/ipv4/ipv4wait.scc"

# Fixes for pci
KERNEL_FEATURES_append = " patches/drivers/pci/quirks.scc"