From d53dbb38c43da3fd04fed9a55e7b3b9e2c512b9a Mon Sep 17 00:00:00 2001
From: Saul Wold <sgw@linux.intel.com>
Date: Tue, 7 Nov 2017 10:32:26 -0800
Subject: meta-intel: Reorganize the layout to remove common

Remove the concept of the common directory and move all the recipes-* dirs
to the top level as a normal layer would be. layer.conf is updated appropriately

Signed-off-by: Saul Wold <sgw@linux.intel.com>
---
 .../libva/libva-intel-driver_1.8.3.bb              | 35 ++++++++++++++++++++++
 recipes-multimedia/libva/va-intel.bb               | 32 ++++++++++++++++++++
 2 files changed, 67 insertions(+)
 create mode 100644 recipes-multimedia/libva/libva-intel-driver_1.8.3.bb
 create mode 100644 recipes-multimedia/libva/va-intel.bb

(limited to 'recipes-multimedia/libva')

diff --git a/recipes-multimedia/libva/libva-intel-driver_1.8.3.bb b/recipes-multimedia/libva/libva-intel-driver_1.8.3.bb
new file mode 100644
index 00000000..72451c02
--- /dev/null
+++ b/recipes-multimedia/libva/libva-intel-driver_1.8.3.bb
@@ -0,0 +1,35 @@
+SUMMARY = "VA driver for Intel G45 & HD Graphics family"
+DESCRIPTION = "libva-driver-intel is the VA-API implementation \
+for Intel G45 chipsets and Intel HD Graphics for Intel Core \
+processor family."
+
+HOMEPAGE = "http://www.freedesktop.org/wiki/Software/vaapi"
+BUGTRACKER = "https://bugs.freedesktop.org"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=2e48940f94acb0af582e5ef03537800f"
+
+COMPATIBLE_HOST = '(i.86|x86_64).*-linux'
+
+DEPENDS = "libva libdrm"
+
+SRC_URI = "git://github.com/01org/intel-vaapi-driver.git;branch=v1.8-branch"
+# 1.8.3 release tag
+SRCREV = "f1d9ceddc0e84ed8d44dd59017b0e19b75dd5dcd"
+
+S = "${WORKDIR}/git"
+
+inherit autotools pkgconfig distro_features_check
+
+REQUIRED_DISTRO_FEATURES = "opengl"
+
+PACKAGECONFIG ??= "${@bb.utils.contains("DISTRO_FEATURES", "x11", "x11", "", d)} \
+                   ${@bb.utils.contains("DISTRO_FEATURES", "opengl wayland", "wayland", "", d)}"
+PACKAGECONFIG[x11] = "--enable-x11,--disable-x11"
+PACKAGECONFIG[wayland] = "--enable-wayland,--disable-wayland,wayland wayland-native virtual/egl"
+
+FILES_${PN} += "${libdir}/dri/*.so"
+FILES_${PN}-dev += "${libdir}/dri/*.la"
+FILES_${PN}-dbg += "${libdir}/dri/.debug"
+
+UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>\d+\.\d+(\.\d+)*)"
diff --git a/recipes-multimedia/libva/va-intel.bb b/recipes-multimedia/libva/va-intel.bb
new file mode 100644
index 00000000..88539e25
--- /dev/null
+++ b/recipes-multimedia/libva/va-intel.bb
@@ -0,0 +1,32 @@
+DESCRIPTION = "Video Acceleration Add-ons for Intel BSPs"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
+
+S = "${WORKDIR}"
+
+PR = "r1"
+
+def map_valibs(d):
+    # The intel implementation requires the libva-intel-driver package
+    if bb.utils.contains('MACHINE_FEATURES', 'va-impl-intel', "1", "0", d) == "1":
+       return "libva libva-intel-driver"
+    # All meta-intel video acceleration requires libva
+    return "libva"
+
+VA_IMPL = "${@map_valibs(d)}"
+
+PACKAGES = "\
+    va-intel \
+    "
+
+ALLOW_EMPTY_va-intel = "1"
+
+RDEPENDS_va-intel = " \
+    ${VA_IMPL} \
+    "
+
+COMPATIBLE_HOST = '(i.86|x86_64).*-linux*'
+
+inherit distro_features_check
+
+REQUIRED_DISTRO_FEATURES = "opengl"
-- 
cgit v1.2.3-54-g00ecf