meta-java: initial commit

* taken over mostly stuff from oe classic
* cleaned up recipes
* added license checksums
* bump icedtea6-native to 1.8.11
* use jamvm from git as native

18 files changed, 296 insertions, 0 deletions

diff --git a/recipes-core/jakarta-commons/commons-beanutils_1.8.0.bb b/recipes-core/jakarta-commons/commons-beanutils_1.8.0.bb
new file mode 100644
index 0000000..500937d
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-beanutils_1.8.0.bb
@@ -0,0 +1,13 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "Static utility methods useful in manipulating Java classes that conform to the JavaBeans Specification"
+
+SRC_URI = "http://www.apache.org/dist/commons/beanutils/source/${BP}-src.tar.gz"
+
+DEPENDS += "commons-collections3 commons-logging"
+RDEPENDS_${PN} = "libcommons-collections3-java libcommons-logging-java"
+
+CP = "commons-collections3 commons-logging"
+
+SRC_URI[md5sum] = "1bce3cfa4ae33c94686422e78abc0792"
+SRC_URI[sha256sum] = "aff3c8c772e4ff32f2d9a37a727a488583372e45535a3d5aad09662691851dcf"
diff --git a/recipes-core/jakarta-commons/commons-cli_1.1.bb b/recipes-core/jakarta-commons/commons-cli_1.1.bb
new file mode 100644
index 0000000..bcfaf65
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-cli_1.1.bb
@@ -0,0 +1,10 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "Java argument parsing helper classes"
+
+SRC_URI = "http://www.apache.org/dist/commons/cli/source/${BP}-src.tar.gz"
+
+
+
+SRC_URI[md5sum] = "ccc1aa194132e2387557bbb7f65391f4"
+SRC_URI[sha256sum] = "929eb140c136673e7f5029cd206c81b3c1f5e66bba0dfdcd021b9dd5596356d2"
diff --git a/recipes-core/jakarta-commons/commons-codec_1.3.bb b/recipes-core/jakarta-commons/commons-codec_1.3.bb
new file mode 100644
index 0000000..6af47e1
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-codec_1.3.bb
@@ -0,0 +1,10 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "Java library with simple encoder and decoders for various formats such as Base64 and Hexadecimal"
+
+SRC_URI = "http://www.apache.org/dist/commons/codec/source/${BP}-src.tar.gz"
+
+S = "${WORKDIR}/${BP}"
+
+SRC_URI[md5sum] = "af3c3acf618de6108d65fcdc92b492e1"
+SRC_URI[sha256sum] = "12effcf3fea025bd34edbfec60a6216ca453fb27e781d8e5783caf75fd33d90e"
diff --git a/recipes-core/jakarta-commons/commons-collections3_3.2.1.bb b/recipes-core/jakarta-commons/commons-collections3_3.2.1.bb
new file mode 100644
index 0000000..7e3478b
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-collections3_3.2.1.bb
@@ -0,0 +1,11 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "A set of abstract data type interfaces and implementations that offer a wealth of useful functionality and a solid foundation for extending that functionality"
+
+SRC_URI = "http://www.apache.org/dist/commons/collections/source/commons-collections-${PV}-src.tar.gz"
+
+S = "${WORKDIR}/commons-collections-${PV}-src"
+
+
+SRC_URI[md5sum] = "031ce05872ddb0462f0dcce1e5babbe9"
+SRC_URI[sha256sum] = "9a4a800cb7ecdaf3b6f608cd608682b88b506f1b1c4b727d15471ae3329fc63d"
diff --git a/recipes-core/jakarta-commons/commons-collections_2.1.1.bb b/recipes-core/jakarta-commons/commons-collections_2.1.1.bb
new file mode 100644
index 0000000..79bd612
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-collections_2.1.1.bb
@@ -0,0 +1,9 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "A set of abstract data type interfaces and implementations that offer a wealth of useful functionality and a solid foundation for extending that functionality"
+
+SRC_URI = "http://www.apache.org/dist/commons/collections/source/${BP}-src.tar.gz"
+
+
+SRC_URI[md5sum] = "3fc2e8f9d0647074cba992b534ecf6df"
+SRC_URI[sha256sum] = "73eb5907a31c8770480c70f6a6a8d9a9a2ffe602e1b461c045cff51ace4cab2a"
diff --git a/recipes-core/jakarta-commons/commons-configuration_1.5.bb b/recipes-core/jakarta-commons/commons-configuration_1.5.bb
new file mode 100644
index 0000000..93febd7
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-configuration_1.5.bb
@@ -0,0 +1,24 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "Generic configuration interface for Java applications"
+
+SRC_URI = " \
+           http://www.apache.org/dist/commons/configuration/source/${BP}-src.tar.gz;name=archive \
+           http://ftp.hosting-studio.de/pub/linux/apache/ant/source/apache-ant-1.7.1-src.tar.bz2;name=ant \
+          "
+
+DEPENDS += "commons-logging commons-collections3 commons-beanutils commons-codec commons-digester commons-jxpath commons-lang servlet2.4"
+RDEPENDS_${PN} = "libcommons-logging-java libcommons-collections3-java libcommons-beanutils-java libcommons-codec-java libcommons-digester-java libcommons-jxpath-java libcommons-lang-java libservlet2.4-java"
+
+CP = "commons-logging commons-collections3 commons-beanutils commons-codec commons-digester commons-jxpath commons-lang servlet-api-2.4"
+
+# Makes use of -sourcepath hack: We inject Ant sourcefiles into the build and remove them
+# afterwards.
+COMPILE_SOURCEPATH = "${WORKDIR}/apache-ant-1.7.1/src/main:src/java"
+
+CLEAN_PATH = "build/org/apache/tools"
+
+SRC_URI[archive.md5sum] = "6a019d26d576a87eda2ef84c8ffc2e31"
+SRC_URI[archive.sha256sum] = "06e5dd81c1302118298156f70b8138fa131ed8f258671b1b67e36a34d80357a0"
+SRC_URI[ant.md5sum] = "0d68db4a1ada5c91bcbf53cefd0c2fd7"
+SRC_URI[ant.sha256sum] = "4dc49a7260ef90a6dc6611b7e96b9f047d507589736d4a2ad6efbe3edfc6fba6"
diff --git a/recipes-core/jakarta-commons/commons-digester_1.8.bb b/recipes-core/jakarta-commons/commons-digester_1.8.bb
new file mode 100644
index 0000000..feb0786
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-digester_1.8.bb
@@ -0,0 +1,15 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "Converts XML to a Java object by a set of mapping rules."
+
+SRC_URI = "http://www.apache.org/dist/commons/digester/source/${BP}-src.tar.gz"
+
+DEPENDS += "commons-logging commons-beanutils"
+RDEPENDS_${PN} = "libcommons-logging-java libcommons-beanutils-java"
+
+CP = "commons-logging commons-beanutils"
+
+FINDARGS = "-name '*.dtd'"
+
+SRC_URI[md5sum] = "689f41905a68c67f7231f9afbb3e2147"
+SRC_URI[sha256sum] = "d9a965c82828a881d2ab6256fba7076f62815a9545b3af9d553dc5271577182b"
diff --git a/recipes-core/jakarta-commons/commons-discovery_0.4.bb b/recipes-core/jakarta-commons/commons-discovery_0.4.bb
new file mode 100644
index 0000000..0de4c5c
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-discovery_0.4.bb
@@ -0,0 +1,13 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "discovering, or finding, implementations for pluggable interfaces"
+
+SRC_URI = "http://www.apache.org/dist/commons/discovery/source/${BP}-src.tar.gz"
+
+DEPENDS += "commons-logging"
+RDEPENDS_${PN} = "libcommons-logging-java"
+
+CP = "commons-logging"
+
+SRC_URI[md5sum] = "1275ad4c6ce54b9323269e30dc42dd0e"
+SRC_URI[sha256sum] = "596242302be4f0502073f5a934c608289bba6221591e7dbea53ce629f67498a3"
diff --git a/recipes-core/jakarta-commons/commons-el_1.0.bb b/recipes-core/jakarta-commons/commons-el_1.0.bb
new file mode 100644
index 0000000..3ba21ee
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-el_1.0.bb
@@ -0,0 +1,17 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "Implementation of the JSP2.0 Expression Language API"
+
+SRC_URI = "http://www.apache.org/dist/commons/el/source/${BP}-src.tar.gz"
+
+DEPENDS += "jsp2.0 servlet2.4"
+RDEPENDS_${PN} = "libjsp2.0-java libservlet2.4-java"
+
+CP = "jsp-api-2.0 servlet-api-2.4"
+
+FINDARGS = "\( -name '*.properties' -or -name '*.jj' \)"
+
+
+
+SRC_URI[md5sum] = "25038283a0b5f638db5e891295d20020"
+SRC_URI[sha256sum] = "3c9bdded6073563aaaddc9ad7c7387b242dc03cc385381503026b665a366c2c6"
diff --git a/recipes-core/jakarta-commons/commons-fileupload_1.2.1.bb b/recipes-core/jakarta-commons/commons-fileupload_1.2.1.bb
new file mode 100644
index 0000000..34ff2c1
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-fileupload_1.2.1.bb
@@ -0,0 +1,17 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "Robust, high-performance, file upload capability for Java servlets and web applications"
+
+SRC_URI = "http://www.apache.org/dist/commons/fileupload/source/${BP}-src.tar.gz"
+
+DEPENDS += "commons-beanutils commons-io servlet2.3"
+RDEPENDS_${PN} = "libcommons-beanutils-java libcommons-io-java libservlet2.3-java"
+
+CP = "commons-beanutils commons-io servlet-2.3"
+
+# Exclude portlet stuff from compilation like Debian does.
+COMPILE_FINDARGS = "-name '*.java' -not -wholename '*portlet*'"
+
+
+SRC_URI[md5sum] = "c2bdb9264aec564e3f4fbbdf4344a844"
+SRC_URI[sha256sum] = "08905cb3a0db4f7fa67f3b579b2c481060334d50d7f913c6974c7513243152f5"
diff --git a/recipes-core/jakarta-commons/commons-httpclient_3.1.bb b/recipes-core/jakarta-commons/commons-httpclient_3.1.bb
new file mode 100644
index 0000000..64f80f6
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-httpclient_3.1.bb
@@ -0,0 +1,16 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "Efficient, up-to-date, and feature-rich package implementing the client side of the most recent HTTP standards and recommendations"
+
+SRC_URI = "http://www.apache.org/dist/httpcomponents/commons-httpclient/source/${BP}-src.tar.gz"
+
+S = "${WORKDIR}/${BP}"
+
+DEPENDS += "commons-logging commons-codec"
+RDEPENDS_${PN} = "libcommons-logging-java libcommons-codec-java"
+
+CP = "commons-logging commons-codec"
+
+
+SRC_URI[md5sum] = "2c9b0f83ed5890af02c0df1c1776f39b"
+SRC_URI[sha256sum] = "f9a496d3418b0e15894fb351652cd4fa5ca434ebfc3ce3bb8da40defd8b097f2"
diff --git a/recipes-core/jakarta-commons/commons-io_1.4.bb b/recipes-core/jakarta-commons/commons-io_1.4.bb
new file mode 100644
index 0000000..ce627ea
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-io_1.4.bb
@@ -0,0 +1,8 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "Java library with utility classes, stream implementations, file filters and endian classes"
+
+SRC_URI = "http://www.apache.org/dist/commons/io/source/${BP}-src.tar.gz"
+
+SRC_URI[md5sum] = "24b228f2d0c40ffed9204cdab015bccf"
+SRC_URI[sha256sum] = "eca986497f7b4d1b1ec41821b1b5df827bb31fc14833e4449cfa8bcd5d7f29bb"
diff --git a/recipes-core/jakarta-commons/commons-jxpath_1.3.bb b/recipes-core/jakarta-commons/commons-jxpath_1.3.bb
new file mode 100644
index 0000000..9e612b2
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-jxpath_1.3.bb
@@ -0,0 +1,13 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "JXPath interpreter for Java"
+
+SRC_URI = "http://www.apache.org/dist/commons/jxpath/source/${BP}-src.tar.gz"
+
+DEPENDS += "commons-logging commons-collections3 commons-beanutils servlet2.3 jdom"
+RDEPENDS_${PN} = "libcommons-logging-java libcommons-collections3-java libcommons-beanutils-java libservlet2.3-java libjdom-java"
+
+CP = "commons-logging commons-collections3 commons-beanutils servlet-2.3 jdom"
+
+SRC_URI[md5sum] = "9af6ed5d009061986d709a370829860e"
+SRC_URI[sha256sum] = "da314198d75c6da660e2603bd1543a8f5d0b640c5144b748e62e59afc278efe6"
diff --git a/recipes-core/jakarta-commons/commons-lang_2.4.bb b/recipes-core/jakarta-commons/commons-lang_2.4.bb
new file mode 100644
index 0000000..a470d63
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-lang_2.4.bb
@@ -0,0 +1,9 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "Set of Java classes that provide helper methods for the standard java.lang classes"
+
+SRC_URI = "http://www.apache.org/dist/commons/lang/source/${BP}-src.tar.gz"
+
+
+SRC_URI[md5sum] = "625ff5f2f968dd908bca43c9469d6e6b"
+SRC_URI[sha256sum] = "2445238cd0eb167e99a1147394f61325490559f3df7e7e8f628043fb70cbf2f4"
diff --git a/recipes-core/jakarta-commons/commons-logging_1.1.1.bb b/recipes-core/jakarta-commons/commons-logging_1.1.1.bb
new file mode 100644
index 0000000..235b7f4
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-logging_1.1.1.bb
@@ -0,0 +1,19 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "Java Internet protocol suite library"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=d273d63619c9aeaf15cdaf76422c4f87"
+
+SRC_URI = "http://www.apache.org/dist/commons/logging/source/${BP}-src.tar.gz"
+
+DEPENDS += "log4j1.2 servlet2.3 logkit"
+DEPENDS_virtclass-native += "log4j1.2-native servlet2.3-native logkit-native"
+
+CP = "log4j-1.2 servlet-2.3 logkit"
+
+COMPILE_FINDARGS = "-name '*.java' -and -not -name '*Avalon*'"
+
+SRC_URI[md5sum] = "e5cfa8cca13152d7545fde6b1783c60a"
+SRC_URI[sha256sum] = "b49a79fa78ebfae15dc46ae6f0144fee6b94ab608a25518c54609d3419909eb2"
+
+NATIVE_INSTALL_WORKS = "1"
+BBCLASSEXTEND = "native"
diff --git a/recipes-core/jakarta-commons/commons-net_1.4.1.bb b/recipes-core/jakarta-commons/commons-net_1.4.1.bb
new file mode 100644
index 0000000..26b8603
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-net_1.4.1.bb
@@ -0,0 +1,24 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "Java Internet protocol suite library"
+LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=3b83ef96387f14655fc854ddc3c6bd57"
+
+SRC_URI = "http://www.apache.org/dist/commons/net/source/${BP}-src.tar.gz"
+
+S = "${WORKDIR}/${BP}"
+
+DEPENDS += "oro"
+DEPENDS_virtclass-native += "oro-native"
+
+RDEPENDS_${PN} = "liboro-java"
+RDEPENDS_${PN}_virtclass-native = ""
+
+CP = "oro"
+
+MAINSOURCES = "src/java/org"
+
+SRC_URI[md5sum] = "ccbb3f67b55e8a7a676499db4386673c"
+SRC_URI[sha256sum] = "fdea779f261f70b9bbec40121c830b11e3e63b6188f662f95505045ff8d44add"
+
+NATIVE_INSTALL_WORKS = "1"
+BBCLASSEXTEND = "native"
diff --git a/recipes-core/jakarta-commons/commons-pool_1.4.bb b/recipes-core/jakarta-commons/commons-pool_1.4.bb
new file mode 100644
index 0000000..b6bd4f4
--- /dev/null
+++ b/recipes-core/jakarta-commons/commons-pool_1.4.bb
@@ -0,0 +1,8 @@
+require jakarta-commons.inc
+
+DESCRIPTION = "Java Object-pooling API"
+
+SRC_URI = "http://www.apache.org/dist/commons/pool/source/${BP}-src.tar.gz"
+
+SRC_URI[md5sum] = "4dc988ee16e1471799af97763297b41b"
+SRC_URI[sha256sum] = "ca4452f2a2ce2daf6eaa1743ded2d3b36013200c48e3f2117b65584ca5cc1d9b"
diff --git a/recipes-core/jakarta-commons/jakarta-commons.inc b/recipes-core/jakarta-commons/jakarta-commons.inc
new file mode 100644
index 0000000..3ee081e
--- /dev/null
+++ b/recipes-core/jakarta-commons/jakarta-commons.inc
@@ -0,0 +1,60 @@
+LICENSE = "AL2.0"
+AUTHOR = "Apache Software Foundation"
+
+inherit java-library
+
+S = "${WORKDIR}/${BP}-src"
+
+# Directory in which the projects sources are located.
+MAINSOURCES = "src/java"
+
+# Directories which should appear in the -sourcepath argument.
+COMPILE_SOURCEPATH = "src/java"
+
+COMPILE_FINDARGS = "-name '*.java'"
+FINDARGS = "-name '*.properties'"
+
+# Directories to be removed after compilation.
+CLEAN_PATH = ""
+
+# Some projects have a replaceable version number in their manifest template.
+do_unpackpost() {
+  if [ -d src/conf ]
+  then
+    find src/conf -exec \
+      sed -i -e "s|@version@|${PV}|" {} \;
+  fi
+}
+
+addtask unpackpost after do_unpack before do_patch
+# Compile step is very similar for Jakarta commons packages
+do_compile() {
+  mkdir -p build
+
+  if [ "${CP}" ]
+  then
+     oe_makeclasspath cp -s ${CP}
+  else
+     cp=.
+  fi
+
+  echo "javac -sourcepath ${COMPILE_SOURCEPATH} -cp $cp -d build \`find ${MAINSOURCES} ${COMPILE_FINDARGS}\`"
+  javac -sourcepath ${COMPILE_SOURCEPATH} -cp $cp -d build `find ${MAINSOURCES} ${COMPILE_FINDARGS}`
+
+  # Copy extraneous files
+  echo "(cd ${MAINSOURCES} && find . ${FINDARGS} -exec cp {} ../../build/{} \;)"
+  (cd ${MAINSOURCES} && find . ${FINDARGS} -exec cp {} ../../build/{} \;)
+
+        # Optionally remove stuff after compilation (needed for sourcepath hacks).
+        if [ ${CLEAN_PATH} ]; then
+                rm -rf ${CLEAN_PATH}
+        fi
+
+  # Some projects have manifest, some have not. This works for both.
+  if [ -f src/conf/MANIFEST.MF ]
+  then
+    fastjar -C build -c -m src/conf/MANIFEST.MF -f ${JARFILENAME} .
+  else
+    fastjar -C build -c -f ${JARFILENAME} .
+  fi
+}