libva-intel-driver: upgrade to 1.2.1

Remove the .bb/.inc split as we're only supporting one version.

Add PACKAGECONFIG for X11 and Wayland features.  Add patch to fix compile error
in builds with Wayland but without X11.

Drop the workaround patch, isn't relevant for released hardware.

Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Tom Zanussi <tom.zanussi@intel.com>

1 files changed, 31 insertions, 0 deletions

diff --git a/common/recipes-multimedia/libva/libva-intel-driver_1.2.1.bb b/common/recipes-multimedia/libva/libva-intel-driver_1.2.1.bb
new file mode 100644
index 00000000..f90ad502
--- /dev/null
+++ b/common/recipes-multimedia/libva/libva-intel-driver_1.2.1.bb
@@ -0,0 +1,31 @@
+SUMMARY = "VA driver for Intel G45 & HD Graphics family"
+DESCRIPTION = "libva-driver-intel is the VA-API implementation \
+for Intel G45 chipsets and Intel HD Graphics for Intel Core \
+processor family."
+
+HOMEPAGE = "http://www.freedesktop.org/wiki/Software/vaapi"
+BUGTRACKER = "https://bugs.freedesktop.org"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=2e48940f94acb0af582e5ef03537800f"
+
+COMPATIBLE_HOST = '(i.86|x86_64).*-linux'
+
+DEPENDS = "libva libdrm"
+
+SRC_URI = "http://www.freedesktop.org/software/vaapi/releases/${BPN}/${BPN}-${PV}.tar.bz2"
+SRC_URI += "file://wayland-include.patch"
+
+SRC_URI[md5sum] = "8248d224d35c9544777f1c7250f581b2"
+SRC_URI[sha256sum] = "5c6917c961b1de7f0d5ea3a6feac8eeec098d8aff6cdf2bca44e9b3083515186"
+
+inherit autotools pkgconfig
+
+PACKAGECONFIG ??= "${@base_contains("DISTRO_FEATURES", "x11", "x11", "", d)} \
+                   ${@base_contains("DISTRO_FEATURES", "opengl wayland", "wayland", "", d)}"
+PACKAGECONFIG[x11] = "--enable-x11,--disable-x11"
+PACKAGECONFIG[wayland] = "--enable-wayland,--disable-wayland,wayland virtual/egl"
+
+FILES_${PN} += "${libdir}/dri/*.so"
+FILES_${PN}-dev += "${libdir}/dri/*.la"
+FILES_${PN}-dbg += "${libdir}/dri/.debug"