summaryrefslogtreecommitdiffstats
path: root/recipes-bsp/amt/lms7_7.1.20.bb
diff options
context:
space:
mode:
Diffstat (limited to 'recipes-bsp/amt/lms7_7.1.20.bb')
-rw-r--r--recipes-bsp/amt/lms7_7.1.20.bb58
1 files changed, 58 insertions, 0 deletions
diff --git a/recipes-bsp/amt/lms7_7.1.20.bb b/recipes-bsp/amt/lms7_7.1.20.bb
new file mode 100644
index 00000000..eca36811
--- /dev/null
+++ b/recipes-bsp/amt/lms7_7.1.20.bb
@@ -0,0 +1,58 @@
1DESCRIPTION = "Intel Local Manageability Service allows applications \
2to access the Intel Active Management Technology (AMT) firmware via \
3the Intel Management Engine Interface (MEI)."
4HOMEPAGE = "http://software.intel.com/en-us/articles/download-the-latest-intel-amt-open-source-drivers"
5
6LICENSE = "BSD_LMS"
7
8PR = "r0"
9BPN="lms"
10PV_SUB = "25"
11SRC_URI = "http://software.intel.com/sites/default/files/m/4/e/a/9/b/37962-${BPN}_${PV}.${PV_SUB}.zip \
12 file://atnetworktool-printf-fix.patch \
13 file://readlink-declaration.patch \
14 file://0001-Protocol.cpp-Add-whitespace-for-gcc6-compile-error.patch \
15 file://0001-Include-sys-select.h-for-fd_set.patch \
16 file://0002-Use-proper-netinet-in.h-API.patch \
17 "
18
19LOCALSRC = "file://${WORKDIR}/outputdir/${BPN}-${PV}-${PV_SUB}.tar.gz"
20
21COMPATIBLE_HOST = '(i.86|x86_64).*-linux'
22
23LIC_FILES_CHKSUM = "file://COPYING;md5=7264184cf88d9f27b719a9656255b47b"
24
25SRC_URI[md5sum] = "687b76e78bfdbcf567c0e842c1fe240a"
26SRC_URI[sha256sum] = "cc0457f0044e924794bb1aeae9a72c28666a525cd8a963d0d92970222946e75b"
27
28inherit autotools update-rc.d
29
30INITSCRIPT_NAME = "lms7"
31INITSCRIPT_PARAMS = "defaults"
32
33python do_unpack() {
34 s = d.getVar('S', True)
35 d.setVar('S', '${WORKDIR}/outputdir')
36 bb.build.exec_func('base_do_unpack', d)
37 # temorarily change SRC_URI for unpack
38 src_uri = d.getVar('SRC_URI', True)
39 d.setVar('SRC_URI', '${LOCALSRC}')
40 d.setVar('S', s)
41 bb.build.exec_func('base_do_unpack', d)
42 d.setVar('SRC_URI', src_uri)
43}
44
45
46do_install_append () {
47 mv ${D}/${sbindir}/lms ${D}/${sbindir}/lms7
48 install -d ${D}${sysconfdir}/init.d
49 # The configure script looks at the host to decide where to put init
50 # scripts, so move it at the same time as renaming it.
51 if test -f ${D}${sysconfdir}/rc.d/init.d/lms ; then
52 mv ${D}${sysconfdir}/rc.d/init.d/lms ${D}${sysconfdir}/init.d/${INITSCRIPT_NAME}
53 else
54 mv ${D}${sysconfdir}/init.d/lms ${D}${sysconfdir}/init.d/${INITSCRIPT_NAME}
55 fi
56 sed -i 's/^NAME=lms/NAME=lms7/' ${D}${sysconfdir}/init.d/${INITSCRIPT_NAME}
57 rmdir ${D}${datadir} || :
58}