From 640880536da477a2c38e6522f4678a7b4b3819fb Mon Sep 17 00:00:00 2001
From: Valentin Jec <valentin.jec@nxp.com>
Date: Fri, 25 Oct 2024 13:58:18 +0300
Subject: Upgrade NXP BSP to LF6.6.36_2.1.0

imx-g2d: Upgrade 2.1.14 -> 2.2.0

Signed-off-by: Valentin Jec <valentin.jec@nxp.com>
---
 recipes-graphics/imx-g2d/imx-dpu-g2d_2.2.0.bb | 47 +++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 recipes-graphics/imx-g2d/imx-dpu-g2d_2.2.0.bb

(limited to 'recipes-graphics/imx-g2d/imx-dpu-g2d_2.2.0.bb')

diff --git a/recipes-graphics/imx-g2d/imx-dpu-g2d_2.2.0.bb b/recipes-graphics/imx-g2d/imx-dpu-g2d_2.2.0.bb
new file mode 100644
index 00000000..5e8f5402
--- /dev/null
+++ b/recipes-graphics/imx-g2d/imx-dpu-g2d_2.2.0.bb
@@ -0,0 +1,47 @@
+# Copyright (C) 2016 Freescale Semiconductor
+# Copyright 2017-2024 NXP
+# Released under the MIT license (see COPYING.MIT for the terms)
+
+DESCRIPTION = "G2D library using i.MX DPU"
+LICENSE = "Proprietary"
+LIC_FILES_CHKSUM = "file://COPYING;md5=ca53281cc0caa7e320d4945a896fb837" 
+
+DEPENDS = "libdrm ${LIBGAL_IMX}"
+LIBGAL_IMX              = "libgal-imx"
+LIBGAL_IMX:mx95-nxp-bsp = ""
+
+PROVIDES += "virtual/libg2d"
+
+SRC_URI = "${FSL_MIRROR}/${IMX_BIN_NAME}.bin;fsl-eula=true;name=${IMX_SRC_URI_NAME}"
+IMX_BIN_NAME = "${BPN}-${IMX_SRC_URI_NAME}-${PV}-${IMX_SRCREV_ABBREV}"
+
+IMX_SRCREV_ABBREV = "7943590"
+IMX_SRC_URI_NAME = "v1"
+SRC_URI[v1.sha256sum] = "bf347f53e8f390a0554c0db76707819bb50cf4aaa564a9c86821ae9add26e113"
+
+IMX_SRCREV_ABBREV:mx95-nxp-bsp = "7943590"
+IMX_SRC_URI_NAME:mx95-nxp-bsp = "v2"
+SRC_URI[v2.sha256sum] = "c0a87908cd04c208659423746a57eaee6a30b4d680ec871f3495ad4a2acb5076"
+
+S = "${WORKDIR}/${IMX_BIN_NAME}"
+
+inherit fsl-eula-unpack
+
+do_install () {
+    install -d ${D}${libdir}
+    install -d ${D}${includedir}
+    cp -d ${S}/g2d/usr/lib/*.so* ${D}${libdir}
+    cp -Pr ${S}/g2d/usr/include/* ${D}${includedir}
+}
+
+INSANE_SKIP:append:libc-musl = " file-rdeps"
+RDEPENDS:${PN}:append:libc-musl = " gcompat"
+
+# The packaged binaries have been stripped of debug info, so disable
+# operations accordingly.
+INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
+INHIBIT_PACKAGE_STRIP = "1"
+INHIBIT_SYSROOT_STRIP = "1"
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+COMPATIBLE_MACHINE = "(imxdpu)"
-- 
cgit v1.2.3-54-g00ecf