Create meta-gplv2 from files from OE-Core

Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>

5 files changed, 101 insertions, 0 deletions

diff --git a/recipes-sato/rxvt-unicode.inc b/recipes-sato/rxvt-unicode.inc
new file mode 100644
index 0000000..4d5daa6
--- /dev/null
+++ b/recipes-sato/rxvt-unicode.inc
@@ -0,0 +1,58 @@
+SECTION = "x11/utils"
+SUMMARY = "rxvt terminal clone supporting unicode"
+DESCRIPTION = "rxvt-unicode is a clone of the well known \
+terminal emulator rxvt, modified to store text in Unicode \
+(either UCS-2 or UCS-4) and to use locale-correct input and \
+output. It also supports mixing multiple fonts at the \
+same time, including Xft fonts."
+DEPENDS = "virtual/libx11 libxt libxft gdk-pixbuf libxmu"
+
+SRC_URI = "http://dist.schmorp.de/rxvt-unicode/Attic/rxvt-unicode-${PV}.tar.bz2 \
+           file://xwc.patch \
+           file://rxvt.desktop \
+           file://rxvt.png"
+
+inherit autotools update-alternatives
+
+PROVIDES = "virtual/x-terminal-emulator"
+ALTERNATIVE_${PN} = "x-terminal-emulator"
+ALTERNATIVE_TARGET[x-terminal-emulator] = "${bindir}/rxvt"
+
+CFLAGS_append = " -fpermissive"
+
+EXTRA_OECONF = "--enable-xim \
+                --enable-utmp --enable-wtmp --enable-lastlog \
+                --with-term=rxvt --enable-keepscrolling \
+                --enable-xft --with-name=rxvt --enable-frills \
+                --enable-swapscreen --enable-transparency \
+                --with-codesets=eu --enable-pointer-blank \
+                --enable-text-blink --enable-rxvt-scroll \
+                --enable-combining --disable-perl \
+                --with-x=${STAGING_DIR_HOST}${prefix}"
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG[startup] = "--enable-startup-notification,--disable-startup-notification,startup-notification,"
+
+do_configure_prepend () {
+        if [ ! -e ${S}/acinclude.m4 ]; then
+                cp ${S}/aclocal.m4 ${S}/acinclude.m4
+        fi
+}
+
+do_compile_prepend () {
+        echo '#define UTMP_FILE "${localstatedir}/run/utmp"' >> config.h
+        echo '#define WTMP_FILE "${localstatedir}/log/wtmp"' >> config.h
+        echo '#define LASTLOG_FILE "${localstatedir}/log/lastlog"' >> config.h
+        echo '#define HAVE_XLOCALE 1' >> config.h
+}
+
+do_install_append () {
+        install -d ${D}/${datadir}
+        install -d ${D}/${datadir}/applications
+        install -d ${D}/${datadir}/pixmaps/
+
+        install -m 0644 ${WORKDIR}/rxvt.png ${D}/${datadir}/pixmaps
+        install -m 0644 ${WORKDIR}/rxvt.desktop ${D}/${datadir}/applications
+}
+
+FILES_${PN} += "${datadir}/applications/rxvt.desktop ${datadir}/pixmaps/rxvt.png"
diff --git a/recipes-sato/rxvt-unicode/rxvt.desktop b/recipes-sato/rxvt-unicode/rxvt.desktop
new file mode 100644
index 0000000..882ea41
--- /dev/null
+++ b/recipes-sato/rxvt-unicode/rxvt.desktop
@@ -0,0 +1,9 @@
+[Desktop Entry]
+Version=1.0
+Name=Terminal
+Comment=A unicode capable rxvt clone
+Exec=rxvt
+Icon=terminal
+Terminal=false
+Type=Application
+Categories=Utility;TerminalEmulator;
diff --git a/recipes-sato/rxvt-unicode/rxvt.png b/recipes-sato/rxvt-unicode/rxvt.png
new file mode 100644
index 0000000..e56fa2e
--- /dev/null
+++ b/recipes-sato/rxvt-unicode/rxvt.png
diff --git a/recipes-sato/rxvt-unicode/xwc.patch b/recipes-sato/rxvt-unicode/xwc.patch
new file mode 100644
index 0000000..16efeef
--- /dev/null
+++ b/recipes-sato/rxvt-unicode/xwc.patch
@@ -0,0 +1,26 @@
+Upstream-Status: Pending
+
+diff -ruN rxvt-unicode-9.10-orig//src/screen.C rxvt-unicode-9.10/src/screen.C
+--- rxvt-unicode-9.10-orig//src/screen.C        2011-04-19 13:34:01.327664984 +0800
++++ rxvt-unicode-9.10/src/screen.C      2011-04-19 13:34:47.037665001 +0800
+@@ -3152,7 +3152,7 @@
+       return false;
+     }
+ 
+-#if 0
++#if HAVE_XWC
+   XTextProperty ct;
+ 
+   if (XwcTextListToTextProperty (dpy, &selection.text, 1, XStringStyle, &ct) >= 0)
+@@ -3734,9 +3734,11 @@
+         }
+       else
+ #endif
++#ifdef HAVE_XWC
+       if (XwcTextListToTextProperty (dpy, &cl, 1, (XICCEncodingStyle) style, &ct) >= 0)
+         freect = 1;
+       else
++#endif
+         {
+           /* if we failed to convert then send it raw */
+           ct.value = (unsigned char *)cl;
diff --git a/recipes-sato/rxvt-unicode_9.20.bb b/recipes-sato/rxvt-unicode_9.20.bb
new file mode 100644
index 0000000..3480ec7
--- /dev/null
+++ b/recipes-sato/rxvt-unicode_9.20.bb
@@ -0,0 +1,8 @@
+require rxvt-unicode.inc
+
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+                    file://src/main.C;beginline=1;endline=31;md5=775485398a09fa7aee6f90464af88432"
+
+SRC_URI[md5sum] = "4a5b823f08d21036f94a6c51e94d025b"
+SRC_URI[sha256sum] = "e73e13fe64b59fd3c8e6e20c00f149d388741f141b8155e4700d3ed40aa94b4e"