emgd-driver-bin: upgrade from 1.10 to 1.14

1.14 is the latest released driver for emgd. This change is tested on
crownbay machine.

Add runtime dependency to libxcb-dri2

Otherwise the libxcb-dri2.so is not getting installed, and video
acceleration of emgd does not work. It is dynamic dependency of
emgd_drv_video.so

put files in gstreamer-0.10/.debug directory to the debug package.
It avoids debug files packaging warnings.

add downloadfilename param to SRC_URI

As the url does not have the filename of the tarball, specify it here
so that updated wget bitbake fetcher can save the downloaded file
accordingly.
BTW now EDC has also published another download URL on our request:
http://edc.intel.com/App_Shared/Downloads/LIN_IEMGD_1_14_GOLD_2443.tgz

And update emgd driver version in the README.

Signed-off-by: Nitin A Kamble <nitin.a.kamble@intel.com>
Signed-off-by: Tom Zanussi <tom.zanussi@intel.com>
Tested-by: Tom Zanussi <tom.zanussi@intel.com>

1 files changed, 92 insertions, 0 deletions

diff --git a/common/recipes-graphics/xorg-xserver/emgd-driver-bin_1.14.bb b/common/recipes-graphics/xorg-xserver/emgd-driver-bin_1.14.bb
new file mode 100644
index 00000000..b1ba1b84
--- /dev/null
+++ b/common/recipes-graphics/xorg-xserver/emgd-driver-bin_1.14.bb
@@ -0,0 +1,92 @@
+SUMMARY = "EMGD 1.14 xserver binaries"
+DESCRIPTION = "EMGD 1.14 includes some userspace binaries that use non-free \
+licensing, which are now available via a non-click-through downloadable \
+tarball, and is what this recipe now uses.  Since it is a non-free license, \
+this recipe is marked as 'License_emgd-driver-bin_1.14' and you need to add \
+to LICENSE_FLAGS_WHITELIST += \"License_emgd-driver-bin_1.14\" to your \
+local.conf in order to enable it in a build."
+LICENSE = "Intel-binary-only"
+LICENSE_FLAGS = "license_${PN}_${PV}"
+PR = "r1"
+
+EMGD_LIC_DIR = "IEMGD_HEAD_Linux/License"
+EMGD_RPM_DIR = "IEMGD_HEAD_Linux/MeeGo1.2"
+EMGD_VIDEO_PLUGIN_DIR = "../common/video_plugin"
+
+LIC_FILES_CHKSUM = "file://${WORKDIR}/${EMGD_LIC_DIR}/License.txt;md5=b54f01caaf8483b3cb60c0c40f2bf22d"
+
+DEPENDS = "rpm-native xz-native"
+RDEPENDS = "libxcb-dri2"
+
+SRC_URI = "https://edc.intel.com/Download.aspx?id=6190;downloadfilename=LIN_IEMGD_1_14_GOLD_2443.tgz"
+
+SRC_URI[md5sum] = "733a7f237ffce21238ce2c9956df4fd6"
+SRC_URI[sha256sum] = "bcdc333b5edbda7c746a83ef821ded4a0ca55ead30980e4e3680cdb6469f45a2"
+
+# These are closed binaries generated elsewhere so don't check ldflags
+INSANE_SKIP_${PN} = "ldflags"
+
+FILES_${PN} += "${libdir}/dri ${libdir}/gstreamer-0.10 ${libdir}/xorg/modules/drivers"
+FILES_${PN}-dbg += "${libdir}/xorg/modules/drivers/.debug ${libdir}/dri/.debug ${libdir}/gstreamer-0.10/.debug"
+
+S = "${WORKDIR}/${EMGD_RPM_DIR}"
+
+do_install () {
+    # A gstreamer VA buffer library
+    rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/gst-vabuffer*.rpm | cpio -id
+
+    # MIX Common contains common classes, datatype, header files used by other MIX components
+    rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/mixcommon*.rpm | cpio -id
+
+    # MIX Video Bitstream Parser is an user library interface for various video format bitstream parsing
+    rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/mixvbp*.rpm | cpio -id
+
+    # MIX Video is an user library interface for various video codecs available on the platform.
+    rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/mixvideo*.rpm | cpio -id
+
+    install -d -m 0755                                    ${D}${libdir}/gstreamer-0.10
+    install -m 0755 ${S}/usr/lib/*                        ${D}${libdir}/
+
+    # A gstreamer plugin that uses MIX Video for hardware accelerated video decoding and rendering.
+    rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/gst-plugins-mixvideo*.rpm | cpio -id
+
+    # A collection of gstreamer plugins that uses VA libraries for hardware accelerated video rendering and text overlay.
+    rpm2cpio ${S}/${EMGD_VIDEO_PLUGIN_DIR}/gst-plugins-va*.rpm | cpio -id
+
+    install -m 0755 ${S}/usr/lib/gstreamer-0.10/*         ${D}${libdir}/gstreamer-0.10/
+
+    # EMGD runtime graphics libraries
+    rpm2cpio ${S}/emgd-bin*.rpm | xz -d | cpio -id
+
+    install -d -m 0755                                    ${D}${libdir}/dri
+    install -d -m 0755                                    ${D}${libdir}/xorg/modules/drivers
+    install -d -m 0755                                    ${D}${sysconfdir}
+    install -d -m 0755                                    ${D}${mandir}/man4
+    install -m 0755 ${S}/usr/lib/*.so.*                   ${D}${libdir}/
+    install -m 0755 ${S}/usr/lib/dri/*                    ${D}${libdir}/dri/
+    install -m 0755 ${S}/usr/lib/xorg/modules/drivers/*   ${D}${libdir}/xorg/modules/drivers/
+    install -m 0755 ${S}/etc/*                            ${D}${sysconfdir}/
+    install -m 0755 ${S}/usr/share/man/man4/*             ${D}${mandir}/man4/
+
+    # Khronos development headers needed for EGL, OpenGL-ES, and OpenVG development
+    rpm2cpio ${S}/emgd-devel*.rpm | xz -d | cpio -id
+
+    install -d -m 0755                                    ${D}${includedir}/EGL
+    install -m 0755 ${S}/usr/include/EGL/*.h              ${D}${includedir}/EGL/
+    install -d -m 0755                                    ${D}${includedir}/GLES
+    install -m 0755 ${S}/usr/include/GLES/*.h             ${D}${includedir}/GLES/
+    install -d -m 0755                                    ${D}${includedir}/GLES2
+    install -m 0755 ${S}/usr/include/GLES2/*.h            ${D}${includedir}/GLES2/
+    install -d -m 0755                                    ${D}${includedir}/KHR
+    install -m 0755 ${S}/usr/include/KHR/*.h              ${D}${includedir}/KHR/
+    install -d -m 0755                                    ${D}${includedir}/VG
+    install -m 0755 ${S}/usr/include/VG/*.h               ${D}${includedir}/VG/
+
+    ln -sf libEGL.so.1                                    ${D}${libdir}/libEGL.so
+    ln -sf libGLES_CM.so.1                                ${D}${libdir}/libGLES_CM.so
+    ln -sf libGLESv2.so.2                                 ${D}${libdir}/libGLESv2.so
+    ln -sf libOpenVG.so.1                                 ${D}${libdir}/libOpenVG.so
+    ln -sf libOpenVGU.so.1                                ${D}${libdir}/libOpenVGU.so
+}
+
+LEAD_SONAME = "libEGL.so"