dbus-java,libmatthew: Add recipes for dbus-java 2.7 and libmatthew 0.8

Signed-off-by: Khem Raj <raj.khem@gmail.com>

4 files changed, 187 insertions, 0 deletions

diff --git a/recipes-core/dbus/dbus-java_2.7.bb b/recipes-core/dbus/dbus-java_2.7.bb
new file mode 100644
index 0000000..2fae051
--- /dev/null
+++ b/recipes-core/dbus/dbus-java_2.7.bb
@@ -0,0 +1,92 @@
+DESCRIPTION = "A pure Java D-Bus Implementation"
+DESCRIPTION_dbus-java-viewer = "${DESCRIPTION} (DBusViewer Binary)"
+DESCRIPTION_dbus-java-bin = "${DESCRIPTION} (Binaries)"
+AUTHOR = "Matthew Johnson <dbus@matthew.ath.cx>"
+HOMEPAGE = "http://dbus.freedesktop.org/doc/dbus-java"
+SECTION = "libs"
+LICENSE = "LGPL-2.1 & AFL-2.1"
+
+DEPENDS = "libmatthew docbook-utils-native docbook-sgml-dtd-4.1-native fastjar-native"
+RDEPENDS_dbus-java-viewer = "java2-runtime libunixsocket-java dbus-java-bin libmatthew-debug-java ${JPN}"
+RDEPENDS_dbus-java-bin = "java2-runtime libunixsocket-java libmatthew-debug-java ${JPN}"
+RSUGGESTS_libdbus-java = "libunixsocket-java"
+
+PR = "r0"
+LIC_FILES_CHKSUM = "file://COPYING;md5=72cc739fb93ae32741edbae802490e92"
+SRC_URI = "http://dbus.freedesktop.org/releases/dbus-java/dbus-java-${PV}.tar.gz"
+
+SRC_URI[md5sum] = "8b8470db5cd657591bac245e3b6e18e4"
+SRC_URI[sha256sum] = "be404ea36284d938646192d0ee42e146853064217d4e3aaf89b56bd351ebca33"
+
+S = "${WORKDIR}/dbus-java-${PV}"
+
+inherit java-library
+
+# jamvm-native unfortunately contains non-generificed java/lang/reflect classes
+# which are accessed in this package. Work around this by setting the bootclasspath
+# explicitly.
+JCFLAGS = "-bootclasspath ${STAGING_DATADIR}/classpath/glibj.zip"
+
+do_compile () {
+  oe_runmake \
+        JCFLAGS="-source 1.5 ${JCFLAGS}" \
+        JAVAC="javac" \
+        JARPREFIX="${STAGING_DATADIR_JAVA}" \
+        JAVAUNIXJARDIR="${STAGING_DATADIR_JAVA}" \
+        JAVAUNIXLIBDIR="${STAGING_DIR_TARGET}${libdir_jni}" \
+        CLASSPATH="${S}/classes" \
+        JAR="fastjar" \
+        bin
+
+  # Generated shell scripts will have staging paths inside them.
+        rm bin/*
+  
+        # Generate them again with target paths.
+        oe_runmake \
+                JAVAC="oefatal \"No Java compilation expected here.\"" \
+                JAR="oefatal \"No jar invocation expected here.\"" \
+                JARPREFIX=${datadir_java} \
+                JAVAUNIXJARDIR=${datadir_java} \
+                JAVAUNIXLIBDIR=${libdir_jni} \
+                bin
+
+        # Generate man pages.
+        oe_runmake \
+                JAVAC="oefatal \"No Java compilation expected here.\"" \
+                JAR="oefatal \"No jar invocation expected here.\"" \
+                JARPREFIX=${datadir_java} \
+                JAVAUNIXJARDIR=${datadir_java} \
+                JAVAUNIXLIBDIR=${libdir_jni} \
+                man
+}
+
+JARFILENAME = "${JPN}-${PV}.jar"
+
+do_install () {
+  oe_jarinstall ${JPN}-${PV}.jar ${JPN}.jar dbus.jar
+  oe_jarinstall dbus-java-viewer-${PV}.jar dbus-java-viewer.jar dbus-viewer.jar
+  oe_jarinstall dbus-java-bin-${PV}.jar dbus-java-bin.jar dbus-bin.jar
+  
+  install -d ${D}${bindir}
+  install bin/DBusViewer ${D}${bindir}
+  install bin/DBusCall ${D}${bindir}
+  install bin/CreateInterface ${D}${bindir}
+  install bin/ListDBus ${D}${bindir}
+  install bin/DBusDaemon ${D}${bindir}
+
+        oe_runmake \
+                JAVAC="oefatal \"No Java compilation expected here.\"" \
+                JAR="oefatal \"No jar invocation expected here.\"" \
+                MANPREFIX=${D}${mandir} \
+                DOCPREFIX=${D}${docdir}/${JPN} \
+                install-man
+}
+
+# ${JPN} must be last otherwise it would pick up dbus-viewer*.jar
+# and dbus-bin*.jar
+PACKAGES = "dbus-java-viewer dbus-java-viewer-doc dbus-java-bin dbus-java-bin-doc ${JPN}"
+
+FILES_dbus-java-viewer = "${datadir}/java/dbus-java-viewer*.jar ${bindir}/DBusViewer"
+FILES_dbus-java-viewer-doc = "${mandir}/DBusViewer*"
+FILES_dbus-java-bin = "${datadir}/java/dbus-java-bin*.jar ${bindir}"
+FILES_dbus-java-bin-doc = "${mandir} ${docdir}/${JPN}"
diff --git a/recipes-core/libmatthew/files/Makefile-0.7.patch b/recipes-core/libmatthew/files/Makefile-0.7.patch
new file mode 100644
index 0000000..4a91cd5
--- /dev/null
+++ b/recipes-core/libmatthew/files/Makefile-0.7.patch
@@ -0,0 +1,15 @@
+Index: libmatthew-java-0.7/Makefile
+===================================================================
+--- libmatthew-java-0.7.orig/Makefile   2008-05-27 13:17:47.000000000 +0800
++++ libmatthew-java-0.7/Makefile        2008-05-27 13:18:04.000000000 +0800
+@@ -8,8 +8,8 @@
+ PPFLAGS+=-C -P
+ CFLAGS+=-fpic -Wall -Os -pedantic -std=c99 -Werror
+ GCJFLAGS+=-fjni
+-JCFLAGS+=-source 5.0
+-INCLUDES+=-I$(JAVA_HOME)/include -I$(JAVA_HOME)/include/linux
++#JCFLAGS+=-source 5.0
++#INCLUDES+=-I$(JAVA_HOME)/include -I$(JAVA_HOME)/include/linux
+ JAVADOCFLAGS?=-quiet -author -link http://java.sun.com/j2se/1.4.2/docs/api/
+ 
+ LDVER?=$(shell ld -v | cut -d' ' -f1)
diff --git a/recipes-core/libmatthew/libmatthew.inc b/recipes-core/libmatthew/libmatthew.inc
new file mode 100644
index 0000000..d0ea00a
--- /dev/null
+++ b/recipes-core/libmatthew/libmatthew.inc
@@ -0,0 +1,68 @@
+DESCRIPTION = "Unix socket, debug and hexdump JAVA libraries"
+AUTHOR = "Matthew Johnson <web@matthew.ath.cx>"
+HOMEPAGE = "http://www.matthew.ath.cx/projects/java"
+SECTION = "libs"
+LICENSE = "MIT"
+DEPENDS = "virtual/java-native classpath-native classpath"
+
+S = "${WORKDIR}/libmatthew-java-${PV}"
+
+inherit java-library
+
+# Some internal version numbers which change from time to time.
+# Allowing to override them makes this include file more
+# versatile.
+VER_CGI         ?= "0.6"
+VER_DEBUG       ?= "1.1"
+VER_HEXDUMP     ?= "0.2"
+VER_IO          ?= "0.1"
+VER_UNIX        ?= "0.5"
+
+do_compile() {
+    oe_runmake \
+        JAVAC="javac" \
+        JAR="fastjar" \
+        JAVAH="gjavah" \
+        INCLUDES="-I${STAGING_INCDIR}/classpath" \
+        LDFLAGS="-fpic -shared -lc ${LDFLAGS}" \
+        LD="${CC}" \
+        CFLAGS="-fpic -Wall -Os -pedantic -std=c99 -Werror"
+}
+
+# we do not have jar name corresponding to JPN
+# which will be installed via JARFILENAME see java-library.bbclass
+# create a dummy for install to succeed
+
+JARFILENAME = "unix-${VER_UNIX}.jar"
+
+do_install() {
+    oe_jarinstall cgi-${VER_CGI}.jar cgi.jar
+    oe_jarinstall debug-disable-${VER_DEBUG}.jar debug-disable.jar
+    oe_jarinstall debug-enable-${VER_DEBUG}.jar debug-enable.jar
+    oe_jarinstall hexdump-${VER_HEXDUMP}.jar hexdump.jar
+    oe_jarinstall io-${VER_IO}.jar io.jar
+    oe_jarinstall unix-${VER_UNIX}.jar unix.jar
+    oe_libinstall -so libcgi-java ${D}${libdir_jni}
+    oe_libinstall -so libunix-java ${D}${libdir_jni}
+}
+
+PACKAGES = "\
+        libcgi-java libcgi-jni libcgi-jni-dbg \
+        libunixsocket-java libunixsocket-jni libunixsocket-jni-dbg \
+        ${PN}-io-java ${PN}-debug-java \
+"
+
+FILES_libcgi-java = "${datadir_java}/cgi*.jar"
+FILES_libcgi-jni = "${libdir_jni}/libcgi-java.so"
+FILES_libcgi-jni-dbg = "${libdir_jni}/.debug/libcgi-java.so"
+RDEPENDS_libcgi-java = "libcgi-jni"
+
+FILES_libunixsocket-java = "${datadir_java}/unix*.jar"
+FILES_libunixsocket-jni = "${libdir_jni}/libunix-java.so"
+FILES_libunixsocket-jni-dbg = "${libdir_jni}/.debug/libunix-java.so"
+RDEPENDS_libunixsocket-java = "libunixsocket-jni"
+
+FILES_${PN}-io-java = "${datadir_java}/io*.jar"
+
+FILES_${PN}-debug-java = "${datadir_java}/debug-*.jar ${datadir_java}/hexdump*.jar"
+
diff --git a/recipes-core/libmatthew/libmatthew_0.8.bb b/recipes-core/libmatthew/libmatthew_0.8.bb
new file mode 100644
index 0000000..c4ace08
--- /dev/null
+++ b/recipes-core/libmatthew/libmatthew_0.8.bb
@@ -0,0 +1,12 @@
+require libmatthew.inc
+
+PR = "r0"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=48a42f2f9747f02bf40a0bce2655b509"
+
+SRC_URI = "http://pkgs.fedoraproject.org/repo/pkgs/libmatthew-java/libmatthew-java-0.8.tar.gz/8455b8751083ce25c99c2840609271f5/libmatthew-java-${PV}.tar.gz \
+          "
+#           file://Makefile-0.7.patch"
+SRC_URI[md5sum] = "8455b8751083ce25c99c2840609271f5"
+SRC_URI[sha256sum] = "05d1d3d9b5e33bd3642102aae10bba904e296c5c01a10854200ad4df349c8dfa"
+