From 90c152050cf76c780668b861277c40ce1fe5f41f Mon Sep 17 00:00:00 2001
From: Saul Wold <sgw@linux.intel.com>
Date: Wed, 16 Dec 2015 10:33:49 -0800
Subject: intel-microcode: Update to the 20151106 version

Dates changed in Licence file required CHKSUM update

Signed-off-by: Saul Wold <sgw@linux.intel.com>
---
 .../microcode/intel-microcode_20151106.bb          | 66 ++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 common/recipes-core/microcode/intel-microcode_20151106.bb

(limited to 'common/recipes-core/microcode/intel-microcode_20151106.bb')

diff --git a/common/recipes-core/microcode/intel-microcode_20151106.bb b/common/recipes-core/microcode/intel-microcode_20151106.bb
new file mode 100644
index 00000000..f168b7d7
--- /dev/null
+++ b/common/recipes-core/microcode/intel-microcode_20151106.bb
@@ -0,0 +1,66 @@
+SUMMARY = "Intel Processor Microcode Datafile for Linux"
+HOMEPAGE = "http://www.intel.com/"
+DESCRIPTION = "The microcode data file contains the latest microcode\
+ definitions for all Intel processors. Intel releases microcode updates\
+ to correct processor behavior as documented in the respective processor\
+ specification updates. While the regular approach to getting this microcode\
+ update is via a BIOS upgrade, Intel realizes that this can be an\
+ administrative hassle. The Linux operating system and VMware ESX\
+ products have a mechanism to update the microcode after booting.\
+ For example, this file will be used by the operating system mechanism\
+ if the file is placed in the /etc/firmware directory of the Linux system."
+
+LICENSE = "Intel-Microcode-License"
+LIC_FILES_CHKSUM = "file://microcode.dat;md5=0c9b76c8fa021400a15b3fd71a71977b"
+
+SRC_URI = "http://downloadmirror.intel.com/25512/eng/microcode-${PV}.tgz"
+SRC_URI[md5sum] = "288dc721fb39d71457ef2f5a49161f57"
+SRC_URI[sha256sum] = "096e39489eef67666be652e81fa372a06b74f39ea3d565dc0287242c668717e7"
+
+DEPENDS = "iucode-tool-native"
+S = "${WORKDIR}"
+
+COMPATIBLE_HOST = "(i.86|x86_64).*-linux"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit deploy
+
+# Use any of the iucode_tool parameters to filter specific microcodes from the data file
+# For further information, check the iucode-tool's manpage : http://manned.org/iucode-tool
+UCODE_FILTER_PARAMETERS ?= ""
+
+do_compile() {
+	mkdir -p ${WORKDIR}/ucode/kernel/x86/microcode
+	${STAGING_DIR_NATIVE}${sbindir_native}/iucode_tool \
+		${UCODE_FILTER_PARAMETERS} \
+		--overwrite \
+		--write-to=${WORKDIR}/microcode_${PV}.bin \
+		${WORKDIR}/microcode.dat
+
+	${STAGING_DIR_NATIVE}${sbindir_native}/iucode_tool \
+		${UCODE_FILTER_PARAMETERS} \
+		--overwrite \
+		--write-earlyfw=${WORKDIR}/microcode_${PV}.cpio \
+		${WORKDIR}/microcode.dat
+}
+
+do_install() {
+	install -d ${D}${base_libdir}/firmware/intel-ucode/
+	install ${WORKDIR}/microcode_${PV}.bin ${D}${base_libdir}/firmware/intel-ucode/
+	cd ${D}${base_libdir}/firmware/intel-ucode/
+	ln -sf microcode_${PV}.bin microcode.bin
+}
+
+do_deploy() {
+	install -d ${DEPLOYDIR}
+	install ${S}/microcode_${PV}.cpio ${DEPLOYDIR}/
+	cd ${DEPLOYDIR}
+	rm -f microcode.cpio
+	ln -sf microcode_${PV}.cpio microcode.cpio
+}
+
+addtask deploy before do_build after do_compile
+
+PACKAGES = "${PN}"
+
+FILES_${PN} = "${base_libdir}"
-- 
cgit v1.2.3-54-g00ecf