From 03730c26904466db2a71413de1e7f89922e92679 Mon Sep 17 00:00:00 2001
From: Yuqing Zhu <carol.zhu@nxp.com>
Date: Mon, 18 Apr 2016 22:57:47 +0800
Subject: imx-parser: Upgrade to v4.0.9

--Change the recipe name from "libfslparser" to "imx-parser"

--Add RREPLACE/RPROVIDES/RCONFLICTS for backwards compatibility.

--Add aac latm parser in parser_libs, support aac latm in mpeg2 parser

Change-Id: I2e3cb92a952fe10136c25206f1527ca1472598cc
Signed-off-by: Yuqing Zhu <carol.zhu@nxp.com>
Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
---
 recipes-multimedia/imx-parser/imx-parser.inc      | 38 +++++++++++++++++++++++
 recipes-multimedia/imx-parser/imx-parser_4.0.9.bb |  9 ++++++
 2 files changed, 47 insertions(+)
 create mode 100644 recipes-multimedia/imx-parser/imx-parser.inc
 create mode 100644 recipes-multimedia/imx-parser/imx-parser_4.0.9.bb

(limited to 'recipes-multimedia/imx-parser')

diff --git a/recipes-multimedia/imx-parser/imx-parser.inc b/recipes-multimedia/imx-parser/imx-parser.inc
new file mode 100644
index 000000000..6fb34de8d
--- /dev/null
+++ b/recipes-multimedia/imx-parser/imx-parser.inc
@@ -0,0 +1,38 @@
+# Copyright (C) 2012-2014 O.S. Systems Software LTDA.
+# Copyright (C) 2012-2016 Freescale Semiconductor
+# Released under the MIT license (see COPYING.MIT for the terms)
+DESCRIPTION = "Freescale Multimedia parser libs"
+LICENSE = "Proprietary"
+SECTION = "multimedia"
+LIC_FILES_CHKSUM = "file://COPYING;md5=8cf95184c220e247b9917e7244124c5a"
+
+# For backwards compatibility
+RREPLACES_${PN} = "libfslparser"
+RPROVIDES_${PN} = "libfslparser"
+RCONFLICTS_${PN} = "libfslparser"
+
+inherit fsl-eula-unpack autotools pkgconfig
+
+SRC_URI = "${FSL_MIRROR}/${PN}-${PV}.bin;fsl-eula=true"
+
+# Choose between Soft Float-Point and Hard Float-Point
+EXTRA_OECONF = "${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', '--enable-fhw', '--enable-fsw', d)}"
+
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+
+python __set_insane_skip() {
+    # FIXME: All binaries lack GNU_HASH in elf binary but as we don't have
+    # the source we cannot fix it. Disable the insane check for now.
+    # FIXME: gst-fsl-plugin looks for the .so files so we need to deploy those
+    for p in d.getVar('PACKAGES', True).split():
+        d.setVar("INSANE_SKIP_%s" % p, "ldflags dev-so textrel")
+}
+
+do_package_qa[prefuncs] += "__set_insane_skip"
+
+# FIXME: gst-fsl-plugin looks for the .so files so we need to deploy those
+FILES_${PN} += "${libdir}/imx-mm/*/*${SOLIBS} ${libdir}/imx-mm/*/*${SOLIBSDEV}"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
diff --git a/recipes-multimedia/imx-parser/imx-parser_4.0.9.bb b/recipes-multimedia/imx-parser/imx-parser_4.0.9.bb
new file mode 100644
index 000000000..165017267
--- /dev/null
+++ b/recipes-multimedia/imx-parser/imx-parser_4.0.9.bb
@@ -0,0 +1,9 @@
+# Copyright (C) 2013-2015 Freescale Semiconductor
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+require imx-parser.inc
+
+SRC_URI[md5sum] = "184687baede96fe3919196c3f91d907c"
+SRC_URI[sha256sum] = "1bec0101843db2e95d61e3dbe9e35172d874e54be19cc5d8bf72a735d5e3236f"
+
+COMPATIBLE_MACHINE = "(mx6|mx6ul|mx7)"
-- 
cgit v1.2.3-54-g00ecf