From fe25ab0a190680d05bb3e3c5f509274d0f89d722 Mon Sep 17 00:00:00 2001
From: "C.R. Guo" <chunrong.guo@nxp.com>
Date: Wed, 7 Mar 2018 16:45:45 +0800
Subject: optee-os: Rename optee-os -> optee-os-qoriq

Signed-off-by: Chunrong Guo <chunrong.guo@nxp.com>
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
---
 recipes-security/optee/optee-os-qoriq_git.bb | 67 ++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 recipes-security/optee/optee-os-qoriq_git.bb

(limited to 'recipes-security/optee/optee-os-qoriq_git.bb')

diff --git a/recipes-security/optee/optee-os-qoriq_git.bb b/recipes-security/optee/optee-os-qoriq_git.bb
new file mode 100644
index 000000000..21b467efc
--- /dev/null
+++ b/recipes-security/optee/optee-os-qoriq_git.bb
@@ -0,0 +1,67 @@
+SUMMARY = "OP-TEE Trusted OS"
+DESCRIPTION = "OPTEE OS"
+
+LICENSE = "BSD"
+LIC_FILES_CHKSUM = "file://${S}/LICENSE;md5=69663ab153298557a59c67a60a743e5b"
+
+DEPENDS = "python-pycrypto-native"
+
+inherit deploy pythonnative
+
+SRCREV = "4886ddbd44665589215df4ef010958cba55dc8ba"
+SRC_URI = "git://bitbucket.sw.nxp.com/scm/dash/optee_os.git;nobranch=1 \
+           file://0001-allow-setting-sysroot-for-libgcc-lookup.patch \
+          "
+
+S = "${WORKDIR}/git"
+
+OPTEEMACHINE ?= "${MACHINE}"
+
+EXTRA_OEMAKE = "PLATFORM=ls-${OPTEEMACHINE} CFG_ARM64_core=y \
+                ARCH=arm \
+                CROSS_COMPILE_core=${HOST_PREFIX} \
+                CROSS_COMPILE_ta_arm64=${HOST_PREFIX} \
+                NOWERROR=1 \
+                LDFLAGS= \
+                LIBGCC_LOCATE_CFLAGS=--sysroot=${STAGING_DIR_HOST} \
+        "
+
+OPTEE_ARCH_armv7a = "arm32"
+OPTEE_ARCH_aarch64 = "arm64"
+
+do_compile() {
+    unset LDFLAGS
+    oe_runmake all CFG_TEE_TA_LOG_LEVEL=0
+}
+
+do_install() {
+    #install core on boot directory
+    install -d ${D}/lib/firmware/
+
+    install -m 644 ${B}/out/arm-plat-ls/core/tee.elf ${D}/lib/firmware/tee_${MACHINE}.bin
+    #install TA devkit
+    install -d ${D}/usr/include/optee/export-user_ta/
+
+    for f in  ${B}/out/arm-plat-ls/export-ta_${OPTEE_ARCH}/* ; do
+        cp -aR  $f  ${D}/usr/include/optee/export-user_ta/
+    done
+}
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+do_deploy() {
+        install -d ${DEPLOYDIR}/optee
+        for f in ${D}/lib/firmware/*; do
+            install -m 644 $f ${DEPLOYDIR}/optee/tee_${MACHINE}.bin
+        done
+}
+
+addtask deploy before do_build after do_install
+
+FILES_${PN} = "/lib/firmware/"
+FILES_${PN}-dev = "/usr/include/optee"
+
+INSANE_SKIP_${PN}-dev = "staticdev"
+
+INHIBIT_PACKAGE_STRIP = "1"
+COMPATIBLE_MACHINE = "(ls1043ardb|ls1046ardb|ls1012ardb)"
-- 
cgit v1.2.3-54-g00ecf