From 1342bcdc5bfc6620737e7d195e7d9bd744348577 Mon Sep 17 00:00:00 2001
From: Anuj Mittal <anuj.mittal@intel.com>
Date: Tue, 29 Aug 2023 09:37:00 +0800
Subject: onednn: upgrade 2.6.1 -> 2.6.3

Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>
---
 .../clang-layer/recipes-core/dnn/onednn_2.6.3.bb   | 54 ++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 dynamic-layers/clang-layer/recipes-core/dnn/onednn_2.6.3.bb

(limited to 'dynamic-layers/clang-layer/recipes-core/dnn/onednn_2.6.3.bb')

diff --git a/dynamic-layers/clang-layer/recipes-core/dnn/onednn_2.6.3.bb b/dynamic-layers/clang-layer/recipes-core/dnn/onednn_2.6.3.bb
new file mode 100644
index 00000000..f7ec5f61
--- /dev/null
+++ b/dynamic-layers/clang-layer/recipes-core/dnn/onednn_2.6.3.bb
@@ -0,0 +1,54 @@
+HOMEPAGE = "https://www.oneapi.com"
+SUMMARY  = "Deep Neural Network Library"
+DESCRIPTION = "This software is a user mode library that accelerates\
+deep-learning applications and frameworks on Intel architecture."
+LICENSE  = "Apache-2.0 & BSD-3-Clause & BSL-1.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=b48e3de3bfd47c27882a0d85b20823f5 \
+                    file://tests/gtests/gtest/LICENSE;md5=cbbd27594afd089daa160d3a16dd515a \
+                    file://src/cpu/x64/xbyak/COPYRIGHT;md5=3b9bf048d063d54cdb28964db558bcc7 \
+                    file://src/common/ittnotify/LICENSE.BSD;md5=e671ff178b24a95a382ba670503c66fb \
+                    "
+SECTION = "lib"
+
+inherit pkgconfig cmake ptest
+
+S = "${WORKDIR}/git"
+SRCREV = "92ac40077b3b5816c7b78cdf39a988599929f0e9"
+SRC_URI = "git://github.com/oneapi-src/oneDNN.git;branch=rls-v2.6;protocol=https \
+           file://run-ptest \
+           "
+
+UPSTREAM_CHECK_GITTAGREGEX = "^v(?P<pver>(\d+(\.\d+)+))$"
+
+CVE_PRODUCT = "intel:math_kernel_library"
+
+COMPATIBLE_HOST = '(x86_64).*-linux'
+COMPATIBLE_HOST:libc-musl = 'null'
+
+EXTRA_OECMAKE += " \
+                   -DDNNL_LIBRARY_TYPE=SHARED \
+                   -DDNNL_BUILD_EXAMPLES=ON \
+                   -DDNNL_BUILD_TESTS=ON \
+                   -DDNNL_CPU_RUNTIME=OMP \
+                   -DDNNL_ARCH_OPT_FLAGS="" \
+                   -DCMAKE_SKIP_RPATH=ON \
+                   "
+
+PACKAGECONFIG ??= "gpu"
+PACKAGECONFIG[gpu] = "-DDNNL_GPU_RUNTIME=OCL, , opencl-headers ocl-icd, intel-compute-runtime"
+
+do_install:append () {
+    install -d ${D}${bindir}/mkl-dnn/tests/benchdnn/inputs
+    install -m 0755 ${B}/tests/benchdnn/benchdnn ${D}${bindir}/mkl-dnn/tests/benchdnn
+    cp -r ${B}/tests/benchdnn/inputs/* ${D}${bindir}/mkl-dnn/tests/benchdnn/inputs
+}
+
+do_install_ptest () {
+    install -d ${D}${PTEST_PATH}/tests
+    install -m 0755 ${B}/tests/api-c ${D}${PTEST_PATH}/tests
+    install -m 0755 ${B}/tests/test_c_symbols-c ${D}${PTEST_PATH}/tests
+}
+
+PACKAGES =+ "${PN}-test"
+
+FILES:${PN}-test = "${bindir}/mkl-dnn/*"
-- 
cgit v1.2.3-54-g00ecf