From d5fb8c53d1934e2433a5441741429f407e7c6266 Mon Sep 17 00:00:00 2001
From: Naveen Saini <naveen.kumar.saini@intel.com>
Date: Thu, 28 May 2020 17:53:24 +0800
Subject: intel-compute-runtime: upgrade 20.15.16524 -> 20.20.16837

Release notes:
https://github.com/intel/compute-runtime/releases/tag/20.20.16837

Signed-off-by: Naveen Saini <naveen.kumar.saini@intel.com>
Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>
---
 .../intel-compute-runtime_20.20.16837.bb           | 53 ++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dynamic-layers/clang-layer/recipes-opencl/compute-runtime/intel-compute-runtime_20.20.16837.bb

(limited to 'dynamic-layers/clang-layer/recipes-opencl/compute-runtime/intel-compute-runtime_20.20.16837.bb')

diff --git a/dynamic-layers/clang-layer/recipes-opencl/compute-runtime/intel-compute-runtime_20.20.16837.bb b/dynamic-layers/clang-layer/recipes-opencl/compute-runtime/intel-compute-runtime_20.20.16837.bb
new file mode 100644
index 00000000..102b91fd
--- /dev/null
+++ b/dynamic-layers/clang-layer/recipes-opencl/compute-runtime/intel-compute-runtime_20.20.16837.bb
@@ -0,0 +1,53 @@
+SUMMARY = "The Intel(R) Graphics Compute Runtime for OpenCL(TM)"
+DESCRIPTION = "The Intel(R) Graphics Compute Runtime for OpenCL(TM) \
+is an open source project to converge Intel's development efforts \
+on OpenCL(TM) compute stacks supporting the GEN graphics hardware \
+architecture."
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=ae27f47fd6755510247c19e547e4c804 \
+                    file://third_party/opencl_headers/LICENSE;md5=dcefc90f4c3c689ec0c2489064e7273b"
+
+SRC_URI = "git://github.com/intel/compute-runtime.git;protocol=https \
+           "
+SRC_URI_append_class-target = " file://allow-to-find-cpp-generation-tool.patch"
+
+SRCREV = "b9b34659c8817393dd8ce35bf37c167c23cefcff"
+
+S = "${WORKDIR}/git"
+
+DEPENDS += " intel-graphics-compiler gmmlib clang"
+DEPENDS_append_class-target = " intel-compute-runtime-native"
+
+RDEPENDS_${PN} += " intel-graphics-compiler gmmlib"
+
+inherit cmake pkgconfig
+
+COMPATIBLE_HOST = '(x86_64).*-linux'
+COMPATIBLE_HOST_libc-musl = "null"
+
+EXTRA_OECMAKE = " \
+                 -DIGC_DIR=${STAGING_INCDIR}/igc \
+                 -DBUILD_TYPE=Release \
+                 -DSKIP_UNIT_TESTS=1 \
+                 -DCCACHE_ALLOWED=FALSE \
+                 "
+EXTRA_OECMAKE_append_class-target = " \
+                                     -Dcloc_cmd_prefix=ocloc \
+                                    "
+do_install_append_class-native() {
+    install -d ${D}${bindir}
+    install ${B}/bin/cpp_generate_tool ${D}${bindir}/
+}
+
+SOLIBS = ".so"
+FILES_SOLIBSDEV = ""
+
+FILES_${PN} += " \
+                 ${libdir}/intel-opencl/libigdrcl.so \
+                 ${libdir}/libocloc.so \
+                 "
+
+BBCLASSEXTEND = "native nativesdk"
+
+UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>\d+(\.\d+)+)"
-- 
cgit v1.2.3-54-g00ecf