From d53dbb38c43da3fd04fed9a55e7b3b9e2c512b9a Mon Sep 17 00:00:00 2001
From: Saul Wold <sgw@linux.intel.com>
Date: Tue, 7 Nov 2017 10:32:26 -0800
Subject: meta-intel: Reorganize the layout to remove common

Remove the concept of the common directory and move all the recipes-* dirs
to the top level as a normal layer would be. layer.conf is updated appropriately

Signed-off-by: Saul Wold <sgw@linux.intel.com>
---
 .../intel-gpu-tools/intel-gpu-tools_1.19.bb        | 40 ++++++++++++++++++++++
 1 file changed, 40 insertions(+)
 create mode 100644 recipes-graphics/intel-gpu-tools/intel-gpu-tools_1.19.bb

(limited to 'recipes-graphics/intel-gpu-tools/intel-gpu-tools_1.19.bb')

diff --git a/recipes-graphics/intel-gpu-tools/intel-gpu-tools_1.19.bb b/recipes-graphics/intel-gpu-tools/intel-gpu-tools_1.19.bb
new file mode 100644
index 00000000..de9ed609
--- /dev/null
+++ b/recipes-graphics/intel-gpu-tools/intel-gpu-tools_1.19.bb
@@ -0,0 +1,40 @@
+require ${COREBASE}/meta/recipes-graphics/xorg-app/xorg-app-common.inc
+
+SUMMARY = "Intel GPU tools"
+DESCRIPTION = "Variety of small tools for testing intel graphics."
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=e4b3dd344780e0400593b21b115a6947"
+
+LICENSE_append = " & ISC"
+
+inherit autotools gtk-doc
+
+DEPENDS += "libdrm libpciaccess cairo udev glib-2.0 libxv libx11 libxext libxrandr procps"
+RDEPENDS_${PN} += "bash"
+RDEPENDS_${PN}-tests += "bash"
+
+PACKAGE_BEFORE_PN = "${PN}-benchmarks ${PN}-tests"
+
+SRC_URI[md5sum] = "4fdfa56acca3b046fc61fb12686656f3"
+SRC_URI[sha256sum] = "a49c8ae7c0431c1f33cd9492f83ec4e06e98a48429178e4bd22d9a1a87e3b0f1"
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[libunwind] = "--with-libunwind,--without-libunwind,libunwind,libunwind"
+
+EXTRA_OECONF = "--disable-nouveau --disable-shader-debugger"
+COMPATIBLE_HOST = "(x86_64.*|i.86.*)-linux"
+COMPATIBLE_HOST_libc-musl_class-target = "null"
+
+gputools_sysroot_preprocess() {
+	rm -f ${SYSROOT_DESTDIR}${libdir}/pkgconfig/intel-gen4asm.pc
+}
+SYSROOT_PREPROCESS_FUNCS += "gputools_sysroot_preprocess"
+
+FILES_${PN} += "${libdir}/intel_aubdump.so"
+FILES_${PN}-benchmarks += "${libexecdir}/intel-gpu-tools/benchmarks"
+FILES_${PN}-tests += "\
+		${libexecdir}/intel-gpu-tools/*\
+		${datadir}/intel-gpu-tools/1080p-right.png\
+		${datadir}/intel-gpu-tools/1080p-left.png\
+		${datadir}/intel-gpu-tools/pass.png\
+		${datadir}/intel-gpu-tools/test-list.txt"
-- 
cgit v1.2.3-54-g00ecf