openjdk-8: fix rewrite QA warnings

Fix bitbake warnings from variable renaming like

    Variable key FILES_${PN} (${bindir}/* ${sbindir}/* ${libexecdir}/* ${libdir}/lib*${SOLIBS} ${sysconfdir} ${sharedstatedir} ${localstatedir} ${base_bindir}/* ${base_sbindir}/* ${base_libdir}/*${SOLIBS} ${base_prefix}/lib/udev/rules.d ${prefix}/lib/udev/rules.d ${datadir}/${BPN} ${libdir}/${BPN}/* ${datadir}/pixmaps ${datadir}/applications ${datadir}/idl ${datadir}/omf ${datadir}/sounds ${libdir}/bonobo/servers) replaces original key FILES_openjre-8 (    ${JRE_HOME}/bin/[a-z]*     ${JRE_HOME}/lib/[a-z]*     ${JRE_HOME}/LICENSE     ${JRE_HOME}/release ).

It is caused by using FILES_${PN} and FILES_{JDKPN} or FILES_${JREPN},
respectively. Moving FILES_{JDKPN} to openjdk-8_%.bb and FILES_${JREPN} to
openjre-8_%.bb to allow consequently use FILES_${PN}.

Signed-off-by: Jens Rehsack <sno@netbsd.org>
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>

3 files changed, 122 insertions, 150 deletions

diff --git a/recipes-core/openjdk/openjdk-8-cross.inc b/recipes-core/openjdk/openjdk-8-cross.inc
index 20ac194..457a010 100644
--- a/recipes-core/openjdk/openjdk-8-cross.inc
+++ b/recipes-core/openjdk/openjdk-8-cross.inc
@@ -1,8 +1,5 @@
-JDKPN = "openjdk-8"
-JREPN = "openjre-8"
-
-JDK_HOME = "${libdir_jvm}/${JDKPN}"
-JRE_HOME = "${libdir_jvm}/${JREPN}"
+JDK_HOME = "${libdir_jvm}/openjdk-8"
+JRE_HOME = "${libdir_jvm}/openjre-8"
 
 DEPENDS = "\
     openjdk-8-native zip-native ant-native libxslt \
@@ -72,129 +69,3 @@ EXTRA_OEMAKE_append = '\
     QUIETLY= \
     images \
 '
-
-FILES_${JREPN}_append = "\
-    ${JRE_HOME}/bin/[a-z]* \
-    ${JRE_HOME}/lib/[a-z]* \
-    ${JRE_HOME}/LICENSE \
-    ${JRE_HOME}/release \
-"
-
-FILES_${JDKPN}_append = "\
-    ${JDK_HOME}/bin/[a-z]* \
-    ${JDK_HOME}/lib/[a-z]* \
-    ${JDK_HOME}/jre/bin/[a-z]* \
-    ${JDK_HOME}/jre/lib/[a-z]* \
-    ${JDK_HOME}/LICENSE \
-    ${JDK_HOME}/jre/LICENSE \
-    ${JDK_HOME}/release \
-"
-
-FILES_${JDKPN}-dev_append = "\
-    ${JDK_HOME}/include \
-"
-
-FILES_${JDKPN}-dbg_append = "\
-    ${JDK_HOME}/bin/.debug/ \
-    ${JDK_HOME}/lib/.debug/ \
-    ${JDK_HOME}/lib/${JDK_ARCH}/.debug/ \
-    ${JDK_HOME}/lib/${JDK_ARCH}/jli/.debug/ \
-    ${JDK_HOME}/jre/bin/.debug/ \
-    ${JDK_HOME}/jre/lib/.debug/ \
-    ${JDK_HOME}/jre/lib/${JDK_ARCH}/.debug/ \
-    ${JDK_HOME}/jre/lib/${JDK_ARCH}/jli/.debug/ \
-    ${JDK_HOME}/jre/lib/${JDK_ARCH}/native_threads/.debug/ \
-    ${JDK_HOME}/jre/lib/${JDK_ARCH}/server/.debug/ \
-    ${JDK_HOME}/jre/lib/${JDK_ARCH}/headless/.debug/ \
-    ${JDK_HOME}/jre/lib/${JDK_ARCH}/xawt/.debug/ \
-    ${JDK_HOME}/jre/lib/${JDK_ARCH}/client/.debug/ \
-"
-
-FILES_${JREPN}-dbg_append = "\
-    ${JRE_HOME}/bin/.debug/ \
-    ${JRE_HOME}/lib/.debug/ \
-    ${JRE_HOME}/lib/${JDK_ARCH}/.debug/ \
-    ${JRE_HOME}/lib/${JDK_ARCH}/jli/.debug/ \
-    ${JRE_HOME}/lib/${JDK_ARCH}/server/.debug/ \
-"
-
-FILES_${JDKPN}-demo = " ${JDK_HOME}/demo ${JDK_HOME}/sample "
-RDEPENDS_${JDKPN}-demo = " ${JDKPN} "
-
-FILES_${JDKPN}-demo-dbg = "\
-    ${JDK_HOME}/demo/jvmti/gctest/lib/.debug/ \
-    ${JDK_HOME}/demo/jvmti/heapTracker/lib/.debug/ \
-    ${JDK_HOME}/demo/jvmti/heapViewer/lib/.debug/ \
-    ${JDK_HOME}/demo/jvmti/hprof/lib/.debug/ \
-    ${JDK_HOME}/demo/jvmti/minst/lib/.debug/ \
-    ${JDK_HOME}/demo/jvmti/mtrace/lib/.debug/ \
-    ${JDK_HOME}/demo/jvmti/versionCheck/lib/.debug/ \
-    ${JDK_HOME}/demo/jvmti/waiters/lib/.debug/ \
-    ${JDK_HOME}/demo/jvmti/compiledMethodLoad/lib/.debug/ \
-"
-
-FILES_${JDKPN}-doc_append = "\
-    ${JDK_HOME}/man \
-    ${JDK_HOME}/ASSEMBLY_EXCEPTION \
-    ${JDK_HOME}/THIRD_PARTY_README \
-    ${JDK_HOME}/jre/ASSEMBLY_EXCEPTION \
-    ${JDK_HOME}/jre/THIRD_PARTY_README \
-"
-FILES_${JREPN}-doc_append = "\
-    ${JRE_HOME}/man \
-    ${JRE_HOME}/ASSEMBLY_EXCEPTION \
-    ${JRE_HOME}/THIRD_PARTY_README \
-"
-
-FILES_${JDKPN}-source = " ${JDK_HOME}/src.zip "
-
-# Even though a vm is a hard dependency it is set as RRECOMMENDS so a single vm can get uninstalled:
-# root@beaglebone:~/java# opkg remove openjdk-7-vm-shark
-# No packages removed.
-# Collected errors:
-#  * print_dependents_warning: Package openjdk-7-vm-shark is depended upon by packages:
-#  * print_dependents_warning:         openjdk-7-java
-#  * print_dependents_warning: These might cease to work if package openjdk-7-vm-shark is removed.
-#RRECOMMENDS_${JDKPN}-java = "java2-vm"
-
-# There is a symlink to a .so but this one is valid.
-INSANE_SKIP_${JDKPN}-common = "dev-so"
-
-FILES_${JDKPN}-doc_append = "${JDK_HOME}/man"
-
-do_compile_append() {
-    find ${B}/images/j2sdk-image -name "*.jar" -print0 | \
-      xargs -0 -n1 ${STAGING_LIBDIR_NATIVE}/jvm/openjdk-8-native/bin/pack200 --repack --effort=9 --segment-limit=-1 --modification-time=latest
-    find ${B}/images/j2re-image -name "*.jar" -print0 | \
-      xargs -0 -n1 ${STAGING_LIBDIR_NATIVE}/jvm/openjdk-8-native/bin/pack200 --repack --effort=9 --segment-limit=-1 --modification-time=latest --strip-debug
-}
-
-do_install_jdk() {
-    rm -rf ${D}${JDK_HOME}
-        mkdir -p ${D}${JDK_HOME}
-    cp -rp ${B}/images/j2sdk-image/* ${D}${JDK_HOME}
-    install -m644 ${WORKDIR}/jvm.cfg  ${D}${JDK_HOME}/jre/lib/${JDK_ARCH}/
-    find ${D}${JDK_HOME} -name "*.debuginfo" -print0 | xargs -0 rm
-}
-
-do_install_jre() {
-    rm -rf ${D}${JRE_HOME}
-        mkdir -p ${D}${JRE_HOME}
-    cp -rp ${B}/images/j2re-image/* ${D}${JRE_HOME}
-    install -m644 ${WORKDIR}/jvm.cfg  ${D}${JRE_HOME}/lib/${JDK_ARCH}/
-    find ${D}${JRE_HOME} -name "*.debuginfo" -print0 | xargs -0 rm
-}
-
-inherit update-alternatives
-
-ALTERNATIVE_${JDKPN} = "java"
-ALTERNATIVE_TARGET_${JDKPN} = "${JDK_HOME}/bin/java"
-
-ALTERNATIVE_${JREPN} = "java"
-ALTERNATIVE_TARGET_${JREPN} = "${JRE_HOME}/bin/java"
-
-ALTERNATIVE_${JDKPN}-jdk = "javac"
-ALTERNATIVE_TARGET_${JDKPN}-jdk = "${JDK_HOME}/bin/javac"
-
-ALTERNATIVE_LINK_NAME[java] = "${bindir}/java"
-ALTERNATIVE_LINK_NAME[javac] = "${bindir}/javac"
diff --git a/recipes-core/openjdk/openjdk-8_72b05.bb b/recipes-core/openjdk/openjdk-8_72b05.bb
index 4c8899e..96473f5 100644
--- a/recipes-core/openjdk/openjdk-8_72b05.bb
+++ b/recipes-core/openjdk/openjdk-8_72b05.bb
@@ -11,26 +11,97 @@ PATCHES_URI_append = "\
     file://openjdk8-use_builtin_frame_address_0_rather_than_returning_address_of_local_variable.patch;apply=no \
 "
 
+do_compile_append() {
+    find ${B}/images/j2sdk-image -name "*.jar" -print0 | \
+      xargs -0 -n1 ${STAGING_LIBDIR_NATIVE}/jvm/openjdk-8-native/bin/pack200 --repack --effort=9 --segment-limit=-1 --modification-time=latest
+}
+
 do_install() {
-    do_install_jdk
+    rm -rf ${D}${JDK_HOME}
+        mkdir -p ${D}${JDK_HOME}
+    cp -rp ${B}/images/j2sdk-image/* ${D}${JDK_HOME}
+    install -m644 ${WORKDIR}/jvm.cfg  ${D}${JDK_HOME}/jre/lib/${JDK_ARCH}/
+    find ${D}${JDK_HOME} -name "*.debuginfo" -print0 | xargs -0 rm
 }
 
 PACKAGES_append = " \
-    ${JDKPN}-demo-dbg \
-    ${JDKPN}-demo \
-    ${JDKPN}-source \
+    ${PN}-demo-dbg \
+    ${PN}-demo \
+    ${PN}-source \
+"
+
+FILES_${PN}_append = "\
+    ${JDK_HOME}/bin/[a-z]* \
+    ${JDK_HOME}/lib/[a-z]* \
+    ${JDK_HOME}/jre/bin/[a-z]* \
+    ${JDK_HOME}/jre/lib/[a-z]* \
+    ${JDK_HOME}/LICENSE \
+    ${JDK_HOME}/jre/LICENSE \
+    ${JDK_HOME}/release \
+"
+
+FILES_${PN}-dev_append = "\
+    ${JDK_HOME}/include \
+"
+
+FILES_${PN}-dbg_append = "\
+    ${JDK_HOME}/bin/.debug/ \
+    ${JDK_HOME}/lib/.debug/ \
+    ${JDK_HOME}/lib/${JDK_ARCH}/.debug/ \
+    ${JDK_HOME}/lib/${JDK_ARCH}/jli/.debug/ \
+    ${JDK_HOME}/jre/bin/.debug/ \
+    ${JDK_HOME}/jre/lib/.debug/ \
+    ${JDK_HOME}/jre/lib/${JDK_ARCH}/.debug/ \
+    ${JDK_HOME}/jre/lib/${JDK_ARCH}/jli/.debug/ \
+    ${JDK_HOME}/jre/lib/${JDK_ARCH}/native_threads/.debug/ \
+    ${JDK_HOME}/jre/lib/${JDK_ARCH}/server/.debug/ \
+    ${JDK_HOME}/jre/lib/${JDK_ARCH}/headless/.debug/ \
+    ${JDK_HOME}/jre/lib/${JDK_ARCH}/xawt/.debug/ \
+    ${JDK_HOME}/jre/lib/${JDK_ARCH}/client/.debug/ \
 "
 
-RPROVIDES_${JDKPN} = "java2-vm"
-PROVIDES_${JDKPN} = "java2-vm"
-RPROVIDES_${JDKPN} = "java2-runtime"
-PROVIDES_${JDKPN} = "java2-runtime"
+FILES_${PN}-demo = " ${JDK_HOME}/demo ${JDK_HOME}/sample "
+RDEPENDS_${PN}-demo = " ${PN} "
+
+FILES_${PN}-demo-dbg = "\
+    ${JDK_HOME}/demo/jvmti/gctest/lib/.debug/ \
+    ${JDK_HOME}/demo/jvmti/heapTracker/lib/.debug/ \
+    ${JDK_HOME}/demo/jvmti/heapViewer/lib/.debug/ \
+    ${JDK_HOME}/demo/jvmti/hprof/lib/.debug/ \
+    ${JDK_HOME}/demo/jvmti/minst/lib/.debug/ \
+    ${JDK_HOME}/demo/jvmti/mtrace/lib/.debug/ \
+    ${JDK_HOME}/demo/jvmti/versionCheck/lib/.debug/ \
+    ${JDK_HOME}/demo/jvmti/waiters/lib/.debug/ \
+    ${JDK_HOME}/demo/jvmti/compiledMethodLoad/lib/.debug/ \
+"
+
+FILES_${PN}-doc_append = "\
+    ${JDK_HOME}/man \
+    ${JDK_HOME}/ASSEMBLY_EXCEPTION \
+    ${JDK_HOME}/THIRD_PARTY_README \
+    ${JDK_HOME}/jre/ASSEMBLY_EXCEPTION \
+    ${JDK_HOME}/jre/THIRD_PARTY_README \
+    ${JDK_HOME}/man \
+"
+
+FILES_${PN}-source = " ${JDK_HOME}/src.zip "
+
+RPROVIDES_${PN} = "java2-vm"
+PROVIDES_${PN} = "java2-vm"
+RPROVIDES_${PN} = "java2-runtime"
+PROVIDES_${PN} = "java2-runtime"
 
 inherit update-alternatives
 
-ALTERNATIVE_${PN} = "java"
-ALTERNATIVE_LINK = "${bindir}/java"
-ALTERNATIVE_TARGET = "${JDK_HOME}/bin/java"
 ALTERNATIVE_PRIORITY = "100"
 
+ALTERNATIVE_${PN} = "java"
+ALTERNATIVE_LINK_NAME[java] = "${bindir}/java"
+ALTERNATIVE_TARGET[java] = "${JDK_HOME}/bin/java"
+
+ALTERNATIVE_${PN}-jdk = "javac"
+ALTERNATIVE_LINK_NAME[javac] = "${bindir}/javac"
+ALTERNATIVE_TARGET[javac] = "${JDK_HOME}/bin/javac"
+
+
 # PR = "${INC_PR}.1"
diff --git a/recipes-core/openjdk/openjre-8_72b05.bb b/recipes-core/openjdk/openjre-8_72b05.bb
index 67eb1d3..1543652 100644
--- a/recipes-core/openjdk/openjre-8_72b05.bb
+++ b/recipes-core/openjdk/openjre-8_72b05.bb
@@ -11,20 +11,50 @@ PATCHES_URI_append = "\
     file://openjdk8-use_builtin_frame_address_0_rather_than_returning_address_of_local_variable.patch;apply=no \
 "
 
+do_compile_append() {
+    find ${B}/images/j2re-image -name "*.jar" -print0 | \
+      xargs -0 -n1 ${STAGING_LIBDIR_NATIVE}/jvm/openjdk-8-native/bin/pack200 --repack --effort=9 --segment-limit=-1 --modification-time=latest --strip-debug
+}
+
 do_install() {
-    do_install_jre
+    rm -rf ${D}${JRE_HOME}
+        mkdir -p ${D}${JRE_HOME}
+    cp -rp ${B}/images/j2re-image/* ${D}${JRE_HOME}
+    install -m644 ${WORKDIR}/jvm.cfg  ${D}${JRE_HOME}/lib/${JDK_ARCH}/
+    find ${D}${JRE_HOME} -name "*.debuginfo" -print0 | xargs -0 rm
 }
 
-RPROVIDES_${JREPN} = "java2-vm"
-PROVIDES_${JREPN} = "java2-vm"
-RPROVIDES_${JREPN} = "java2-runtime"
-PROVIDES_${JREPN} = "java2-runtime"
+FILES_${PN}_append = "\
+    ${JRE_HOME}/bin/[a-z]* \
+    ${JRE_HOME}/lib/[a-z]* \
+    ${JRE_HOME}/LICENSE \
+    ${JRE_HOME}/release \
+"
+
+FILES_${PN}-dbg_append = "\
+    ${JRE_HOME}/bin/.debug/ \
+    ${JRE_HOME}/lib/.debug/ \
+    ${JRE_HOME}/lib/${JDK_ARCH}/.debug/ \
+    ${JRE_HOME}/lib/${JDK_ARCH}/jli/.debug/ \
+    ${JRE_HOME}/lib/${JDK_ARCH}/server/.debug/ \
+"
+
+FILES_${PN}-doc_append = "\
+    ${JRE_HOME}/man \
+    ${JRE_HOME}/ASSEMBLY_EXCEPTION \
+    ${JRE_HOME}/THIRD_PARTY_README \
+"
+
+RPROVIDES_${PN} = "java2-vm"
+PROVIDES_${PN} = "java2-vm"
+RPROVIDES_${PN} = "java2-runtime"
+PROVIDES_${PN} = "java2-runtime"
 
 inherit update-alternatives
 
 ALTERNATIVE_${PN} = "java"
-ALTERNATIVE_LINK = "${bindir}/java"
-ALTERNATIVE_TARGET = "${JRE_HOME}/bin/java"
-ALTERNATIVE_PRIORITY = "100"
+ALTERNATIVE_LINK_NAME[java] = "${bindir}/java"
+ALTERNATIVE_TARGET[java] = "${JRE_HOME}/bin/java"
+ALTERNATIVE_PRIORITY[java] = "100"
 
 # PR = "${INC_PR}.1"