onednn: upgrade 2.4.4 -> 2.5.2

 *Fixed performance regression in binary primitive with broadcast (b972174, ff75122).
 *Fixed issue with SYCL device properties initialization (cabc5ca, 095f13e).
 *Fixed issue in matmul primitive with zero points (3157354).
 *Fixed segmentation fault in depthwise convolution primitive for shapes with huge spatial size for processors with Intel AVX-512 support (6834764, 1d2addc).
 *Fixed issue in forward convolution primitive for processors with Intel AVX2 support (d691137).
 *Fixed performance regression on GPUs with SYCL runtime (d8364e5).

Signed-off-by: ezhilarasan s <ezhilarasanx.s@intel.com>
Signed-off-by: Anuj Mittal <anuj.mittal@intel.com>

1 files changed, 54 insertions, 0 deletions

diff --git a/dynamic-layers/clang-layer/recipes-core/dnn/onednn_2.5.2.bb b/dynamic-layers/clang-layer/recipes-core/dnn/onednn_2.5.2.bb
new file mode 100644
index 00000000..fbea19f7
--- /dev/null
+++ b/dynamic-layers/clang-layer/recipes-core/dnn/onednn_2.5.2.bb
@@ -0,0 +1,54 @@
+HOMEPAGE = "https://www.oneapi.com"
+SUMMARY  = "Deep Neural Network Library"
+DESCRIPTION = "This software is a user mode library that accelerates\
+deep-learning applications and frameworks on Intel architecture."
+LICENSE  = "Apache-2.0 & BSD-3-Clause & BSL-1.0"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=b48e3de3bfd47c27882a0d85b20823f5 \
+                    file://tests/gtests/gtest/LICENSE;md5=cbbd27594afd089daa160d3a16dd515a \
+                    file://src/cpu/x64/xbyak/COPYRIGHT;md5=3b9bf048d063d54cdb28964db558bcc7 \
+                    file://src/common/ittnotify/LICENSE.BSD;md5=e671ff178b24a95a382ba670503c66fb \
+                    "
+SECTION = "lib"
+
+inherit pkgconfig cmake ptest
+
+S = "${WORKDIR}/git"
+SRCREV = "ee7eacb012b95a677c3c1dae0d05e730d99f180e"
+SRC_URI = "git://github.com/oneapi-src/oneDNN.git;branch=rls-v2.5;protocol=https \
+           file://run-ptest \
+           "
+
+UPSTREAM_CHECK_GITTAGREGEX = "^v(?P<pver>(\d+(\.\d+)+))$"
+
+CVE_PRODUCT = "intel:math_kernel_library"
+
+COMPATIBLE_HOST = '(x86_64).*-linux'
+COMPATIBLE_HOST:libc-musl = 'null'
+
+EXTRA_OECMAKE += " \
+                   -DDNNL_LIBRARY_TYPE=SHARED \
+                   -DDNNL_BUILD_EXAMPLES=ON \
+                   -DDNNL_BUILD_TESTS=ON \
+                   -DDNNL_CPU_RUNTIME=OMP \
+                   -DDNNL_ARCH_OPT_FLAGS="" \
+                   -DCMAKE_SKIP_RPATH=ON \
+                   "
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[gpu] = "-DDNNL_GPU_RUNTIME=OCL, , opencl-headers ocl-icd, intel-compute-runtime"
+
+do_install:append () {
+    install -d ${D}${bindir}/mkl-dnn/tests/benchdnn/inputs
+    install -m 0755 ${B}/tests/benchdnn/benchdnn ${D}${bindir}/mkl-dnn/tests/benchdnn
+    cp -r ${B}/tests/benchdnn/inputs/* ${D}${bindir}/mkl-dnn/tests/benchdnn/inputs
+}
+
+do_install_ptest () {
+    install -d ${D}${PTEST_PATH}/tests
+    install -m 0755 ${B}/tests/api-c ${D}${PTEST_PATH}/tests
+    install -m 0755 ${B}/tests/test_c_symbols-c ${D}${PTEST_PATH}/tests
+}
+
+PACKAGES =+ "${PN}-test"
+
+FILES:${PN}-test = "${bindir}/mkl-dnn/*"