10 files changed, 466 insertions, 0 deletions

diff --git a/recipes-bsp/apptrk/apptrk_git.bb b/recipes-bsp/apptrk/apptrk_git.bb
new file mode 100644
index 0000000..09d5de5
--- /dev/null
+++ b/recipes-bsp/apptrk/apptrk_git.bb
@@ -0,0 +1,20 @@
+DESCRIPTION = "Userspace debug agent for PA CodeWarrior"
+LICENSE = "Freescale-EULA"
+LIC_FILES_CHKSUM = "file://COPYING;md5=95560debfde180684364319811cc1421"
+
+DEPENDS = "elfutils"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/apptrk.git;nobranch=1"
+SRCREV = "cbed10997c5e2a4aaa004fb0e1efec858bf1bbe1"
+
+S = "${WORKDIR}/git"
+
+CFLAGS += " -I${STAGING_INCDIR} -ISource/Linux -ISource/Portable \
+                 -ISource/Linux_PA -ISource/PA -DPPC \
+"
+CFLAGS_append_powerpc64 = " -DENABLE_64BIT_SUPPORT"
+
+do_install() {
+        install -d ${D}/usr/bin
+        oe_runmake install DESTDIR=${D}
+}
diff --git a/recipes-bsp/boot-format/boot-format/flags.patch b/recipes-bsp/boot-format/boot-format/flags.patch
new file mode 100644
index 0000000..cddb34c
--- /dev/null
+++ b/recipes-bsp/boot-format/boot-format/flags.patch
@@ -0,0 +1,21 @@
+Index: git/Makefile
+===================================================================
+--- git.orig/Makefile
++++ git/Makefile
+@@ -3,14 +3,14 @@
+ INSTALL=install
+ PREFIX=/usr
+ 
+-CFLAGS=-Wall
++override CFLAGS+=-Wall
+ 
+ all: boot_format
+ 
+ boot_format.o: boot_format.c boot_format.h
+ 
+ boot_format: boot_format.o
+-       $(CC) $< -o $@
++       $(CC) $(CFLAGS) $< -o $@ $(LDFLAGS)
+ 
+ install: boot_format
+        $(INSTALL) -d $(DESTDIR)$(PREFIX)/bin
diff --git a/recipes-bsp/boot-format/boot-format_git.bb b/recipes-bsp/boot-format/boot-format_git.bb
new file mode 100644
index 0000000..2d9f9b1
--- /dev/null
+++ b/recipes-bsp/boot-format/boot-format_git.bb
@@ -0,0 +1,20 @@
+DESCRIPTION = "Boot format utility for booting from eSDHC/eSPI"
+LICENSE = "GPLv2"
+PR = "r6"
+LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/boot-format.git;nobranch=1 \
+           file://flags.patch"
+SRCREV = "4eb81a6797ef4e58bf7d9b2d58afb37a21c1f550"
+
+S = "${WORKDIR}/git"
+EXTRA_OEMAKE = 'CC="${CC}" CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"'
+
+do_install(){
+        oe_runmake DESTDIR=${D} PREFIX=${prefix} install
+}
+
+PACKAGES =+ "${PN}-config"
+FILES_${PN}-config += "${datadir}/*"
+
+BBCLASSEXTEND = "native nativesdk"
diff --git a/recipes-bsp/ipc/ipc-ust_git.bb b/recipes-bsp/ipc/ipc-ust_git.bb
new file mode 100644
index 0000000..c6b3cfe
--- /dev/null
+++ b/recipes-bsp/ipc/ipc-ust_git.bb
@@ -0,0 +1,50 @@
+SUMMARY = "Linux IPC Userspace Tool"
+DESCRIPTION = "DSP boot application and ipc test application"
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://COPYING;md5=fa38cd73d71527dc6efb546474f64d10"
+
+require ipc.inc
+
+S = "${WORKDIR}/git"
+
+# workaround for issue of parallel build, required a actual fix in ipc source
+PARALLEL_MAKE = ""
+
+EXTRA_OEMAKE = 'CROSS_COMPILE="${TARGET_PREFIX}" CC="${CC}" AR="${AR}"'
+
+do_compile () {
+    case ${MACHINE} in
+        bsc9132qds|bsc9131rdb) SOC=B913x;;
+        b4860qds|b4420qds|b4860qds-64b) SOC=B4860;;
+    esac
+    oe_runmake ${SOC}=1
+}
+
+do_install () {
+    install -d ${D}${bindir}
+    install -d ${D}${includedir}
+    install -d ${D}/ipc
+    install -m 755 ${S}/dsp_boot/dsp_bt ${D}/ipc
+    install -m 755 ${S}/ipc/ipc_test ${D}/ipc
+    install -m 755 ${S}/ipc/ipc_test67 ${D}/ipc
+    install -m 755 ${S}/ipc/l1d_app ${D}/ipc
+    install -m 755 ${S}/fsl_shm/app ${D}${bindir}/lg_shm_test
+    install -d ${D}${base_libdir}
+    install -m 755 ${S}/ipc/libipc.so ${D}${base_libdir}
+    install -m 755 ${S}/ipc/libmem.so ${D}${base_libdir}
+    install -m 755 ${S}/ipc/libdspboot.so  ${D}${base_libdir}
+    install -d ${D}${includedir}/ipc
+    install -d ${D}${includedir}/ipc/ipc/include
+    install -d ${D}${includedir}/ipc/fsl_shm/lib
+    install ${S}/ipc/include/*.h ${D}${includedir}/ipc/ipc/include
+    install ${S}/dsp_boot/*.h ${D}${includedir}/ipc/ipc/include
+    install ${S}/kernel/fsl_ipc_types.h ${D}${includedir}/ipc/ipc/include
+    install ${S}/kernel/fsl_heterogeneous_common.h ${D}${includedir}/ipc/ipc/include
+    install ${S}/kernel/fsl_heterogeneous_l1_defense.h ${D}${includedir}/ipc/ipc/include
+    install ${S}/fsl_shm/include/*.h ${D}${includedir}/ipc/ipc/include
+    install ${S}/fsl_shm/lib/*.h ${D}${includedir}/ipc/fsl_shm/lib
+}
+
+FILES_${PN} += "/ipc/*"
+FILES_${PN}-dbg += "/ipc/.debug"
+
diff --git a/recipes-bsp/ipc/ipc.inc b/recipes-bsp/ipc/ipc.inc
new file mode 100644
index 0000000..547771a
--- /dev/null
+++ b/recipes-bsp/ipc/ipc.inc
@@ -0,0 +1,7 @@
+DEPENDS = "virtual/kernel"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/ipc.git;nobranch=1"
+SRCREV = "c9c92ac6a7a31c9d878096eb7d135c22a38f20ff"
+
+COMPATIBLE_MACHINE = "(bsc9132qds|bsc9131rdb|b4860qds|b4420qds)"
+
diff --git a/recipes-bsp/pkc-firmware/pkc-firmware_git.bb b/recipes-bsp/pkc-firmware/pkc-firmware_git.bb
new file mode 100644
index 0000000..3cc5d44
--- /dev/null
+++ b/recipes-bsp/pkc-firmware/pkc-firmware_git.bb
@@ -0,0 +1,41 @@
+DESCRIPTION = "U-boot firmware for c293pcie support "
+HOMEPAGE = "http://u-boot.sf.net"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=1707d6db1d42237583f50183a5651ecb"
+
+INHIBIT_DEFAULT_DEPS = "1"
+DEPENDS = "virtual/${TARGET_PREFIX}gcc libgcc"
+
+inherit deploy
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/pkc-firmware.git;nobranch=1"
+SRCREV = "b891873c1eea7a7d53f9472ea601712897cb17b7"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${TARGET_PREFIX}gcc ${TOOLCHAIN_OPTIONS}"'
+
+do_compile () {
+    unset LDFLAGS
+    unset CFLAGS
+    unset CPPFLAGS
+    oe_runmake C293QDS_36BIT_SDCARD
+}
+
+do_install(){
+    install -d ${D}${sysconfdir}/crypto/
+    install ${S}/u-boot.bin ${D}${sysconfdir}/crypto/pkc-firmware.bin
+}
+
+do_deploy(){
+    install -d ${DEPLOYDIR}/pkc-firmware
+    install ${S}/u-boot.bin ${DEPLOYDIR}/pkc-firmware/pkc-firmware.bin
+}
+
+addtask deploy after do_install
+
+FILES_{PN} += "/etc/crypto/pkc-firmware.bin"
+COMPATIBLE_MACHINE = "(c293pcie)"
+
diff --git a/recipes-bsp/qe-ucode/qe-ucode_git.bb b/recipes-bsp/qe-ucode/qe-ucode_git.bb
new file mode 100644
index 0000000..028d9bc
--- /dev/null
+++ b/recipes-bsp/qe-ucode/qe-ucode_git.bb
@@ -0,0 +1,35 @@
+DESCRIPTION = "qe microcode binary"
+SECTION = "qe-ucode"
+LICENSE = "Freescale-EULA"
+LIC_FILES_CHKSUM = "file://EULA;md5=60037ccba533a5995e8d1a838d85799c"
+
+python () {
+    if not d.getVar("QE_UCODE", True):
+        machine = d.getVar("MACHINE", True)
+        raise bb.parse.SkipPackage("QE_UCODE not set in \
+            meta-fsl-ppc/conf/machine/%s.conf" % machine)
+}
+
+inherit deploy
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/qe-ucode.git;nobranch=1"
+SRCREV= "49efc94b553de5c2a9bd28093592eff0068e161c"
+
+S = "${WORKDIR}/git"
+
+do_install () {
+    install -d ${D}/boot
+    install -m 644 ${QE_UCODE} ${D}/boot/
+}
+
+do_deploy () {
+    install -d ${DEPLOYDIR}/boot
+    install -m 644 ${QE_UCODE} ${DEPLOYDIR}/boot/
+}
+addtask deploy before do_build after do_install
+
+PACKAGES += "${PN}-image"
+FILES_${PN}-image += "/boot/*"
+ALLOW_EMPTY_${PN} = "1"
+COMPATIBLE_MACHINE = "(p1021rdb|p1025twr|t1)"
+
diff --git a/recipes-bsp/rcw/rcw_git.bb b/recipes-bsp/rcw/rcw_git.bb
new file mode 100644
index 0000000..97ffcb8
--- /dev/null
+++ b/recipes-bsp/rcw/rcw_git.bb
@@ -0,0 +1,47 @@
+DESCRIPTION = "Reset Control Words (RCW)"
+SECTION = "rcw"
+LICENSE = "BSD"
+PR = "r8"
+
+LIC_FILES_CHKSUM = "file://rcw.py;beginline=8;endline=28;md5=9ba0b28922dd187b06b6c8ebcfdd208e"
+
+# this package is specific to the machine itself
+INHIBIT_DEFAULT_DEPS = "1"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+inherit deploy
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/rcw.git;nobranch=1"
+SRCREV = "3e89f378ed70e9b856756de8c3dbdfccb045fa0c"
+
+S = "${WORKDIR}/git"
+
+export PYTHON
+
+do_install () {
+    make install
+
+    M=`echo ${MACHINE} | sed s/-prt//g | sed s/-64b//g`
+    if [ "t1042rdb" = "${M}" ] || [ "t1042rdb-pi" = "${M}" ];then
+        M=t1042rdb_pi
+    fi
+    install -d ${D}/boot/rcw
+    cp -r ${S}/${M}/${M}/* ${D}/boot/rcw
+}
+
+do_deploy () {
+    M=`echo ${MACHINE} | sed s/-prt//g | sed s/-64b//g`
+    if [ "t1042rdb" = "${M}" ] || [ "t1042rdb-pi" = "${M}" ];then
+        M=t1042rdb_pi
+    fi
+    install -d ${DEPLOYDIR}/rcw
+    cp -r ${S}/${M}/${M}/* ${DEPLOYDIR}/rcw
+}
+addtask deploy after do_install
+
+PACKAGES += "${PN}-image"
+FILES_${PN}-image += "/boot"
+
+COMPATIBLE_HOST_qoriq-ppc = ".*"
+COMPATIBLE_HOST ?= "(none)"
+ALLOW_EMPTY_${PN} = "1"
diff --git a/recipes-bsp/u-boot/files/Fix-the-depend-race-issue.patch b/recipes-bsp/u-boot/files/Fix-the-depend-race-issue.patch
new file mode 100644
index 0000000..1ddc667
--- /dev/null
+++ b/recipes-bsp/u-boot/files/Fix-the-depend-race-issue.patch
@@ -0,0 +1,38 @@
+Upstream-Status: Pending
+
+From 301832414369b749918e0d5db850eed19b81c0fc Mon Sep 17 00:00:00 2001
+From: Zhenhua Luo <zhenhua.luo@freescale.com>
+Date: Tue, 24 Sep 2013 00:54:40 -0500
+Subject: [PATCH] Fix the depend race issue
+
+| make[3]: Entering directory `/srv/home/pokybuild/yocto-autobuilder-new/yocto-slave/nightly-fsl-ppc/build/build/tmp/work/p1022ds-poky-linux-gnuspe/u-boot/git-r30/git/arch/powerpc/cpu/mpc85xx'
+| /srv/home/pokybuild/yocto-autobuilder-new/yocto-slave/nightly-fsl-ppc/build/build/tmp/work/p1022ds-poky-linux-gnuspe/u-boot/git-r30/git/P1022DS_NAND/spl/arch/powerpc/cpu/mpc85xx/.depend:125: *** missing separator.  Stop.
+| make[3]: Leaving directory `/srv/home/pokybuild/yocto-autobuilder-new/yocto-slave/nightly-fsl-ppc/build/build/tmp/work/p1022ds-poky-linux-gnuspe/u-boot/git-r30/git/arch/powerpc/cpu/mpc85xx'
+| make[2]: *** [/srv/home/pokybuild/yocto-autobuilder-new/yocto-slave/nightly-fsl-ppc/build/build/tmp/work/p1022ds-poky-linux-gnuspe/u-boot/git-r30/git/P1022DS_NAND/spl/arch/powerpc/cpu/mpc85xx/start.o] Error 2
+| make[2]: *** Waiting for unfinished jobs....
+
+Signed-off-by: Zhenhua Luo <zhenhua.luo@freescale.com>
+---
+ spl/Makefile | 6 +++++-
+ 1 file changed, 5 insertions(+), 1 deletion(-)
+
+diff --git a/spl/Makefile b/spl/Makefile
+index 6dbb105..3156d87 100644
+--- a/spl/Makefile
++++ b/spl/Makefile
+@@ -185,7 +185,11 @@ $(eval $(call make_u_boot_list, $(obj)u-boot.lst, $(LIBS)))
+ $(obj)u-boot-spl.lds: $(LDSCRIPT) $(obj)u-boot.lst depend
+        $(CPP) $(CPPFLAGS) $(LDPPFLAGS) -I$(obj). -ansi -D__ASSEMBLY__ -P - < $< > $@
+ 
+-depend:        $(obj).depend
++# Explicitly make _depend in subdirs containing multiple targets to prevent
++# parallel sub-makes creating .depend files simultaneously.
++depend dep:    $(obj).depend
++               for dir in $(SUBDIRS) $(CPUDIR) $(LDSCRIPT_MAKEFILE_DIR) ; do \
++                       $(MAKE) -C $(SRCTREE)/$$dir _depend ; done
+ .PHONY: depend
+ 
+ # defines $(obj).depend target
+-- 
+1.8.2.1
+
diff --git a/recipes-bsp/u-boot/u-boot-qoriq_2014.07.bb b/recipes-bsp/u-boot/u-boot-qoriq_2014.07.bb
new file mode 100644
index 0000000..b780658
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-qoriq_2014.07.bb
@@ -0,0 +1,187 @@
+DESCRIPTION = "U-boot bootloader"
+HOMEPAGE = "http://u-boot.sf.net"
+SECTION = "bootloaders"
+PROVIDES = "virtual/bootloader u-boot"
+LICENSE = "GPLv2 & BSD-3-Clause & BSD-2-Clause & LGPL-2.0 & LGPL-2.1"
+LIC_FILES_CHKSUM = " \
+    file://Licenses/gpl-2.0.txt;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+    file://Licenses/bsd-2-clause.txt;md5=6a31f076f5773aabd8ff86191ad6fdd5 \
+    file://Licenses/bsd-3-clause.txt;md5=4a1190eac56a9db675d58ebe86eaf50c \
+    file://Licenses/lgpl-2.0.txt;md5=5f30f0716dfdd0d91eb439ebec522ec2 \
+    file://Licenses/lgpl-2.1.txt;md5=4fbd65380cdd255951079008b364516c \
+"
+
+PV = "2014.07+fslgit"
+INHIBIT_DEFAULT_DEPS = "1"
+DEPENDS = "boot-format-native libgcc ${@base_contains('TCMODE', 'external-fsl', '', 'virtual/${TARGET_PREFIX}gcc', d)}"
+
+inherit deploy
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/u-boot.git;nobranch=1"
+SRCREV = "659b6a23a8b1f3026200bc6352dbacef53f4dcb1"
+
+python () {
+    if d.getVar("TCMODE", True) == "external-fsl":
+        return
+
+    ml = d.getVar("MULTILIB_VARIANTS", True)
+    arch = d.getVar("OVERRIDES", True)
+
+    if "e5500-64b:" in arch or "e6500-64b:" in arch:
+        if not "lib32" in ml:
+            raise bb.parse.SkipPackage("Building the u-boot for this arch requires multilib to be enabled")
+        sys_multilib = 'powerpc' + d.getVar('TARGET_VENDOR') + 'mllib32-' + d.getVar('HOST_OS')
+        d.setVar('DEPENDS_append', ' lib32-gcc-cross-powerpc lib32-libgcc')
+        d.setVar('PATH_append', ':' + d.getVar('STAGING_BINDIR_NATIVE') + '/' + sys_multilib)
+        d.setVar('TOOLCHAIN_OPTIONS_append', '/../lib32-' + d.getVar("MACHINE"))
+        d.setVar("WRAP_TARGET_PREFIX", sys_multilib + '-')
+}
+
+WRAP_TARGET_PREFIX ?= "${TARGET_PREFIX}"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+UBOOT_LOCALVERSION = "${@d.getVar('SDK_VERSION', True).partition(' ')[0]}"
+
+USRC ?= ""
+S = '${@base_conditional("USRC", "", "${WORKDIR}/git", "${USRC}", d)}'
+
+EXTRA_OEMAKE = 'CROSS_COMPILE=${WRAP_TARGET_PREFIX} CC="${WRAP_TARGET_PREFIX}gcc ${TOOLCHAIN_OPTIONS}"'
+
+do_compile () {
+    unset LDFLAGS
+    unset CFLAGS
+    unset CPPFLAGS
+
+    if [ ! -e ${B}/.scmversion -a ! -e ${S}/.scmversion ]
+    then
+        head=`git rev-parse --verify --short HEAD 2> /dev/null`
+        printf "%s%s%s" ${UBOOT_LOCALVERSION} +g $head > ${B}/.scmversion
+        printf "%s%s%s" ${UBOOT_LOCALVERSION} +g $head > ${S}/.scmversion
+    fi
+
+    if [ "x${UBOOT_MACHINES}" = "x" ]; then
+        UBOOT_MACHINES=${UBOOT_MACHINE}
+    fi
+
+    for board in ${UBOOT_MACHINES}; do
+        if ! grep -wq $board ${S}/boards.cfg;then
+            echo "WARNING: $board not supported in boards.cfg"
+            continue
+        fi
+
+        oe_runmake O=${board} distclean
+        oe_runmake O=${board} ${board}_config
+        oe_runmake O=${board} all
+
+        case "${board}" in
+            *SDCARD*)   UBOOT_TARGET="u-boot-sd";;
+            *SPIFLASH*) UBOOT_TARGET="u-boot-spi";;
+            *NAND*)     UBOOT_TARGET="u-boot-nand";;
+            *SRIO*)     UBOOT_TARGET="u-boot-srio";;
+            *)      UBOOT_TARGET="";;
+        esac
+
+        # deal with sd/spi/nand/srio image
+        UBOOT_SOURCE=u-boot.bin
+        if [ "x${UBOOT_TARGET}" != "x" ] && echo $board |egrep -qi "SECBOOT|SECURE"; then
+            cp ${S}/${board}/${UBOOT_SOURCE}  ${S}/${board}/${UBOOT_TARGET}.bin
+        elif [ "x${UBOOT_TARGET}" != "x" ]; then
+            # some boards' final binary was not named as u-boot.bin
+            if [ "${UBOOT_TARGET}" = "u-boot-nand" ];then
+                if echo $board |egrep -q "^(BSC|C29|P10|P2020RDB)";then
+                    UBOOT_SOURCE=u-boot-with-spl.bin
+                elif echo $board |egrep -q "^(B4|T1|T2|T4)";then
+                    UBOOT_SOURCE=u-boot-with-spl-pbl.bin
+                elif echo $board |egrep -q "^(P2041|P3|P4|P5)";then
+                    UBOOT_SOURCE=u-boot.pbl
+                fi
+            elif [ "${UBOOT_TARGET}" = "u-boot-spi" ];then
+                if echo $board |egrep -q "^(P10|P2020RDB)";then
+                    UBOOT_SOURCE=u-boot-with-spl.bin
+                elif echo $board |egrep -q "^(T1|T2)";then
+                    UBOOT_SOURCE=u-boot-with-spl-pbl.bin
+                elif echo $board |egrep -q "^(B4|P2041|P3|P4|P5|T4)";then
+                    UBOOT_SOURCE=u-boot.pbl
+                fi
+            elif [ "${UBOOT_TARGET}" = "u-boot-sd" ];then
+                if echo $board |egrep -q "^(P10|P2020RDB)";then
+                    UBOOT_SOURCE=u-boot-with-spl.bin
+                elif echo $board |egrep -q "^(B4|T1|T2|T4)";then
+                    UBOOT_SOURCE=u-boot-with-spl-pbl.bin
+                elif echo $board |egrep -q "^(P2041|P3|P4|P5)";then
+                    UBOOT_SOURCE=u-boot.pbl
+                fi
+            fi
+            cp ${S}/${board}/${UBOOT_SOURCE}  ${S}/${board}/${UBOOT_TARGET}.bin
+
+            # use boot-format to regenerate spi image if BOOTFORMAT_CONFIG is not empty
+            if [ "${UBOOT_TARGET}" = "u-boot-spi" ] && [ -n "${BOOTFORMAT_CONFIG}" ];then
+                ${STAGING_BINDIR_NATIVE}/boot_format \
+                ${STAGING_DATADIR_NATIVE}/boot_format/${BOOTFORMAT_CONFIG} \
+                ${S}/${board}/${UBOOT_SOURCE} -spi ${S}/${board}/${UBOOT_TARGET}.bin
+            fi
+        fi
+    done
+}
+
+do_install(){
+    if [ "x${UBOOT_MACHINES}" = "x" ]; then
+        UBOOT_MACHINES=${UBOOT_MACHINE}
+    fi
+
+    for board in ${UBOOT_MACHINES}; do
+        if ! grep -wq $board ${S}/boards.cfg;then
+            continue
+        fi
+
+        case "${board}" in
+            *SDCARD*)   UBOOT_TARGET="u-boot-sd";;
+            *SPIFLASH*) UBOOT_TARGET="u-boot-spi";;
+            *NAND*)     UBOOT_TARGET="u-boot-nand";;
+            *SRIO*)     UBOOT_TARGET="u-boot-srio";;
+            *)      UBOOT_TARGET="u-boot";;
+        esac
+
+        if [ -f ${S}/${board}/${UBOOT_TARGET}.bin ]; then
+            mkdir -p ${D}/boot/
+            install ${S}/${board}/${UBOOT_TARGET}.bin ${D}/boot/${UBOOT_TARGET}-${board}-${PV}-${PR}.bin
+            ln -sf ${UBOOT_TARGET}-${board}-${PV}-${PR}.bin ${D}/boot/${UBOOT_TARGET}.bin
+        fi
+    done
+}
+
+do_deploy(){
+    if [ "x${UBOOT_MACHINES}" = "x" ]; then
+        UBOOT_MACHINES=${UBOOT_MACHINE}
+    fi
+
+    for board in ${UBOOT_MACHINES}; do
+        if ! grep -wq $board ${S}/boards.cfg;then
+            continue
+        fi
+
+        case "${board}" in
+            *SDCARD*)   UBOOT_TARGET="u-boot-sd";;
+            *SPIFLASH*) UBOOT_TARGET="u-boot-spi";;
+            *NAND*)     UBOOT_TARGET="u-boot-nand";;
+            *SRIO*)     UBOOT_TARGET="u-boot-srio";;
+            *)      UBOOT_TARGET="u-boot";;
+        esac
+
+        if [ -f ${S}/${board}/${UBOOT_TARGET}.bin ]; then
+            mkdir -p ${DEPLOYDIR}
+            install ${S}/${board}/${UBOOT_TARGET}.bin ${DEPLOYDIR}/${UBOOT_TARGET}-${board}-${PV}-${PR}.bin
+
+            cd ${DEPLOYDIR}
+            rm -f ${UBOOT_TARGET}-${board}.bin
+            ln -sf ${UBOOT_TARGET}-${board}-${PV}-${PR}.bin ${UBOOT_TARGET}-${board}.bin
+        fi
+    done
+}
+addtask deploy after do_install
+
+PACKAGES += "${PN}-images"
+FILES_${PN}-images += "/boot"
+
+ALLOW_EMPTY_${PN} = "1"