change layout to follow oe-core guidelines of recipes

Follow the rules defined in:
http://git.yoctoproject.org/cgit/cgit.cgi/poky/tree/meta/recipes.txt

recipes-bsp          - Anything with links to specific hardware or
                       hardware configuration information
recipes-connectivity - Libraries and applications related to
                       communication with other devices
recipes-core         - What's needed to build a basic working Linux
                       image including commonly used dependencies
recipes-devtools     - Tools primarily used by the build system (but can
                       also be used on targets)
recipes-extended     - Applications which whilst not essential add
                       features compared to the alternatives in
                       core. May be needed for full tool functionality
                       or LSB compliance.
recipes-gnome        - All things related to the GTK+ application
                       framework
recipes-graphics     - X and other graphically related system libraries
recipes-kernel       - The kernel and generic applications/libraries
                       with strong kernel dependencies
recipes-lsb4         - Recipes added for the sole purpose of supporting
                       the Linux Standard Base (LSB) 4.x
recipes-multimedia   - Codecs and support utilties for audio, images and
                       video
recipes-rt           - Provides package and image recipes for using and
                       testing the PREEMPT_RT kernel
recipes-qt           - All things related to the Qt application
                       framework
recipes-sato         - The Sato demo/reference UI/UX, its associated
                       apps and configuration
recipes-support      - Recipes used by other recipes but that are not
                       directly included in images
recipes-dpaa         - recipes related to fsl dpaa feature
recipes-virtualization - recipes related to fsl virtualization feature

Signed-off-by: Ting Liu <b28495@freescale.com>

7 files changed, 268 insertions, 0 deletions

diff --git a/recipes-dpaa/eth-config/eth-config_git.bb b/recipes-dpaa/eth-config/eth-config_git.bb
new file mode 100644
index 0000000..ac25013
--- /dev/null
+++ b/recipes-dpaa/eth-config/eth-config_git.bb
@@ -0,0 +1,19 @@
+DESCRIPTION = "Ethernet Configuration Files"
+SECTION = "eth-config"
+LICENSE = "Freescale-EULA"
+LIC_FILES_CHKSUM = "file://COPYING;md5=cf02dc8eb5ac4a76f3812826520dea87"
+
+PR = "r2"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/eth-config.git"
+SRCREV = "c255231fb606bff18390da3b26e1ee9fca55e4e6"
+
+S = "${WORKDIR}/git"
+
+do_install() {
+        install -d ${D}/etc/fmc/config
+        install -m 644 ${S}/*.xml ${D}/etc/fmc/config
+        install -d ${D}/etc/fmc/config/shared_mac
+        install -m 644 ${S}/shared_mac/*.xml ${D}/etc/fmc/config/shared_mac
+        install -m 644 ${S}/shared_mac/README ${D}/etc/fmc/config/shared_mac
+}
diff --git a/recipes-dpaa/flib/flib_git.bb b/recipes-dpaa/flib/flib_git.bb
new file mode 100644
index 0000000..fb3f698
--- /dev/null
+++ b/recipes-dpaa/flib/flib_git.bb
@@ -0,0 +1,15 @@
+DESCRIPTION = "Foundation Library"
+SECTION = "flib"
+LICENSE = "BSD & GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=3f16fa8e677e45af3127c5c4bafc3c00"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/flib.git"
+SRCREV = "ff692ad3c286a07717c6677177825889fe17d450"
+
+S = "${WORKDIR}/git"
+
+do_install(){
+    oe_runmake install DESTDIR=${D}
+}
+
+ALLOW_EMPTY_${PN} = "1"
diff --git a/recipes-dpaa/fm-ucode/fm-ucode_git.bb b/recipes-dpaa/fm-ucode/fm-ucode_git.bb
new file mode 100644
index 0000000..76d00b9
--- /dev/null
+++ b/recipes-dpaa/fm-ucode/fm-ucode_git.bb
@@ -0,0 +1,46 @@
+DESCRIPTION = "Fman microcode binary"
+SECTION = "fm-ucode"
+LICENSE = "Freescale-EULA"
+LIC_FILES_CHKSUM = "file://EULA;md5=60037ccba533a5995e8d1a838d85799c"
+
+PR = "r1"
+
+COMPATIBLE_MACHINE = "(p1023rdb|p2041rdb|p3041ds|p4080ds|p5020ds|p5040ds|p5020ds-64b|p5040ds-64b|b4420qds|b4420qds-64b|b4860qds|b4860qds-64b|t4160qds|t4160qds-64b|t4240qds|t4240qds-64b)"
+inherit deploy
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/fm-ucode.git"
+SRCREV = "4ca0e41de225b34962e1517c2c75bbb31a381e1a"
+
+S = "${WORKDIR}/git"
+
+ALLOW_EMPTY_${PN} = "1"
+do_install () {
+    case ${MACHINE} in
+        b4420qds|b4420qds-64b|b4860qds|b4860qds-64b) UCODE=b4860qds;;
+        t4240qds|t4240qds-64b|t4160qds|t4160qds-64b) UCODE=t4240qds;;
+        p5020ds|p5020ds-64b) UCODE=p5020ds;;
+        p5040ds|p5040ds-64b) UCODE=p5040ds;;
+        *) UCODE=${MACHINE};;
+    esac
+    UCODE=`echo $UCODE | sed -e 's,[a-zA-Z]*$,,'`
+    install -d ${D}/boot
+    install -m 644 fsl_fman_ucode_${UCODE}*.bin ${D}/boot/
+}
+
+do_deploy () {
+    case ${MACHINE} in
+        b4420qds|b4420qds-64b|b4860qds|b4860qds-64b) UCODE=b4860qds;;
+        t4240qds|t4240qds-64b|t4160qds|t4160qds-64b) UCODE=t4240qds;;
+        p5020ds|p5020ds-64b) UCODE=p5020ds;;
+        p5040ds|p5040ds-64b) UCODE=p5040ds;;
+        *) UCODE=${MACHINE};;
+    esac
+    UCODE=`echo $UCODE | sed -e 's,[a-zA-Z]*$,,'`
+    install -d ${DEPLOYDIR}/
+    install -m 644 fsl_fman_ucode_${UCODE}*.bin ${DEPLOYDIR}/
+}
+addtask deploy before do_build after do_install
+
+PACKAGES += "${PN}-image"
+FILES_${PN}-image += "/boot"
+
diff --git a/recipes-dpaa/fmc/fmc_git.bb b/recipes-dpaa/fmc/fmc_git.bb
new file mode 100644
index 0000000..20f93f6
--- /dev/null
+++ b/recipes-dpaa/fmc/fmc_git.bb
@@ -0,0 +1,53 @@
+DESCRIPTION = "Frame Manager Configuration tool"
+SECTION = "fmc"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://COPYING;md5=a504ab5a8ff235e67c7301214749346c"
+
+PR = "r2"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/fmc.git"
+SRCREV = "f2e1a831a96f1d04d3d5a5970d2e54c38098cf39"
+
+DEPENDS = "libxml2 fmlib tclap"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = 'FMD_USPACE_HEADER_PATH="${STAGING_INCDIR}/fmd" \
+    FMD_USPACE_LIB_PATH="${STAGING_LIBDIR}" LIBXML2_HEADER_PATH="${STAGING_INCDIR}/libxml2" \
+    TCLAP_HEADER_PATH="${STAGING_INCDIR}" '
+EXTRA_OEMAKE_virtclass-native = 'FMCHOSTMODE=1 FMD_USPACE_HEADER_PATH="${STAGING_INCDIR}/fmd" \
+    FMD_USPACE_LIB_PATH="${STAGING_LIBDIR}" LIBXML2_HEADER_PATH="${STAGING_INCDIR}/libxml2" \
+    TCLAP_HEADER_PATH="${STAGING_INCDIR}" '
+
+PARALLEL_MAKE = ""
+
+do_compile () {
+    if [ "b4860qds" = "${MACHINE}" ] || [ "b4420qds" = "${MACHINE}" ];then
+        EXTRA_OEMAKE_PLATFORM="b4860qds"
+    elif [ "t4240qds" = "${MACHINE}" ] || [ "t4160qds" = "${MACHINE}" ];then
+        EXTRA_OEMAKE_PLATFORM="t4240qds"
+    elif [ "p1023rds" = "${MACHINE}" ];then
+        EXTRA_OEMAKE_PLATFORM="p1023rds"
+    else
+        EXTRA_OEMAKE_PLATFORM=""
+    fi
+    oe_runmake MACHINE=${EXTRA_OEMAKE_PLATFORM} -C source
+}
+
+do_install () {
+    install -d ${D}/${bindir}
+    install -m 755 ${S}/source/fmc ${D}/${bindir}/fmc
+
+    install -d ${D}/etc/fmc/config
+    install -m 644 ${S}/etc/fmc/config/hxs_pdl_v3.xml ${D}/etc/fmc/config
+
+    install -d ${D}/${includedir}/fmc
+    install ${S}/source/fmc.h ${D}/${includedir}/fmc
+
+    install -d ${D}/${libdir}
+    install ${S}/source/libfmc.a ${D}/${libdir}
+}
+
+BBCLASSEXTEND = "native"
diff --git a/recipes-dpaa/fmlib/files/0001-fm-lib-make-the-library-install-path-configurable.patch b/recipes-dpaa/fmlib/files/0001-fm-lib-make-the-library-install-path-configurable.patch
new file mode 100644
index 0000000..4894ce3
--- /dev/null
+++ b/recipes-dpaa/fmlib/files/0001-fm-lib-make-the-library-install-path-configurable.patch
@@ -0,0 +1,43 @@
+From 67b539d256520f95f3c8101f4605ea6d496982df Mon Sep 17 00:00:00 2001
+From: Zhenhua Luo <b19537@freescale.com>
+Date: Thu, 18 Oct 2012 17:28:00 +0300
+Subject: [PATCH] fm-lib: make the library install path configurable
+
+currently library for both 32bit target and 64bit target
+is installed in /usr/lib folder, add a variable to make the
+install path configurable
+
+Signed-off-by: Zhenhua Luo <b19537@freescale.com>
+---
+ Makefile |    8 +++++---
+ 1 file changed, 5 insertions(+), 3 deletions(-)
+
+diff --git a/Makefile b/Makefile
+index 06fe930..d59f44a 100644
+--- a/Makefile
++++ b/Makefile
+@@ -59,6 +59,8 @@ endif
+ 
+ INSTALL?=install
+ 
++LIB_DEST_DIR?=$(PREFIX)/lib
++
+ # Don't forget to increment .version before doing a new release!
+ FM_LIB_VERSION:=$(shell cat .version)
+ 
+@@ -118,9 +120,9 @@ archive: all .version
+ 
+ install-%: %.a
+        @(echo "Installing...")
+-       @($(INSTALL) -d $(DESTDIR)$(PREFIX)/lib)
+-       @($(INSTALL) $< $(DESTDIR)$(PREFIX)/lib)
+-       @(ln -s $(DESTDIR)$(PREFIX)/lib/$< $(DESTDIR)$(PREFIX)/lib/libfm.a)
++       @($(INSTALL) -d $(DESTDIR)$(LIB_DEST_DIR))
++       @($(INSTALL) $< $(DESTDIR)$(LIB_DEST_DIR))
++       @(ln -s $(DESTDIR)$(LIB_DEST_DIR)/$< $(DESTDIR)$(LIB_DEST_DIR)/libfm.a)
+        @(cp -r -p ./include $(DESTDIR)$(PREFIX))
+        @($(INSTALL) -d $(DESTDIR)$(PREFIX)/share/doc/fm-lib-$(FM_LIB_VERSION))
+        @($(INSTALL) $(FM_LIB_DOCFILES) $(DESTDIR)$(PREFIX)/share/doc/fm-lib-$(FM_LIB_VERSION))
+-- 
+1.7.9.5
+
diff --git a/recipes-dpaa/fmlib/fmlib_git.bb b/recipes-dpaa/fmlib/fmlib_git.bb
new file mode 100644
index 0000000..7a7b8f2
--- /dev/null
+++ b/recipes-dpaa/fmlib/fmlib_git.bb
@@ -0,0 +1,43 @@
+DESCRIPTION = "Frame Manager User Space Library"
+SECTION = "fman"
+LICENSE = "BSD & GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=3f16fa8e677e45af3127c5c4bafc3c00"
+
+PR = "r1"
+
+DEPENDS = "linux-libc-headers"
+DEPENDS_virtclass-native = ""
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/fmlib.git"
+SRCREV = "7d843485bdac963d98f81773c0f3cb15936e09da"
+
+S = "${WORKDIR}/git"
+
+TARGET_ARCH_FMLIB = "${DEFAULTTUNE}"
+TARGET_ARCH_FMLIB_e5500 = "ppc32e5500"
+TARGET_ARCH_FMLIB_e6500 = "ppc32e6500"
+COMPATIBLE_HOST_fslmachine = ".*"
+COMPATIBLE_HOST ?= "(none)"
+
+EXTRA_OEMAKE = "DESTDIR=${D} PREFIX=${prefix} LIB_DEST_DIR=${libdir} \
+        CROSS_COMPILE=${TARGET_PREFIX} KERNEL_SRC=${STAGING_EXECPREFIXDIR}"
+
+do_compile () {
+      oe_runmake libfm-${TARGET_ARCH_FMLIB}.a
+}
+
+do_compile_virtclass-native () {
+}
+
+do_install () {
+      oe_runmake install-libfm-${TARGET_ARCH_FMLIB}
+}
+
+do_install_virtclass-native () {
+      install -d ${D}/${includedir}
+      cp -rf ${S}/include/* ${D}/${includedir}
+}
+
+ALLOW_EMPTY_${PN} = "1"
+
+BBCLASSEXTEND = "native"
diff --git a/recipes-dpaa/usdpaa/usdpaa_git.bb b/recipes-dpaa/usdpaa/usdpaa_git.bb
new file mode 100644
index 0000000..48e860f
--- /dev/null
+++ b/recipes-dpaa/usdpaa/usdpaa_git.bb
@@ -0,0 +1,49 @@
+DESCRIPTION = "User-Space Data-Path Acceleration Architecture drivers"
+LICENSE = "BSD & GPLv2"
+LIC_FILES_CHKSUM = "file://Makefile;endline=30;md5=39e58bedc879163c9338596e52df5b1f"
+PR = "r4"
+
+inherit pkgconfig
+
+DEPENDS = "libxml2 libedit ncurses readline flib fmc"
+RDEPENDS_${PN} = "libgcc bash"
+
+SRC_URI = "git://git.freescale.com/ppc/sdk/usdpaa.git"
+SRCREV = "97fe45d9697ef339e10a1885539b23fa7fcb113e"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = 'CC="${CC}" LD="${LD}" AR="${AR}"'
+export ARCH="${TARGET_ARCH}"
+
+do_compile_prepend () {
+        case ${MACHINE} in
+                b4420qds|b4420qds-64b|b4860qds|b4860qds-64b) SOC=B4860;;
+                t4240qds|t4240qds-64b) SOC=T4240;;
+                p1023rdb) SOC=P1023;;
+                *) SOC=P4080;;
+        esac
+        export FMC_EXTRA_CFLAGS="-I ${STAGING_INCDIR}/fmc"
+        export FMLIB_EXTRA_CFLAGS="-I ${STAGING_INCDIR}/fmd \
+                -I ${STAGING_INCDIR}/fmd/Peripherals \
+                -I ${STAGING_INCDIR}/fmd/integrations \
+                -D $SOC"
+
+        export LIBXML2_CFLAGS="$(pkg-config --cflags libxml-2.0)"
+        export LIBXML2_LDFLAGS="$(pkg-config --libs --static libxml-2.0)"
+        export LIBEDIT_CFLAGS="$(pkg-config --cflags libedit)"
+        export LIBEDIT_LDFLAGS="$(pkg-config --libs --static libedit)"
+}
+
+do_install () {
+        oe_runmake install DESTDIR=${D}
+}
+
+PARALLEL_MAKE_pn-${PN} = ""
+FILES_${PN} += "/root/SOURCE_THIS /usr/etc/"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+COMPATIBLE_HOST_fslmachine = ".*"
+COMPATIBLE_HOST ?= "(none)"
+