summaryrefslogtreecommitdiffstats
path: root/recipes-graphics/igt-gpu-tools/igt-gpu-tools_1.25.bb
diff options
context:
space:
mode:
Diffstat (limited to 'recipes-graphics/igt-gpu-tools/igt-gpu-tools_1.25.bb')
-rw-r--r--recipes-graphics/igt-gpu-tools/igt-gpu-tools_1.25.bb39
1 files changed, 39 insertions, 0 deletions
diff --git a/recipes-graphics/igt-gpu-tools/igt-gpu-tools_1.25.bb b/recipes-graphics/igt-gpu-tools/igt-gpu-tools_1.25.bb
new file mode 100644
index 0000000..e2015b0
--- /dev/null
+++ b/recipes-graphics/igt-gpu-tools/igt-gpu-tools_1.25.bb
@@ -0,0 +1,39 @@
1require ${COREBASE}/meta/recipes-graphics/xorg-app/xorg-app-common.inc
2
3SUMMARY = "Intel GPU tools"
4DESCRIPTION = "Variety of small tools for testing intel graphics."
5
6LIC_FILES_CHKSUM = "file://COPYING;md5=67bfee4df38fa6ecbe3a675c552d4c08"
7
8LICENSE_append = " & ISC"
9
10inherit meson
11
12SRC_URI = "${XORG_MIRROR}/individual/app/${BP}.tar.xz"
13
14DEPENDS += "libdrm libpciaccess cairo udev glib-2.0 libxv libx11 libxext libxrandr procps libunwind kmod openssl elfutils bison-native"
15RDEPENDS_${PN} += "bash"
16RDEPENDS_${PN}-tests += "bash"
17
18PACKAGE_BEFORE_PN = "${PN}-benchmarks ${PN}-tests"
19
20SRC_URI[sha256sum] = "40454d8f0484ea2477862007398a08eef78a6c252c4defce1c934548593fdd11"
21
22EXTRA_OEMESON = "-Dlibdrm_drivers=intel "
23SECURITY_LDFLAGS = "${SECURITY_X_LDFLAGS}"
24
25COMPATIBLE_HOST = "(x86_64.*|i.86.*)-linux"
26COMPATIBLE_HOST_libc-musl_class-target = "null"
27
28gputools_sysroot_preprocess() {
29 rm -f ${SYSROOT_DESTDIR}${libdir}/pkgconfig/intel-gen4asm.pc
30}
31SYSROOT_PREPROCESS_FUNCS += "gputools_sysroot_preprocess"
32
33FILES_${PN}-benchmarks += "${libexecdir}/${BPN}/benchmarks"
34FILES_${PN}-tests += "\
35 ${libexecdir}/${BPN}/*\
36 ${datadir}/${BPN}/1080p-right.png\
37 ${datadir}/${BPN}/1080p-left.png\
38 ${datadir}/${BPN}/pass.png\
39 ${datadir}/${BPN}/test-list.txt"