From 433e4f31e92e228d2df21646d838a261077a3041 Mon Sep 17 00:00:00 2001
From: Anuj Mittal <anuj.mittal@intel.com>
Date: Tue, 6 Feb 2018 16:38:19 +0800
Subject: intel-vaapi-driver: upgrade to 2.0.0

Major changes:

* Bump version to 2.0.0
* Add support for Coffee Lake (aka. CFL)
  - Decoding: H.264/MPEG-2/VC-1/JPEG/VP8/HEVC/HEVC 10-bit/VP9/VP9 10-bit
  - Encoding: H.264/MPEG-2/JPEG/VP8/VP9/HEVC/HEVC 10-bit/AVC low power CQP/CBR/VBR mode
  - VPP: CSC/scaling/NoiseReduction/Deinterlacing{Bob, MotionAdaptive, MotionCompensated}/ColorBalance/STD
* Add support for H264 FEI
* Add support for HEVC ROI encoding
* Add support for intensity compensation for VC-1 decoding
* Improve the quality of the H264 encoder on BDW/BSW
* Improve the CSC performance between I420/NV12/P010/YUY2/VYUY format
* Improve the performace of va{Get, Put}Image for I420/NV12/P010/YUY2/VYUY format
* Fix image corruption for VP9 decoding
* Fix race condition in wayland support
* Fix ROI support in VDEnc support
* Fix corrupted stream when using VDEnc CBR/VBR
* Fix GCC 7.1.1 warnings/errors
* Update the shader for HEVC encoding

The upstream package name now is intel-vaapi-driver instead of libva-intel-driver.

Updated to point to release tarball instead of git. Also, changed
the URLs to point to new project page.

Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>
Signed-off-by: California Sullivan <california.l.sullivan@intel.com>
---
 .../libva/intel-vaapi-driver_2.0.0.bb              | 33 ++++++++++++++++++++++
 1 file changed, 33 insertions(+)
 create mode 100644 recipes-multimedia/libva/intel-vaapi-driver_2.0.0.bb

(limited to 'recipes-multimedia/libva/intel-vaapi-driver_2.0.0.bb')

diff --git a/recipes-multimedia/libva/intel-vaapi-driver_2.0.0.bb b/recipes-multimedia/libva/intel-vaapi-driver_2.0.0.bb
new file mode 100644
index 00000000..e651107c
--- /dev/null
+++ b/recipes-multimedia/libva/intel-vaapi-driver_2.0.0.bb
@@ -0,0 +1,33 @@
+SUMMARY = "VA driver for Intel G45 & HD Graphics family"
+DESCRIPTION = "intel-vaapi-driver is the VA-API implementation \
+for Intel G45 chipsets and Intel HD Graphics for Intel Core \
+processor family."
+
+HOMEPAGE = "https://github.com/intel/intel-vaapi-driver"
+BUGTRACKER = "https://github.com/intel/intel-vaapi-driver/issues"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=2e48940f94acb0af582e5ef03537800f"
+
+COMPATIBLE_HOST = '(i.86|x86_64).*-linux'
+
+DEPENDS = "libva libdrm"
+
+SRC_URI = "https://github.com/intel/${BPN}/releases/download/${PV}/${BPN}-${PV}.tar.bz2"
+SRC_URI[md5sum] = "1288657b572b563b24ca27c60a10a032"
+SRC_URI[sha256sum] = "10f6b0a91f34715d8d4d9a9e0fb3cc0afe5fcf85355db1272bd5fff31522f469"
+
+UPSTREAM_CHECK_URI = "https://github.com/intel/intel-vaapi-driver/releases"
+
+inherit autotools pkgconfig distro_features_check
+
+REQUIRED_DISTRO_FEATURES = "opengl"
+
+PACKAGECONFIG ??= "${@bb.utils.contains("DISTRO_FEATURES", "x11", "x11", "", d)} \
+                   ${@bb.utils.contains("DISTRO_FEATURES", "opengl wayland", "wayland", "", d)}"
+PACKAGECONFIG[x11] = "--enable-x11,--disable-x11"
+PACKAGECONFIG[wayland] = "--enable-wayland,--disable-wayland,wayland wayland-native virtual/egl"
+
+FILES_${PN} += "${libdir}/dri/*.so"
+FILES_${PN}-dev += "${libdir}/dri/*.la"
+FILES_${PN}-dbg += "${libdir}/dri/.debug"
-- 
cgit v1.2.3-54-g00ecf