summaryrefslogtreecommitdiffstats
path: root/dynamic-layers/openembedded-layer/recipes-bsp/amt/lms_1921.0.0.0.bb
blob: 8ed74486a895c6c8cd556b09e4ee8ca931dcfd87 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
SUMMARY = "Intel(R) Local Managability Service"
DESCRIPTION = "Intel Local Manageability Service allows applications \
to access the Intel Active Management Technology (AMT) firmware via \
the Intel Management Engine Interface (MEI)."

LICENSE = "Apache-2.0"
LIC_FILES_CHKSUM = "file://COPYING;md5=2ee41112a44fe7014dce33e26468ba93"

COMPATIBLE_HOST = '(i.86|x86_64).*-linux'

inherit cmake systemd

DEPENDS = "metee ace xerces-c libnl libxml2 glib-2.0 glib-2.0-native connman"

EXTRA_OECMAKE += "-DPYTHON_EXECUTABLE=${HOSTTOOLS_DIR}/python3"

REQUIRED_DISTRO_FEATURES= "systemd"

FILES_${PN} += "${datadir}/dbus-1/system-services/*.service"

FILES_${PN} += "${libdir}/libLms*.so"
FILES_SOLIBSDEV = ""
INSANE_SKIP_${PN} += "dev-so"

S = "${WORKDIR}/git"

SYSTEMD_SERVICE_${PN} = "lms.service"

SRC_URI = "git://github.com/intel/lms.git"
SRCREV = "f7c374745ae7efb3ed7860fdc3f8abbb52dc9f8f"

SRC_URI_append = " file://lms_drop_rpath_${PV}.diff"

do_install_append() {
    install -d ${D}${systemd_system_unitdir}
    install -m 0644 ${B}/UNS/lms.service ${D}${systemd_system_unitdir}
}

RDEPENDS_${PN} += "ace"