From a81511cfec6cb9f9fd353c7471d240bc4e9766f2 Mon Sep 17 00:00:00 2001
From: Mihai Lindner <mihai.lindner@nxp.com>
Date: Tue, 21 May 2019 18:13:34 +0300
Subject: imx-atf: Upgrade version from 1.5 to 2.0

Signed-off-by: Mihai Lindner <mihai.lindner@nxp.com>
---
 recipes-bsp/imx-atf/imx-atf_2.0.bb | 47 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 recipes-bsp/imx-atf/imx-atf_2.0.bb

(limited to 'recipes-bsp/imx-atf/imx-atf_2.0.bb')

diff --git a/recipes-bsp/imx-atf/imx-atf_2.0.bb b/recipes-bsp/imx-atf/imx-atf_2.0.bb
new file mode 100644
index 00000000..fdb18fbe
--- /dev/null
+++ b/recipes-bsp/imx-atf/imx-atf_2.0.bb
@@ -0,0 +1,47 @@
+# Copyright (C) 2017-2019 NXP
+
+DESCRIPTION = "i.MX ARM Trusted Firmware"
+SECTION = "BSP"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/BSD-3-Clause;md5=550794465ba0ec5312d6919e203a55f9"
+
+PV .= "+git${SRCPV}"
+
+SRCBRANCH = "imx_4.14.98_2.0.0_ga"
+SRC_URI = "git://source.codeaurora.org/external/imx/imx-atf.git;protocol=https;branch=${SRCBRANCH} \
+           file://0001-Allow-BUILD_STRING-to-be-set-in-.revision-file.patch \
+"
+SRCREV = "1cb68fa0a0dd8bc00b9871b51d4c4e1d0a827b2d"
+
+S = "${WORKDIR}/git"
+
+inherit deploy
+
+BOOT_TOOLS = "imx-boot-tools"
+
+PLATFORM        ?= "INVALID"
+PLATFORM_mx8qm   = "imx8qm"
+PLATFORM_mx8qxp  = "imx8qxp"
+PLATFORM_mx8mq   = "imx8mq"
+PLATFORM_mx8mm   = "imx8mm"
+
+EXTRA_OEMAKE += " \
+    CROSS_COMPILE="${TARGET_PREFIX}" \
+    PLAT=${PLATFORM} \
+"
+
+do_compile() {
+    # Clear LDFLAGS to avoid the option -Wl recognize issue
+    unset LDFLAGS
+    oe_runmake bl31
+}
+
+do_install[noexec] = "1"
+
+do_deploy() {
+    install -Dm 0644 ${S}/build/${PLATFORM}/release/bl31.bin ${DEPLOYDIR}/${BOOT_TOOLS}/bl31-${PLATFORM}.bin
+}
+addtask deploy after do_compile
+
+PACKAGE_ARCH = "${MACHINE_SOCARCH}"
+COMPATIBLE_MACHINE = "(mx8)"
-- 
cgit v1.2.3-54-g00ecf