blob: 84696e35f49b823891c5b32168b36ba4ee167a28 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Copyright (C) 2012-2016 O.S. Systems Software LTDA.
# Copyright (C) 2013-2016 Freescale Semiconductor
# Copyright (C) 2017-2021 NXP
SUMMARY = "Test programs for i.MX BSP"
DESCRIPTION = "Unit tests for the i.MX BSP"
SECTION = "base"
LICENSE = "GPLv2+"
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/GPL-2.0-or-later;md5=fed54355545ffd980b814dab4a3b312c"
DEPENDS = "alsa-lib libdrm"
DEPENDS:append:mx6-nxp-bsp = " imx-lib"
DEPENDS:append:mx7-nxp-bsp = " imx-lib"
DEPENDS:append:imxvpu = " virtual/imxvpu"
PE = "1"
PV = "7.0+${SRCPV}"
SRCBRANCH = "lf-5.10.72_2.2.0"
SRC_URI = " \
git://source.codeaurora.org/external/imx/imx-test.git;protocol=https;branch=${SRCBRANCH} \
file://memtool_profile \
"
SRCREV = "a26b1ee51177e317aa05251d4c8f10c4c68064f6"
S = "${WORKDIR}/git"
inherit module-base use-imx-headers
INHIBIT_PACKAGE_STRIP = "1"
INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
PLATFORM:mx6q-nxp-bsp = "IMX6Q"
PLATFORM:mx6dl-nxp-bsp = "IMX6Q"
PLATFORM:mx6sl-nxp-bsp = "IMX6SL"
PLATFORM:mx6sll-nxp-bsp = "IMX6SL"
PLATFORM:mx6sx-nxp-bsp = "IMX6SX"
PLATFORM:mx6ul-nxp-bsp = "IMX6UL"
PLATFORM:mx7d-nxp-bsp = "IMX7D"
PLATFORM:mx7ulp-nxp-bsp = "IMX7D"
PLATFORM:mx8-nxp-bsp = "IMX8"
PARALLEL_MAKE = "-j 1"
EXTRA_OEMAKE += "${PACKAGECONFIG_CONFARGS}"
PACKAGECONFIG = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}"
PACKAGECONFIG:append:imxvpu = " vpu"
PACKAGECONFIG:append:mx8m-nxp-bsp = " swpdm"
PACKAGECONFIG[x11] = ",,libx11 libxdamage libxrender libxrandr"
PACKAGECONFIG[vpu] = "HAS_VPU=true,HAS_VPU=false,virtual/imxvpu"
PACKAGECONFIG[swpdm] = "HAS_IMX_SW_PDM=true,HAS_IMX_SW_PDM=false,imx-sw-pdm"
do_compile() {
CFLAGS="${TOOLCHAIN_OPTIONS}"
oe_runmake V=1 VERBOSE='' \
CROSS_COMPILE=${TARGET_PREFIX} \
INC="-I${S}/include \
-I${STAGING_INCDIR} \
-I${STAGING_INCDIR_IMX}" \
CC="${CC} -L${STAGING_LIBDIR} ${LDFLAGS}" \
SDKTARGETSYSROOT=${STAGING_DIR_HOST} \
LINUXPATH=${STAGING_KERNEL_DIR} \
KBUILD_OUTPUT=${STAGING_KERNEL_BUILDDIR} \
PLATFORM=${PLATFORM}
}
do_install() {
oe_runmake DESTDIR=${D}/unit_tests \
PLATFORM=${PLATFORM} \
install
if [ -e ${WORKDIR}/clocks.sh ]; then
install -m 755 ${WORKDIR}/clocks.sh ${D}/unit_tests/clocks.sh
fi
install -d -m 0755 ${D}/home/root/
install -m 0644 ${WORKDIR}/memtool_profile ${D}/home/root/.profile
}
FILES:${PN} += "/unit_tests /home/root/.profile"
RDEPENDS:${PN} = "bash"
FILES:${PN}-dbg += "/unit_tests/.debug"
|
