blob: e1b831f172dcda17aac647cfc7b983541eb9dab1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright (C) 2017-2021 NXP
SUMMARY = "OPTEE test"
HOMEPAGE = "http://www.optee.org/"
LICENSE = "BSD-2-Clause & GPL-2.0-only"
LIC_FILES_CHKSUM = "file://LICENSE.md;md5=daa2bcccc666345ab8940aab1315a4fa"
DEPENDS = "python3-cryptography-native optee-os optee-client openssl"
SRC_URI = "git://github.com/nxp-imx/imx-optee-test.git;protocol=https;branch=${SRCBRANCH}"
SRCBRANCH = "lf-5.15.52_2.1.0"
SRCREV = "41222c4b8df1adc0f0bdc737e5cb824becd25f63"
S = "${WORKDIR}/git"
B = "${WORKDIR}/build"
inherit python3native features_check
REQUIRED_MACHINE_FEATURES = "optee"
OPTEE_ARCH:arm = "arm32"
OPTEE_ARCH:aarch64 = "arm64"
CFLAGS += "--sysroot=${STAGING_DIR_HOST}"
CXXFLAGS += "--sysroot=${STAGING_DIR_HOST}"
EXTRA_OEMAKE = " \
TA_DEV_KIT_DIR=${STAGING_INCDIR}/optee/export-user_ta_${OPTEE_ARCH}/ \
OPTEE_CLIENT_EXPORT=${STAGING_DIR_HOST}${exec_prefix} \
CROSS_COMPILE_HOST=${HOST_PREFIX} \
CROSS_COMPILE_TA=${HOST_PREFIX} \
CROSS_COMPILE=${HOST_PREFIX} \
OPENSSL_MODULES=${STAGING_LIBDIR_NATIVE}/ossl-modules \
-C ${S} O=${B} \
"
do_compile() {
oe_runmake all
}
do_compile[cleandirs] = "${B}"
do_install () {
install -d ${D}${bindir}
install ${B}/xtest/xtest ${D}${bindir}
install -d ${D}${nonarch_base_libdir}/optee_armtz
find ${B}/ta -name '*.ta' | while read name; do
install -m 444 $name ${D}${nonarch_base_libdir}/optee_armtz/
done
install -d ${D}${libdir}/tee-supplicant/plugins/
install ${B}/supp_plugin/*plugin ${D}${libdir}/tee-supplicant/plugins/
}
FILES:${PN} += "${nonarch_base_libdir}/optee_armtz/ ${libdir}/tee-supplicant/plugins/"
RDEPENDS:${PN} = "optee-os"
COMPATIBLE_MACHINE = "(imx-nxp-bsp)"
TOOLCHAIN = "gcc"
|
