summaryrefslogtreecommitdiffstats
diff options
context:
space:
mode:
-rw-r--r--common/recipes-graphics/xorg-driver/emgd-driver-bin_1.10.bb91
1 files changed, 91 insertions, 0 deletions
diff --git a/common/recipes-graphics/xorg-driver/emgd-driver-bin_1.10.bb b/common/recipes-graphics/xorg-driver/emgd-driver-bin_1.10.bb
new file mode 100644
index 00000000..5779e5d8
--- /dev/null
+++ b/common/recipes-graphics/xorg-driver/emgd-driver-bin_1.10.bb
@@ -0,0 +1,91 @@
1SUMMARY = "EMGD 1.10 xserver binaries"
2DESCRIPTION = "EMGD 1.10 includes some userspace binaries that use non-free \
3licensing, which are now available via a non-click-through downloadable \
4tarball, and is what this recipe now uses. Since it is a non-free license, \
5this recipe is marked as 'License_emgd-driver-bin_1.10' and you need to add \
6to LICENSE_FLAGS_WHITELIST += \"License_emgd-driver-bin_1.10\" to your \
7local.conf in order to enable it in a build."
8LICENSE = "Intel-binary-only"
9LICENSE_FLAGS = "license_${PN}_${PV}"
10PR = "r1"
11
12EMGD_LIC_DIR = "IEMGD_HEAD_Linux/License"
13EMGD_RPM_DIR = "IEMGD_HEAD_Linux/MeeGo1.2"
14EMGD_VIDEO_PLUGIN_DIR = "../common/video_plugin"
15
16LIC_FILES_CHKSUM = "file://${WORKDIR}/${EMGD_LIC_DIR}/License.txt;md5=b54f01caaf8483b3cb60c0c40f2bf22d"
17
18DEPENDS = "rpm-native xz-native"
19
20SRC_URI = "https://edc.intel.com/App_Shared/Downloads/LIN_EMGD_1_10_RC_2209.tgz"
21
22SRC_URI[md5sum] = "e4a38d9efa0b086ae21b68145c4db4e9"
23SRC_URI[sha256sum] = "acea5f0f93a31553553428623c007d7ed0c604cf715fd87dfe075751da4be548"
24
25# These are closed binaries generated elsewhere so don't check ldflags
26INSANE_SKIP_${PN} = "ldflags"
27
28FILES_${PN} += "${libdir}/dri ${libdir}/gstreamer-0.10 ${libdir}/xorg/modules/drivers"
29FILES_${PN}-dbg += "${libdir}/xorg/modules/drivers/.debug ${libdir}/dri/.debug"
30
31S = "${WORKDIR}/${EMGD_RPM_DIR}"
32
33do_install () {
34 # A gstreamer VA buffer library
35 rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/gst-vabuffer*.rpm | cpio -id
36
37 # MIX Common contains common classes, datatype, header files used by other MIX components
38 rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/mixcommon*.rpm | cpio -id
39
40 # MIX Video Bitstream Parser is an user library interface for various video format bitstream parsing
41 rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/mixvbp*.rpm | cpio -id
42
43 # MIX Video is an user library interface for various video codecs available on the platform.
44 rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/mixvideo*.rpm | cpio -id
45
46 install -d -m 0755 ${D}${libdir}/gstreamer-0.10
47 install -m 0755 ${S}/usr/lib/* ${D}${libdir}/
48
49 # A gstreamer plugin that uses MIX Video for hardware accelerated video decoding and rendering.
50 rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/gst-plugins-mixvideo*.rpm | cpio -id
51
52 # A collection of gstreamer plugins that uses VA libraries for hardware accelerated video rendering and text overlay.
53 rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/gst-plugins-va*.rpm | cpio -id
54
55 install -m 0755 ${S}/usr/lib/gstreamer-0.10/* ${D}${libdir}/gstreamer-0.10/
56
57 # EMGD runtime graphics libraries
58 rpm2cpio ${S}/emgd-bin*.rpm | xz -d | cpio -id
59
60 install -d -m 0755 ${D}${libdir}/dri
61 install -d -m 0755 ${D}${libdir}/xorg/modules/drivers
62 install -d -m 0755 ${D}${sysconfdir}
63 install -d -m 0755 ${D}${mandir}/man4
64 install -m 0755 ${S}/usr/lib/*.so.* ${D}${libdir}/
65 install -m 0755 ${S}/usr/lib/dri/* ${D}${libdir}/dri/
66 install -m 0755 ${S}/usr/lib/xorg/modules/drivers/* ${D}${libdir}/xorg/modules/drivers/
67 install -m 0755 ${S}/etc/* ${D}${sysconfdir}/
68 install -m 0755 ${S}/usr/share/man/man4/* ${D}${mandir}/man4/
69
70 # Khronos development headers needed for EGL, OpenGL-ES, and OpenVG development
71 rpm2cpio ${S}/emgd-devel*.rpm | xz -d | cpio -id
72
73 install -d -m 0755 ${D}${includedir}/EGL
74 install -m 0755 ${S}/usr/include/EGL/*.h ${D}${includedir}/EGL/
75 install -d -m 0755 ${D}${includedir}/GLES
76 install -m 0755 ${S}/usr/include/GLES/*.h ${D}${includedir}/GLES/
77 install -d -m 0755 ${D}${includedir}/GLES2
78 install -m 0755 ${S}/usr/include/GLES2/*.h ${D}${includedir}/GLES2/
79 install -d -m 0755 ${D}${includedir}/KHR
80 install -m 0755 ${S}/usr/include/KHR/*.h ${D}${includedir}/KHR/
81 install -d -m 0755 ${D}${includedir}/VG
82 install -m 0755 ${S}/usr/include/VG/*.h ${D}${includedir}/VG/
83
84 ln -sf libEGL.so.1 ${D}${libdir}/libEGL.so
85 ln -sf libGLES_CM.so.1 ${D}${libdir}/libGLES_CM.so
86 ln -sf libGLESv2.so.2 ${D}${libdir}/libGLESv2.so
87 ln -sf libOpenVG.so.1 ${D}${libdir}/libOpenVG.so
88 ln -sf libOpenVGU.so.1 ${D}${libdir}/libOpenVGU.so
89}
90
91LEAD_SONAME = "libEGL.so"