From 02fc6a68ecc9d76cdaeca483b70dc37180e2e7f8 Mon Sep 17 00:00:00 2001
From: Otavio Salvador <otavio@ossystems.com.br>
Date: Tue, 10 Jul 2018 09:35:08 -0300
Subject: u-boot-fslc: Update to 2018.07-based fork

This updates the fork on top of current 2018.07 release and also adds
a much improved support to pico-imx7d and pico-imx6ul. The list of
commits included are:

bc558729a7 warp7: update defconfig to support the generic loading interface
e5a6138278 mx25pdk: Change root to use a single partition layout
f9d1e13cf5 mx6sabre_common: Dynamically change the video output
865268ce8a mx6sabresd: Enable video interfaces in bootargs
7db6f3d8c5 mx6sabresd: Use LDO dtb file until LDO bypass support is added
84fc5b0de1 mx6slevk: Use LDO dtb file until LDO bypass support is added
ccf16e75e7 pico-imx6ul: Convert to distro config
06eecc42a2 configs/imx: Remove 'mmcautodect' variable
12c65ae7a9 pico-imx7d: Add new pico-pi config
fe4fd4e1ea pico-imx7d: README: Drop old instructions about secure mode
a076cc293b pico-imx7d: README: Use dfu-util to flash U-Boot
24f9fcde47 pico-imx7d: Enable auxiliary code support
78fead0843 pico-imx7d: Allow default fdtfile to be overridden by defconfig
04d0d8894f pico-imx7d: Do not override addrmap5
e5833f48e6 pico-imx7d: Enable CONFIG_ARMV7_BOOT_SEC_DEFAULT
ceb9087434 pico-imx7d: Add Falcon mode support
8800626580 pico-imx7d: Add bootmenu to choose the baseboard
f2c33216e7 pico-imx7d: Add support for update SPL using DFU
6cc975154d pico-imx7d: Add SPL support
349985a0f2 pico-imx7d: Add fastboot support
76a4da5eb1 pico-imx7d: Add default DFU targets
c6c4a0e0d8 pico-imx7d: Add GPT partitioning support
9ac7204c7a pico-imx7d: Fix common distro configuration behavior
62523103a0 pico-imx7d: Convert to distro config

Signed-off-by: Otavio Salvador <otavio@ossystems.com.br>
---
 recipes-bsp/u-boot/u-boot-fslc-fw-utils_2018.07.bb | 45 ++++++++++++++++++++++
 1 file changed, 45 insertions(+)
 create mode 100644 recipes-bsp/u-boot/u-boot-fslc-fw-utils_2018.07.bb

(limited to 'recipes-bsp/u-boot/u-boot-fslc-fw-utils_2018.07.bb')

diff --git a/recipes-bsp/u-boot/u-boot-fslc-fw-utils_2018.07.bb b/recipes-bsp/u-boot/u-boot-fslc-fw-utils_2018.07.bb
new file mode 100644
index 00000000..abcb5013
--- /dev/null
+++ b/recipes-bsp/u-boot/u-boot-fslc-fw-utils_2018.07.bb
@@ -0,0 +1,45 @@
+require u-boot-fslc-common_${PV}.inc
+
+SUMMARY = "U-Boot bootloader fw_printenv/setenv utilities"
+DEPENDS = "mtd-utils"
+
+INSANE_SKIP_${PN} = "already-stripped"
+EXTRA_OEMAKE_class-target = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" V=1'
+EXTRA_OEMAKE_class-cross = 'ARCH=${TARGET_ARCH} CC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
+
+inherit uboot-config
+
+do_compile () {
+    oe_runmake ${UBOOT_MACHINE}
+    oe_runmake envtools
+}
+
+do_install () {
+    install -d ${D}${base_sbindir}
+    install -d ${D}${sysconfdir}
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_printenv
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_setenv
+
+    if [ -e ${WORKDIR}/fw_env.config ]; then
+        install -m 0644 ${WORKDIR}/fw_env.config ${D}${sysconfdir}/fw_env.config
+    else
+        install -m 0644 ${S}/tools/env/fw_env.config ${D}${sysconfdir}/fw_env.config
+    fi
+}
+
+do_install_class-cross () {
+    install -d ${D}${bindir_cross}
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
+    install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
+}
+
+SYSROOT_PREPROCESS_FUNCS_class-cross = "uboot_fw_utils_cross"
+uboot_fw_utils_cross() {
+    sysroot_stage_dir ${D}${bindir_cross} ${SYSROOT_DESTDIR}${bindir_cross}
+}
+
+PROVIDES += "u-boot-fw-utils"
+RPROVIDES_${PN} += "u-boot-fw-utils"
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+BBCLASSEXTEND = "cross"
-- 
cgit v1.2.3-54-g00ecf