blob: 31e8da9b9a4f51a14ef24bfc3039b6cf7be16daa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
SUMMARY = "VA driver for Intel Gen based graphics hardware"
DESCRIPTION = "Intel Media Driver for VAAPI is a new VA-API (Video Acceleration API) \
user mode driver supporting hardware accelerated decoding, encoding, \
and video post processing for GEN based graphics hardware."
HOMEPAGE = "https://github.com/intel/media-driver"
BUGTRACKER = "https://github.com/intel/media-driver/issues"
LICENSE = "MIT & BSD-3-Clause"
LIC_FILES_CHKSUM = "file://LICENSE.md;md5=6aab5363823095ce682b155fef0231f0 \
file://media_driver/media_libvpx.LICENSE;md5=d5b04755015be901744a78cc30d390d4 \
"
# Only for 64 bit until this is resolved: https://github.com/intel/media-driver/issues/356
COMPATIBLE_HOST = '(x86_64).*-linux'
inherit distro_features_check
REQUIRED_DISTRO_FEATURES = "opengl"
DEPENDS += "libva gmmlib"
SRC_URI = "git://github.com/intel/media-driver.git;protocol=https;branch=intel-media-19.2 \
file://0001-dont-mark-implicit-function-declaration-warnings-as-.patch \
"
SRCREV = "9b648d81fb43f70c49304011371279713cb13ccc"
S = "${WORKDIR}/git"
COMPATIBLE_HOST_x86-x32 = "null"
UPSTREAM_CHECK_GITTAGREGEX = "^intel-media-(?P<pver>(?!600\..*)\d+(\.\d+)+)$"
inherit cmake pkgconfig
MEDIA_DRIVER_ARCH_x86 = "32"
MEDIA_DRIVER_ARCH_x86-64 = "64"
EXTRA_OECMAKE += " \
-DMEDIA_RUN_TEST_SUITE=OFF \
-DARCH=${MEDIA_DRIVER_ARCH} \
-DMEDIA_BUILD_FATAL_WARNINGS=OFF \
"
do_configure_prepend_toolchain-clang() {
sed -i -e '/-fno-tree-pre/d' ${S}/media_driver/cmake/linux/media_compile_flags_linux.cmake
}
# See: https://github.com/intel/media-driver/issues/358
FILES_${PN} += " \
${libdir}/dri/ \
${libdir}/igfxcmrt64.so \
"
|
