summaryrefslogtreecommitdiffstats
path: root/recipes-support/jhi/jhi_1.33.bb
diff options
context:
space:
mode:
Diffstat (limited to 'recipes-support/jhi/jhi_1.33.bb')
-rwxr-xr-xrecipes-support/jhi/jhi_1.33.bb65
1 files changed, 65 insertions, 0 deletions
diff --git a/recipes-support/jhi/jhi_1.33.bb b/recipes-support/jhi/jhi_1.33.bb
new file mode 100755
index 00000000..034b56a6
--- /dev/null
+++ b/recipes-support/jhi/jhi_1.33.bb
@@ -0,0 +1,65 @@
1SUMMARY = "Intel Dynamic Application Loader (DAL) Host Interface"
2DESCRIPTION = "A daemon and libraries which allow user space applications \
3to install Java applets on DAL FW and communicate with them"
4LICENSE = "Apache-2.0"
5LIC_FILES_CHKSUM = "file://LICENSE;md5=833126f14614a3276708a4d7c9734645"
6
7SRC_URI = "git://github.com/intel/dynamic-application-loader-host-interface.git;protocol=https"
8
9inherit cmake useradd systemd pkgconfig
10
11SRCREV = "44d64cdbcf7eacd397ce9c18b9094514b62093e6"
12
13S = "${WORKDIR}/git"
14
15DEPENDS += "util-linux libxml2"
16DEPENDS += "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)}"
17RDEPENDS_${PN} += "bash"
18
19USERADD_PACKAGES = "${PN}"
20USERADD_PARAM_${PN} = "--system --no-create-home --shell /bin/false -g mei jhi"
21
22GROUPADD_PARAM_${PN} = "-g 880 mei"
23
24SYSTEMD_PACKAGES = "${PN}"
25
26COMPATIBLE_HOST_libc-musl = 'null'
27
28# systemd is the default so they are installed when sysvinit is not selected as INIT_SYSTEM
29EXTRA_OECMAKE = "-DCMAKE_SKIP_RPATH=ON \
30 -DINIT_SYSTEM=${@bb.utils.contains('DISTRO_FEATURES', 'sysvinit', 'SysVinit', 'systemd', d)} \
31 -DAPPLETS_DIR=${libdir}/dal/applets \
32 -DAPP_REPO_DIR=${localstatedir}/cache/dal/applet_repository \
33 "
34
35do_install_append () {
36 install -d ${D}${localstatedir}/cache/dal/applet_repository
37
38 chown -R jhi ${D}${localstatedir}/cache/dal/applet_repository
39 chgrp -R mei ${D}${localstatedir}/cache/dal/applet_repository
40
41 install -d ${D}${bindir}
42 install -m 755 ${B}/bin_linux/smoketest ${D}${bindir}
43 install -m 755 ${B}/bin_linux/bist ${D}${bindir}
44
45 install -d ${D}${libdir}/dal/smoketest/applets
46 cp -r ${S}/test/smoketest/applets/* ${D}${libdir}/dal/smoketest/applets/
47}
48
49PACKAGES =+ "${PN}-test"
50
51FILES_${PN}-dev = ""
52
53FILES_${PN} = "\
54 ${sbindir} \
55 ${sysconfdir} \
56 ${libdir} \
57 ${libdir}/dal/applets \
58 ${systemd_system_unitdir} \
59 ${localstatedir}/cache/dal/applet_repository \
60 "
61
62FILES_${PN}-test = "\
63 ${bindir} \
64 ${libdir}/dal/smoketest/applets \
65 "