From ca63ad1640f376682bf9d65cc93f6f7eb383923e Mon Sep 17 00:00:00 2001
From: Jun Zhu <junzhu@nxp.com>
Date: Fri, 16 Dec 2022 15:28:16 +0800
Subject: management-complex: Add recipe for v10.35.0

Signed-off-by: Jun Zhu <junzhu@nxp.com>
(cherry picked from commit fa2d57d67407f94614f24eea008c4a69ec73bc1c)
---
 .../management-complex_10.35.0.bb                  | 41 ++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 recipes-dpaa2/management-complex/management-complex_10.35.0.bb

diff --git a/recipes-dpaa2/management-complex/management-complex_10.35.0.bb b/recipes-dpaa2/management-complex/management-complex_10.35.0.bb
new file mode 100644
index 00000000..d114a92e
--- /dev/null
+++ b/recipes-dpaa2/management-complex/management-complex_10.35.0.bb
@@ -0,0 +1,41 @@
+SUMMARY = "DPAA2 Management Complex Firmware"
+LICENSE = "NXP-Binary-EULA"
+LIC_FILES_CHKSUM = "file://NXP-Binary-EULA.txt;md5=1db1363924ceccb1edea921b6495bdc2"
+
+inherit deploy
+
+INHIBIT_DEFAULT_DEPS = "1"
+
+SRC_URI = "git://github.com/nxp/qoriq-mc-binary;protocol=https;nobranch=1"
+SRCREV = "836d7bf606b51c18b5e3726d68dcf3b3ac4de74a"
+
+S = "${WORKDIR}/git"
+
+REGLEX:ls2088a = "ls2088a"
+REGLEX:ls2080a = "ls2080a"
+REGLEX:ls1088a = "ls1088a"
+REGLEX:lx2160a = "lx216xa"
+REGLEX:lx2162a = "lx216xa"
+
+do_install () {
+    install -d ${D}/boot
+    install -m 755 ${S}/${REGLEX}/*.itb ${D}/boot
+}
+
+do_deploy () {
+    install -d ${DEPLOYDIR}/mc_app
+    install -m 755 ${S}/${REGLEX}/*.itb ${DEPLOYDIR}/mc_app
+    # make a symlink to the latest binary
+    for mc_binary in `find ${DEPLOYDIR}/mc_app -type f -printf "%f\n" |sort`;do
+        ln -sfT ${mc_binary} ${DEPLOYDIR}/mc_app/mc.itb
+    done
+}
+addtask deploy before do_build after do_install
+
+PACKAGES += "${PN}-image"
+FILES:${PN}-image += "/boot"
+
+INHIBIT_PACKAGE_STRIP = "1"
+
+COMPATIBLE_MACHINE = "(qoriq-arm64)"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
-- 
cgit v1.2.3-54-g00ecf